10 REM COPYRIGHT 1988 COMPUTE! PUBLICATIONS, INC. - ALL RIGHTS RESERVED
20 REM THIS IS THE UPDATED GEOCONVERTER        REVISED MAY ISSUE 1988 GAZETTE
30 POKE 53280,0:POKE 53281,0:POKE 646,5:PRINTCHR$(142);CHR$(147)
40 FORI=1TO10:PRINT"":NEXT
50 PRINTTAB(5)"[151][213][196][201] COPYRIGHT 1988"
60 PRINTTAB(5)"[199]C[200] COMPUTE! PUBLICATIONS INC."
70 PRINTTAB(5)"[202][198][203] ALL RIGHTS RESERVED"
80 PRINT"[155]GEOCONVERTER 1.1[146]"
90 INPUT"FILE TO CONVERT";GF$
100 PRINT"SEARCHING FOR "GF$
110 HD$="":FOR I=1 TO 4:READ HE:HD$=HD$+CHR$(HE):NEXT
120 FOR I=1TO5:READIE:ID$=ID$+CHR$(IE):NEXT
130 NL$="":T$=CHR$(18):S$=CHR$(1):OPEN 15,8,15,"I0:":OPEN 2,8,2,"#"
140 GOSUB370:GET #2,NT$,NS$
150 FOR E=0 TO 7
160 D$=NL$:GET#2,B$:I=1:IFB$=NL$ THEN220
170 IF ASC(B$)<>130 THEN220
180 GET#2,HT$,HS$:I=3:IF HS$="" THEN HS$=CHR$(0)
190 GET#2,B$:I=I+1:IF B$="" THEN B$=CHR$(0)
200 IF ASC(B$)=160 THEN220
210 D$=D$+B$:GOTO190
220 FOR I=I TO 31:GET#2,B$:NEXT
230 IF D$=GF$ THEN260
240 NEXT E:IF NT$=NL$ THEN260
250 T$=NT$:S$=NS$:GOTO140
260 IF D$=NL$ THENPRINT"FILE NOT FOUND[146]":GOTO360
270 PRINT"CONVERTING "GF$
280 DT$=T$:DS$=S$:T$=HT$:S$=HS$:GOSUB370
290 GET#2,MT$,MS$:IF MS$="" THEN MS$=CHR$(0)
300 FOR I=0 TO 65:GET #2,B$:NEXT
310 GET#2,CT$,GT$:GOSUB370:PRINT#2,HD$;:GOSUB380:T$=DT$:S$=DS$:GOSUB370
320 FOR I=0 TO 32*E+2:GET#2,B$:NEXT
330 PRINT#2,MT$;MS$;:FORI=0 TO 15:GET#2,B$:NEXT
340 PRINT#2,HT$;HS$;CHR$(0);GT$;
350 PRINT#2,ID$;:GOSUB380:PRINT:PRINTGF$" CONVERTED"
360 CLOSE2:CLOSE15:END
370 U$="U1":GOTO390
380 U$="U2"
390 PRINT#15,U$;2;0;ASC(T$+"0");ASC(S$+"0")
400 RETURN
410 DATA 0,255,3,21,87,10,1,0,0