1 SYS65517:IFPEEK(781)=40THENA=40:POKE53281,1:GOTO5
2 A=22
5 PRINT"[147]"TAB((A-8)/2)"[144]AVAIL":FORI=1TO2000:NEXT
10 DIMW$(20),X$(20),IN$(20):PRINT"[147]"
20 PRINT:PRINT"?:";:GOSUB30:IN$=B$:B$="":GOTO60:REM MAIN PROGRAM STARTS @ 20
30 GETC$:PRINTC$;:IFC$=CHR$(13)THENRETURN
40 IFC$=CHR$(20)THENB$=LEFT$(B$,LEN(B$)-1):GOTO30
50 B$=B$+C$:GOTO30
60 L=LEN(IN$):P=1:W=1
70 FORI=1TOL:IFMID$(IN$,I,1)=" "THENGOSUB200
80 NEXT
90 W$(W)=MID$(IN$,P)
100 E$=RIGHT$(W$(W),1):IFE$="."ORE$="?"ORE$="!"THEN120
110 GOTO130
120 W$(W)=LEFT$(W$(W),LEN(W$(W))-1)
130 FORJ=1TOW:X$(J)=W$(J):NEXT
140 GOSUB210
150 PRINT" OK?";
160 GETOK$:IFOK$=""THEN160
170 IFOK$="N"THENGOSUB410
180 J=W:IN$(C)=IN$:C=C+1:IFC>19THENC=0
190 IN$="":GOTO20
200 W$(W)=MID$(IN$,P,I-P):P=I:W=W+1:RETURN
210 PRINT:PRINT:FORI=1TOW
220 IFX$(I)="WAS"ORX$(I)=" WAS"THENW$(I)=" WERE"
230 IFX$(I)="I"ORX$(I)=" I"ORX$(I)=" ME"ORLEFT$(X$(I),2)="I'"THENW$(I)=" YOU"
240 IFX$(I)=" WERE"THENW$(I)=" WAS"
250 IFX$(I)=" MY"THENW$(I)=" YOUR"
260 IFX$(I)=" AM"THENW$(I)=" ARE"
270 IFX$(I)="YOU"ORX$(I)=" YOU"THENW$(I)=" I"
280 IFX$(I)="YOU'RE"ORX$(I)=" YOU'RE"THENW$(I)=" I'M"
290 IFX$(I)="YOUR"ORX$(I)=" YOUR"THENW$(I)=" MY"
300 IFRIGHT$(X$(I),2)="'S"THENW$(I)=LEFT$(X$(I),LEN(X$(I))-2)+" IS"
310 IFRIGHT$(X$(I),3)="I'M"THENW$(I)=LEFT$(X$(I),LEN(X$(I))-3)+"YOU ARE"
320 IFX$(I+1)=" ARE"ANDX$(I)+X$(I+1)="YOU ARE"THENW$(I+1)="'M"
330 IFRIGHT$(X$(I),3)="'VE"THENW$(I)=LEFT$(X$(I),LEN(X$(I))-3)+" HAVE"
340 IFRIGHT$(X$(I),2)="'D"THENW$(I)=LEFT$(X$(I),LEN(X$(I))-2)+" WOULD"
350 IFRIGHT$(X$(I),4)=" THE"THENW$(I)=LEFT$(X$(I),LEN(X$(I))-4):REM DELETE"THE"
360 IFRIGHT$(X$(I),3)=" AN"THENW$(I)="":REM DELETE"AN"
370 IFRIGHT$(X$(I),2)=" A"THENW$(I)=X$(I+1)
380 NEXT
390 FORI=1TOJ+1:PRINTW$(I);:NEXT
400 RETURN
410 X=INT(7*RND(0))+1:PRINT" NO? ";
420 ONXGOTO430,440,450,460,470,480,490
430 PRINT"WHAT'D YOU EXPECT ME TO SAY?  ";IN$(X):RETURN
440 PRINT"IN WHAT WAY? ";:RETURN
450 PRINT"I DON'T UNDERSTAND ";:RETURN
460 PRINT"REALLY? ";:RETURN
470 PRINT:RETURN
480 PRINT"WHY? ";:RETURN
490 PRINT:RETURN