10 REM LINES CHANGED FROM VIC MLX VERSION 2.00 ARE 581,582,765
100 PRINT"[147][156]";CHR$(142);CHR$(8);
101 POKE 788,194:REM DISABLE RUN/STOP
110 PRINT"              "
120 PRINT" [146][223][169]   [223][146][223][169][169] "
130 PRINT"  [165]  [146][169][169][223][146][223] "
140 PRINT"              "
200 PRINT"[156][144]MACHINE LANGUAGE":PRINT"EDITOR VER 2.02"
210 PRINT"[144][145][145][145]STARTING ADDRESS":INPUTS:F=1-F:C$=CHR$(31+119*F)
220 IFS<256ORS>32767THENGOSUB3000:GOTO210
225 PRINT:PRINT:PRINT:PRINT
230 PRINT"[144][145][145][145]ENDING ADDRESS":INPUTE:F=1-F:C$=CHR$(31+119*F)
240 IFE<256ORE>32767THENGOSUB3000:GOTO230
250 IFE<STHENPRINTC$;"ENDING < START  ":GOSUB1000:GOTO 230
260 PRINT:PRINT:PRINT
300 PRINT"[147]";CHR$(14):AD=S
310 A=1:PRINTRIGHT$("0000"+MID$(STR$(AD),2),5);":";
315 FOR J=A TO 6
320 GOSUB570:IFN=-1THENJ=J+N:GOTO320
390 IFN=-211THEN 710
400 IFN=-204THEN 790
410 IFN=-206THENPRINT:INPUT"[197]NTER [206]EW [193]DDRESS";ZZ
415 IFN=-206THENIFZZ<SORZZ>ETHENPRINT"OUT OF RANGE":GOSUB1000:GOTO410
417 IFN=-206THENAD=ZZ:PRINT:GOTO310
420 IF N<>-196 THEN 480
430 PRINT:INPUT"[196]ISPLAY:[198]ROM";F:PRINT,"[212]O";:INPUTT
440 IFF<SORF>EORT<SORT>ETHENPRINT"[193]T LEAST";S;"[157], NOT MORE THAN";E:GOTO430
450 FORI=FTOTSTEP6:PRINT:PRINTRIGHT$("0000"+MID$(STR$(I),2),5);":";
455 FORK=0TO5:N=PEEK(I+K):IFK=3THENPRINTSPC(10);
457 PRINTRIGHT$("00"+MID$(STR$(N),2),3);",";
460 GETA$:IFA$>""THENPRINT:PRINT:GOTO310
470 NEXTK:PRINTCHR$(20);:NEXTI:PRINT:PRINT:GOTO310
480 IFN<0 THEN PRINT:GOTO310
490 A(J)=N:NEXTJ
500 CKSUM=AD-INT(AD/256)*256:FORI=1TO6:CKSUM=(CKSUM+A(I))AND255:NEXT
510 PRINTCHR$(18);:GOSUB570:PRINTCHR$(146);
511 IFN=-1THENA=6:GOTO315
515 PRINTCHR$(20):IFN=CKSUMTHEN530
520 PRINT:PRINT"[204]INE [197]NTERED [215]RONG":PRINT"[210]E-ENTER":PRINT:GOSUB1000:GOTO310
530 GOSUB2000
540 FORI=1TO6:POKEAD+I-1,A(I):NEXT
550 AD=AD+6:IF AD<E THEN 310
560 GOTO 710
570 N=0:Z=0
580 PRINT"[166]";
581 GETA$:IFA$=""THEN581
582 AV=-(A$="M")-2*(A$=",")-3*(A$=".")-4*(A$="J")-5*(A$="K")-6*(A$="L")
583 AV=AV-7*(A$="U")-8*(A$="I")-9*(A$="O"):IFA$="H"THENA$="0"
584 IFAV>0THENA$=CHR$(48+AV)
585 PRINTCHR$(20);:A=ASC(A$):IFA=13ORA=44ORA=32THEN670
590 IFA>128THENN=-A:RETURN
600 IFA<>20 THEN 630
610 PRINTCHR$(146);:GOSUB690:IFI=1ANDT=44THENN=-1:PRINT"[157] [157]";:GOTO690
620 GOTO570
630 IFA<48ORA>57THEN580
640 PRINTA$;:N=N*10+A-48
650 IFN>255 THEN A=20:GOSUB1000:GOTO600
660 Z=Z+1:IFZ<3THEN580
670 IFZ=0THENGOSUB1000:GOTO570
680 PRINT",";:RETURN
690 S%=PEEK(209)+256*PEEK(210)+PEEK(211)
692 FORI=1TO3:T=PEEK(S%-I)
695 IFT<>44ANDT<>58THENPOKES%-I,32:NEXT
700 PRINTLEFT$("[157][157][157]",I-1);:RETURN
710 PRINT"[147]*** [211]AVE ***"
720 F$="":INPUT" [198]ILENAME";F$:IFF$=""THEN310
730 PRINT:PRINT"[212][146]APE OR [196][146]ISK: ([212]/[196])"
740 GETA$:IFA$<>"T"ANDA$<>"D"THEN740
750 DV=1-7*(A$="D"):IFDV=8THENF$="0:"+F$:OPEN15,8,15,"S"+F$:CLOSE15
760 T$=F$:ZK=PEEK(53)+256*PEEK(54)-LEN(T$):POKE782,ZK/256
762 POKE781,ZK-PEEK(782)*256:POKE780,LEN(T$):SYS65469
763 POKE780,1:POKE781,DV:POKE782,1:SYS65466
765 K=S:POKE254,K/256:POKE253,K-PEEK(254)*256:POKE780,253
766 K=E+1:POKE782,K/256:POKE781,K-PEEK(782)*256:SYS65496
770 IF(PEEK(783)AND1)OR(191ANDST)THEN780
775 PRINT"[196]ONE.":GOTO310
780 PRINT"[197]RROR ON [211]AVE.  [212]RY AGAIN.":IFDV=1THEN720
781 OPEN15,8,15:INPUT#15,E1$,E2$:PRINTE1$;E2$:CLOSE15:GOTO720
782 GOTO720
790 PRINT"[147]*** [204]OAD ***"
800 F$="":INPUT" [198]ILENAME";F$:IFF$=""THEN310
810 PRINT:PRINT"[212][146]APE OR [196][146]ISK: ([212]/[196])"
820 GETA$:IFA$<>"T"ANDA$<>"D"THEN820
830 DV=1-7*(A$="D"):IFDV=8THENF$="0:"+F$
840 T$=F$:ZK=PEEK(53)+256*PEEK(54)-LEN(T$):POKE782,ZK/256
841 POKE781,ZK-PEEK(782)*256:POKE780,LEN(T$):SYS65469
845 POKE780,1:POKE781,DV:POKE782,1:SYS65466
850 POKE780,0:SYS65493
860 IF(PEEK(783)AND1)OR(191ANDST)THEN870
865 PRINT"[196]ONE.":GOTO310
870 PRINT"[197]RROR ON [204]OAD.  [212]RY AGAIN.":IFDV=1THEN800
880 OPEN15,8,15:INPUT#15,E1$,E2$:PRINTE1$;E2$:CLOSE15:GOTO800
1000 REM BUZZER
1001 POKE36878,15:POKE36874,190
1002 FORW=1TO300:NEXTW
1003 POKE36878,0:POKE36874,0:RETURN
2000 REM BELL SOUND
2001 FORW=15TO0STEP-1:POKE36878,W:POKE36876,240:NEXTW
2002 POKE36876,0:RETURN
3000 PRINTC$;"NOT ZERO PAGE OR ROM":GOTO1000