10 REM COPYRIGHT 1988 COMPUTE! PUBLICATIONS, INC. - ALL RIGHTS RESERVED
20 DIMFD$(9),CV$(15,1)
30 POKE53280,0:POKE53281,0
40 FORI=0TO15:CV$(I,0)=CHR$(48+I):CV$(I,1)=STR$(I)
50 IFI>9THENCV$(I,0)=CHR$(55+I)
60 NEXTI
70 CF=0:PRINT"[147]"CHR$(14)CHR$(8)"   [195]OPYRIGHT 1988 [195][207][205][208][213][212][197]! [208]UB., [201]NC."
80 PRINTTAB(11)"[193]LL RIGHTS RESERVED"
90 PRINT"[194]UILD DATA FILE FOR [205][204]-[194]OOT...[146]"
100 INPUT"[194][146]UILD OR [214][146]IEW DATA FILEV[157][157][157]";A$
110 IFA$<>"B"THEN320
120 INPUT"[194]ACKGROUND COLOR:[146]0[157][157][157]";BC:BC$=CHR$(BC)
130 INPUT"[194]ORDER COLOR:[146]0[157][157][157]";B2:B2$=CHR$(B2)
140 INPUT"[212]EXT COLOR:[146]6[157][157][157]";T1:T1$=CHR$(T1)
150 INPUT"[198]ILENAME[146]";A$
160 INPUT"[211]TART ADDRESS[146]";B$:IFLEFT$(B$,1)="$"THENGOSUB410:GOTO180
170 AD=VAL(B$):HB=INT(AD/256):LB=AD-HB*256
180 FD$(CF)=CHR$(LB):FD$(CF)=FD$(CF)+CHR$(HB)
190 IFLEN(A$)>=16THEN210
200 FORI=LEN(A$)TO16:A$=A$+CHR$(160):NEXTI
210 FD$(CF)=FD$(CF)+LEFT$(A$,16)
220 INPUT"[193]NOTHER FILE (Y/N)N[157][157][157][146]";G$
230 IFG$="Y"ANDCF<9THENCF=CF+1:GOTO150
240 IFCF=9THENPRINT"[212]OO MANY FILES...[146]"
250 GOTO530:REM VERIFY DATA
260 OPEN15,8,15,"S0:BOOT.DAT":CLOSE15:OPEN2,8,2,"0:BOOT.DAT,S,W"
270 PRINT#2,BC$;:PRINT#2,B2$;:PRINT#2,T1$;
280 PRINT#2,CHR$(CF+1);
290 FORI=0TOCF:PRINT#2,FD$(I);:NEXTI
300 CLOSE2:END
310 PRINT"[196]ATA FILE CONTENTS:[146]"
320 OPEN2,8,2,"0:BOOT.DAT,S,R"
330 FORFC=1TO3:GET#2,A$:CF=ASC(A$+CHR$(0)):PRINTCF,:NEXTFC:PRINT
340 GET#2,A$:CF=ASC(A$):PRINTCF
350 FORI=1TOCF:FORJ=1TO2:GET#2,A$:PRINTASC(A$+CHR$(0));:NEXTJ:REM LOAD ADDRESS
360 A$="":FOR J=0TO15:GET#2,B$:A$=A$+B$:NEXTJ:PRINTA$:NEXTI
370 CLOSE2
380 INPUT"[196]O YOU WISH TO MAKE A CHANGEN[157][157][157]";A$
390 IFA$="Y"THEN70
400 END
410 L$=RIGHT$(B$,2):H$=MID$(B$,2,LEN(B$)-3)
420 N$=L$:GOSUB450:LB=N
430 HB=0:IFLEN(H$)>0THENN$=H$:GOSUB450:HB=N
440 RETURN
450 EQ=0:REM CONVERT A STRING TO A BYTE
460 LN$=RIGHT$(N$,1)
470 IFLN$=CV$(EQ,0)THENN=VAL(CV$(EQ,1)):GOTO490
480 EQ=EQ+1:GOTO470
490 HN$=LEFT$(N$,1):EQ=0
500 IFHN$=CV$(EQ,0)THENN=N+16*VAL(CV$(EQ,1)):GOTO520
510 EQ=EQ+1:GOTO500
520 RETURN
530 PRINT"[196]ATA FILE CONTENTS:[146]"
540 PRINTBC,B2,T1
550 PRINTCF+1
560 FORI=0TOCF:FORJ=1TO2:PRINTASC(MID$(FD$(I),J,1)+CHR$(0));:NEXTJ
570 PRINTRIGHT$(FD$(I),16):NEXTI
580 INPUT"[196]O YOU WISH TO MAKE A CHANGEN[157][157][157]";A$
590 IFA$="Y"THEN70
600 GOTO260