100 POKE53280,0:POKE53281,0:PRINT"[147]"
110 PRINTTAB(7);"SCREEN TYPING"
120 PRINT" F1 [146] CLEAR SCREEN":PRINT" F3 [146] CHANGE LETTER COLOR"
130 PRINT" F5 [146] CHANGE BORDER COLOR":PRINT" F7 [146] CHANGE SCREEN COLOR"
140 DIMP$(12):L$="[144][159][156][158][129][149][150][151][152][153][154][155]":PRINTCHR$(8)
150 INPUT"ENTER NUMBER OF PEOPLE";N:IFN>12THEN150
160 FORI=1TON
170 PRINT"PERSON NUMBER"I"'S NAME";
180 INPUTP$(I):P$(I)=LEFT$(P$(I),30):NEXTI
190 INPUT"NUMBER OF SECONDS PER TURN";D:D=INT(D):IFD<30THEN190
200 TI$="000000":T1=0:L=0:B=0:S=0:P=0:TU=1
210 REM TYPING LOOP
220 GETA$
230 IFTI>T1THEN510
240 IFA$=""THEN220
250 IFASC(A$)<133THEN270
260 ONASC(A$)-132GOTO340,380,440,470
270 IFA$=CHR$(20)THENPRINTCHR$(29)CHR$(20)CHR$(20)MID$(L$,L+1,1)" [146][157]";:GOTO320
280 IFA$=""ORA$=""ORA$=""ORA$="[147]"ORA$="[145]"ORA$="[157]"ORA$=CHR$(148)THEN220
290 IFA$=CHR$(34)THENA$=CHR$(39)
300 IFA$=CHR$(13)ORA$=CHR$(141)THENPRINTCHR$(29)CHR$(20);
310 PRINTMID$(L$,L+1,1);A$;" [146][157]";
320 IFPEEK(1063)<>96THEN340
330 GOTO220
340 REM CLEAR SCREEN
350 PRINT"[147]";MID$(L$,L+1,1);P$(P):POKE1063,96
360 IFTU=1THENPOKE1024+LEN(P$(P)),42:POKE55296+LEN(P$(P)),L
370 GOTO220
380 REM CHANGE LETTER COLOR
390 L=L+1:IFL>15THENL=0
400 IFL=STHEN390
410 FORQ=0TO2:FORI=55296+QTO56295STEP3:POKEI,L:NEXTI,Q
420 GETJ$:IFJ$<>""THEN420
430 GOTO220
440 REM CHANGE BORDER COLOR
450 B=B+1:IFB>15THENB=0
460 POKE53280,B:GOTO220
470 REM CHANGE SCREEN BACKGROUND COLOR
480 S=S+1:IFS>15THENS=0
490 IFS=LTHEN480
500 POKE53281,S:GOTO220
510 REM NEXT TURN
520 IFTU=0THEN560
530 P=P+1:IFP>NTHENP=1
540 POKE53280,0:POKE53281,0:L=1:B=0:S=0
550 T1=T1+(D*60)-720:TU=0:GOTO340
560 REM 12 MORE SECONDS WARNING
570 TU=1:T1=T1+720:POKE1024+LEN(P$(P)),42:POKE55296+LEN(P$(P)),L
580 GOTO220