5 PRINT"[147]"
10 L=12:SYS65517:A=PEEK(781):Q$=CHR$(13):IFA=40THENPOKE53281,15:L=200
20 DIMM$(L,6),N$(6):FORI=1TO6:READN$(I):NEXT
30 DATALAST NAME,FIRST NAME,ADDRESS,CITY/STATE,ZIP CODE,TELEPHONE
40 PRINT"[147][144]ADDRESS FILE"Q$"1..RETRIEVE FILE"Q$"2..ADD/START FILE"
50 PRINT"3..EDIT FILE"Q$"4..DISPLAY FILE"Q$"5..SAVE AND END"
60 INPUT"YOUR CHOICE";B:ONBGOSUB450,70,130,240,450:GOTO40
70 N=N+1:PRINT"[147]RECORD #"N:FORJ=1TO6:PRINTQ$"[144]";N$(J);"[146]":INPUTM$(N,J)
80 NEXTJ:PRINT" N[146]EXT D[146]ELETE E[146]ND"
90 GETA$:IFA$=""OR(A$<>"D"ANDA$<>"N"ANDA$<>"E")THEN90
100 IFA$="N"THEN70
110 IFA$="E"THEN40
120 N=N-1:GOTO70
130 GOSUB660:FORI=1TON:IFB$=M$(I,1)THEN150
140 NEXTI:PRINT"[147]"B$"IS NOT IN FILE.":GOSUB620:GOTO40
150 GOSUB650:PRINT"CHANGE WHAT:":FORJ=1TO6:PRINT""J".."N$(J):NEXT
160 PRINT"7 ..DELETE ENTRY":INPUT"YOUR CHOICE";J:IFJ<1ORJ>7THEN160
170 IFJ=7THEN210
180 PRINT"[147]"M$(I,1)", "M$(I,2)
190 PRINT"[144]OLD "N$(J)" IS":PRINTM$(I,J)Q$Q$"[144]CORRECTED "N$(J)" IS"
200 INPUTM$(I,J):GOSUB620:GOTO220
210 FORA=ITON-1:FORJ=1TO6:M$(A,J)=M$(A+1,J):NEXTJ,A:N=N-1
220 PRINT"[147]DO YOU WISH TO:"Q$"1..CONTINUE EDITING"Q$"2..RETURN TO MENU"
230 INPUT"YOUR CHOICE";B:ONBGOTO130,40:GOTO230
240 PRINT"[147][144]WHICH DO YOU WANT"Q$"1..ALPHABETICAL"Q$"2..INDIVIDUAL"
250 PRINT"3..MENU":INPUT"YOUR CHOICE";B:ONBGOTO260,410,40:GOTO250
260 G=N:IFN=0THENPRINT"NO RECORDS IN FILE.":FORI=1TO2000:NEXT:GOTO40
270 G=INT(G/2)
280 IFG=0THEN380
290 FORA=1TON-G
300 IFM$(A,1)<=M$(A+G,1)THEN350
310 R$=M$(A,1):S$=M$(A,2):T$=M$(A,3):U$=M$(A,4):V$=M$(A,5):W$=M$(A,6)
320 FORJ=1TO6:M$(A,J)=M$(A+G,J):NEXT
330 M$(A+G,1)=R$:M$(A+G,2)=S$:M$(A+G,3)=T$:M$(A+G,4)=U$:M$(A+G,5)=V$
340 M$(A+G,6)=W$:E=A
350 NEXTA
360 IFE=0THEN270
370 E=0:GOTO280
380 PRINT"[147]":L=0:FORI=1TON:L=L+1:PRINTM$(I,1)", "M$(I,2):IFL<>10THEN400
390 L=0:GOSUB620:PRINT"[147]"
400 NEXTI:GOSUB620:GOTO240
410 GOSUB660:FORI=1TON:IFB$=M$(I,1)THEN440
420 NEXTI
430 PRINT"[147]";B$:PRINT"IS NOT IN FILE":GOSUB620:GOTO240
440 GOSUB650:GOSUB620:GOTO240
450 PRINT"[147]DISK OR CASSETTE (D/C)"
460 GETE$:IF(E$<>"D"ANDE$<>"C")ORE$=""THEN460
470 IFE$="D"THENF$="@0:ADDRESSES":F=1:GOTO490
480 F$="ADDRESSES":F=0:G$=""
490 IFB=5THEN540
500 IFF=1THENG$=",S,R"
510 OPEN1,1+7*F,8*F,F$+G$:GOSUB580
520 INPUT#1,N:FORI=1TON:FORJ=1TO6
530 INPUT#1,M$(I,J):NEXT:NEXT:GOSUB580:CLOSE1:GOSUB580:GOTO40
540 IFF=1THENG$=",S,W"
550 OPEN1,1+7*F,1+7*F,F$+G$:GOSUB580
560 PRINT#1,N:FORI=1TON:FORJ=1TO6
570 PRINT#1,M$(I,J):NEXT:NEXT:GOSUB580:CLOSE1:GOSUB580:END
580 IFF=0THENRETURN
590 IFO=0THENOPEN15,8,15:O=1
600 INPUT#15,A,B$,C,D:IFATHENPRINTA,B$,C,D:STOP
610 RETURN
620 PRINT"[144]ANY KEY TO CONT'"
630 GETA$:IFA$=""THEN630
640 RETURN
650 PRINT"[147]"M$(I,1)", "M$(I,2)Q$M$(I,3)Q$M$(I,4)" "M$(I,5)Q$M$(I,6):RETURN
660 PRINT"[147]WHAT NAME DO YOU"Q$"WANT (LAST NAME)?":INPUT"";B$:RETURN