0 CLR
5 REM COPYRIGHT 1991 - COMPUTE PUBLICATIONS INTL LTD - ALL RIGHTS RESERVED
10 REM CREDIT CONTROL -BY G. REID. CC
20 MX=61:X=0:L=1:O$="10.5":P$="10TH OF MONTH":M=10:CL=1000
30 DIM D$(MX,4)
40 PRINT"[147]"
50 FORXX=1TO5:PRINT"":NEXT:GOSUB980
60 PRINT"";TAB(13)"[195][210][197][196][201][212][160][195][207][206][212][210][207][204][154]"
70 PRINTTAB(13)"**************"
80 PRINT CHR$(14)
90 SY$="[159]":SZ$="[146][154]"
100 N$(1)="[196]ATA ENTRY":N$(2)="[196]ISPLAY"
110 N$(3)="[211]TORAGE":N$(4)="[211]TATISTICS"
120 N$(5)="[197]XIT"
130 FOR C=1TO5:PRINTTAB(13) N$(C):NEXT
140 PRINT"[145][145][145][145][145][145]":C=1:PRINTTAB(13)SY$N$(1)SZ$
150 GETG$:IFG$=""THEN150
160 IFG$=CHR$(13)THEN200
170 IFG$=""THEN PRINT"[145]";TAB(13)N$(C):C=C+1:PRINTTAB(13)SY$N$(C)SZ$
180 IFC=6THENPRINT"[145]";:GOTO140
190 GOTO150
200 ON C GOTO330,570,730,210,1240
210 PRINT"[147][211]TATISTICAL DATA ENTRY":PRINT
220 PRINT"[197]NTER YOUR NEW:-"
230 PRINT"[193]NNUAL FINANCE CHARGE RATE"
240 PRINT"[195]URRENT IS--";O$:INPUT O$:IFVAL(O$)<1THEN210
250 PRINT"[205]ONTHLY PAYMENT DATE"
260 PRINT"[195]URRENT IS--";P$:INPUT P$
270 PRINT"[194]UDGETED MAXIMUM MONTHLY CREDIT"
280 PRINT"PURCHASES AMOUNT $"
290 PRINT"[195]URRENT IS--";M:INPUT M:IFM<1THEN270
300 PRINT"[193]SSIGNED [195]REDIT [204]IMIT"
310 PRINT"[195]URRENT IS--";CL:INPUT CL
320 GOTO40
330 X=X+1:Y=0:I$="--":IFX>MX-1THENPRINT"[147][198]ULL FILE":X=L:GOTO430
340 PRINT"[147][197]NTER [205]ONTH & DAY OF PURCHASE":GOSUB420
350 PRINT"[147][197]NTER [211]ELLER'S [206]AME/[196]ESCRIPTION":GOSUB420
360 PRINT"[147][197]NTER [193]MOUNT (CHARGED OR PAID) $"
370 PRINT"([208]AYMENT MUST BE MINUS E.G.  -56)":L=X:GOSUB420
380 B2=B2+VAL(D$(X,3)):B2=INT(B2*100+.5)/100:D$(X,4)=STR$(B2)
390 IFVAL(D$(X,3))<0THENB4=B3:B3=B2
400 IFX=LTHEN430
410 X=X+1:GOTO520
420 INPUTI$:Y=Y+1:D$(X,Y)=I$:I$="--":RETURN
430 PRINT" E=ENTER: C=CHANGES: M=MENU: D=DISPLAY"
440 GET N$:IFN$=""THEN440
450 IF N$="E"THEN330
460 IF N$="C"THEN500
470 IF N$="M"THEN40
480 IF N$="D"THEN570
490 GOTO440
500 PRINT"[147][200]IT [210][197][212][213][210][206] AFTER CHANGES OR TO BY-PASS  AN ENTRY"
510 X=X-1:IFX<1THENX=1
520 PRINT"[197]NTER NEW DATA AT CURSOR:-"
530 B2=VAL(D$(X-1,4)):PRINT
540 PRINT"#";X;TAB(5)"[196]ATE:   ";D$(X,1);:INPUT D$(X,1)
550 PRINTTAB(5)"[211]ELLER: ";LEFT$(D$(X,2),13);:INPUT D$(X,2)
560 PRINTTAB(5)"[193]MOUNT: ";D$(X,3);:INPUT D$(X,3):PRINT:GOTO380
570 G=1:C2=18:C1=C2
580 PRINT"[147]";C$:PRINT" [206]O [196]ATE  [211]ELLER/[196]ETAIL  [193]MOUNT [194]ALANCE"
590 PRINT" -- ----  -------------  ------ -------"
600 FOR C=GTO L
610 PRINTC;TAB(4)LEFT$(D$(C,1),6);TAB(10)LEFT$(D$(C,2),13);
620 PRINTTAB(23);:F$=D$(C,3)
630 GOSUB640:F$=D$(C,4):GOSUB640:PRINT:GOTO680
640 F$="     "+F$:FT$=RIGHT$(F$,3):IFLEFT$(FT$,1)="."THEN670
650 IFMID$(FT$,2,1)="."THENF$=F$+"0":GOTO670
660 F$=F$+".00"
670 PRINTRIGHT$(F$,8);:RETURN
680 IF C<C1THEN720
690 PRINT"[210][197][212][213][210][206]"
700 GET PA$:IFPA$=""THEN700
710 C1=C1+C2
720 NEXT:PRINT:GOTO430
730 PRINT"[147]":INPUT"[197]NTER FILE-NAME";C$
740 PRINT" L=LOAD:  S=SAVE"
750 GET X$:IFX$=""THEN750
760 IFX$="L"THEN900
770 IFX$<>"S"THEN750
780 PRINT"[215]ISH TO [158][211][193][214][197][154] ";C$;" ? [217]/[206]"
790 GETX$:IFX$=""THEN790
800 IFX$<>"Y"THEN40
810 OPEN 1,8,2,"@0:CDF"+C$+",S,W"
820 Q$=CHR$(13)
830 PRINT#1,P$Q$O$Q$M,Q$L,Q$CL
840 C=1:Y=1
850 IF C>LTHEN890
860 A$=D$(C,Y):PRINT#1,A$:Y=Y+1
870 IF Y>4THEN Y=1:C=C+1
880 GOTO850
890 CLOSE 1:PRINT"[147]SAVED "C$:GOTO50
900 OPEN 1,8,2,"0:CDF"+C$+",S,R"
910 INPUT# 1,P$,O$,M,L,CL
920 C=1:Y=1
930 IF C>LTHEN970
940 INPUT#1,A$:D$(C,Y)=A$:Y=Y+1
950 IF Y>4THEN Y=1:C=C+1
960 GOTO930
970 CLOSE 1:X=L:B2=VAL(D$(C-1,4)):GOTO570
980 U=VAL(D$(X,4))
990 UM=INT((U-M)*100+.5)/100
1000 PRINT:PRINT"[158][211]ELECT[154] WITH CURSOR AND [210][197][212][213][210][206]"
1010 PRINT"";TAB(10)"-----------------"
1020 PRINT"[217]OUR CURRENT BALANCE IS $";
1030 IFU>MTHENPRINT"[150]"U"[154]":GOTO1050
1040 PRINTU:IFU=<0THENPRINT" [195]ONGRATULATIONS!":GOTO1230
1050 IF(CL-U)<CL*.2 THEN PRINT" [217]OUR CREDIT LIMIT IS $";CL
1060 IFVAL(D$(X,3))<0THEN1090
1070 PRINT" [212]O AVOID [198]INANCE [195]HARGE AT ";O$;"% [193][208][210],"
1080 PRINT" [208]LEASE PAY BY ";P$;"[154]"
1090 IFU=<M THEN1230
1100 PRINT"[129][194]ALANCE EXCEEDS $";STR$(M);"-BUDGET BY";UM
1110 R=VAL(O$)/12/100:IF(U/M*R) >.99999THEN1210
1120 N=LOG(1/(1-(U/M*R)))/LOG(1+R)
1130 PRINT" [201]F NO FURTHER PURCHASES, IT TAKES"
1140 PRINTINT(N*10+.5)/10;"MONTHS TO PAY OFF.[154]"
1150 IF N<1.15THEN1230
1160 IF VAL(D$(X,3))<(.25*M)THEN IF U<B4THENPRINT" [199]OOD TREND...BUT"
1170 IF N>2 THEN1220
1180 PRINT"[150][201]NCREASE YOUR BUDGET TO $";INT(M*N);
1190 IF N<1.5THEN1230
1200 PRINT" OR":GOTO1220
1210 PRINT"[150] [195]ANNOT BE REPAID.  [194]UDGET OF $";M;"IS    VERY LOW.  [210][197][208][197][193][212]!"
1220 PRINT"[158][200][201][196][197][160][217][207][213][210][160][195][193][210][196] [193][215][193][217]![154]"
1230 RETURN
1240 PRINT"[196]ID YOU SAVE YOUR DATA?   [217]/[206]"
1250 GETS$:IF S$=""THEN1250
1260 IF S$="Y"THEN PRINT"[147]":END
1270 GOTO40