10 REM COPYRIGHT 1988 COMPUTE! PUBLICATIONS, INC. - ALL RIGHTS RESERVED
20 REM SCREENIUS DEMO (FIRST LOAD AND RUN SCREENIUS)
30 POKE53281,0:POKE53280,12:PRINT"[147][152]   COPYRIGHT 1988 COMPUTE! PUB., INC."
40 PRINTTAB(11)"ALL RIGHTS RESERVED":FORI=1TO1750:NEXT
50 PRINT"[147]";:FORX=0TO3:SYS50045,X:NEXTX:REM CLEAR ALL NOTEPAD SCREENS
60 PRINT"SCREENIUS NOTEPAD PROGRAM":PRINT
70 REM THE FOLLOWING LINE DISABLES SCREENIUS FUNCTION-KEY CHECKING
80 POKE56333,127:POKE788,49:POKE789,234:POKE56333,129
90 PRINT"PRESS:":PRINT"F1[146] FOR THIS MENU":PRINT"F3[146] FOR NOTEPAD 1"
100 PRINT"F5[146] FOR NOTEPAD 2":PRINT"F7[146] FOR NOTEPAD 3"
110 PRINT"F2[146] TO SAVE NOTEPADS":PRINT"F4[146] TO LOAD NOTEPADS"
120 PRINT"F6[146] TO DUMP CURRENT NOTEPAD TO A PRINTER"
130 PRINT"F8[146] TO END THE PROGRAM":PRINT
140 SV=49648:REM SAVE ROUTINE ADDRESS
150 LD=49714:REM LOAD ROUTINE ADDRESS
160 PR=49882:REM PRINT ROUTINE ADDRESS
170 DS=50032:REM DISPLAY SCREEN ROUTINE
180 SR=50045:REM STORE SCREEN ADDRESS
190 PRINT"ALL NORMAL EDITING FEATURES ARE ACTIVE,"
200 PRINT"INCLUDING COLOR CONTROLS.":PRINT
210 PRINT"DO NOT CLEAR THIS MENU SCREEN"
220 PRINT"OR YOU WILL LOSE IT!"
230 SN=0:A=209:B=210:C=211:SYSSR,0
240 X=PEEK(A)+256*PEEK(B)+PEEK(C):POKEX,PEEK(X)OR128
250 GETA$:IFA$=""THEN250
260 CH=ASC(A$):IFCH<133ORCH>136THEN280
270 POKEX,PEEK(X)AND127:SYSSR,SN:SN=CH-133:SYSDS,SN:GOTO240:REM UNSHIFTED F KEY
280 IFA$=CHR$(137)THENGOSUB330:GOTO250
290 IFA$=CHR$(138)THENGOSUB360:GOTO250
300 IFA$=CHR$(139)THENGOSUB390:GOTO250
310 IFA$=CHR$(140)THENPRINT"[147]":END
320 POKEX,PEEK(X)AND127:PRINTA$;:GOTO240:
330 SYSSR,SN:PRINT"[147]SAVE NOTEPADS:"
340 INPUT"FILENAME";FI$
350 SYSSV,FI$:SYSDS,SN:RETURN
360 SYSSR,SN:PRINT"[147]LOAD NOTEPADS:"
370 INPUT"FILENAME";FI$
380 SYSLD,FI$:SYSDS,SN:RETURN
390 POKEX,PEEK(X)AND127:SYSSR,SN:SYSPR,SN:POKEX,PEEK(X)OR128:RETURN