5 BO=53280:BA=53281
10 DIMAA$(101),BB$(101),C$(101):GOTO37
20 FORI=1TO80:PRINT" [146]";:NEXT:RETURN
30 POKE781,R:POKE782,C:POKE783,PEEK(783)AND254:SYS65520:RETURN
35 REM ***** MAIN MENU *****
37 POKEBO,12:POKEBA,12:PRINT"[147][144]"
40 PRINT"[144]":GOSUB20:PRINT"       1-EXIT    2-LOAD    3-SAVE       ";
45 GOSUB20:PRINT"    4-EDIT  5-CLEAR  6-PRINT  7-QUIZ    ";:GOSUB20
50 GETA$:IFA$=""THEN50
55 A=ASC(A$)-48:IFA<1ORA>7THEN50
60 ONAGOTO65,380,330,119,440,458,625
65 R=10:C=5:GOSUB30:PRINT"     ARE YOU SURE ? (Y/N)"
70 GETA$:IFA$=""THEN70
75 IFA$="Y"THENPRINT"[147]":END
80 GOTO37
118 REM ### EDIT MENU ###
119 POKEBO,1:POKEBA,1:PRINT"[147]":GOSUB20
120 PRINT"   1-EXIT  2-ENTER  3-LIST  4-MODIFY    ";:GOSUB20
130 GETA$:IFA$=""THEN130
140 A=ASC(A$)-48:IFA<1ORA>4THEN130
150 ONAGOTO37,155,230,1000
151 REM #### INPUT Q+A ####
155 Z=X:POKEBO,1:POKEBA,1
160 PRINT"[147]":GOSUB20:PRINT"  1-EXIT  2-ENTER QUESTION AND ANSWER   ";:GOSUB20
170 R=9:C=0:GOSUB30
171 GETA$:IFA$=""THEN171
172 IFA$="1"THEN119
173 IFA$="2"THEN175
174 GOTO171
175 Z=Z+1:X=X+1:IFX>101THENX=101:Z=101:GOTO200
180 POKE19,64:PRINT"QUESTION #"Z:INPUTAA$(Z):POKE19,0
185 IFAA$(Z)=""THENZ=Z-1:X=X-1:GOTO160
190 POKE19,64:PRINT:PRINT"ANSWER #"Z:INPUTBB$(Z):POKE19,0
195 IFBB$(Z)=""THENZ=Z-1:X=X-1:GOTO160
199 GOTO160
200 PRINT"BUFFER FULL":FORI=1TO1500:NEXT:GOTO119
210 GOTO160
215 REM ### LIST ###
230 POKEBO,1:POKEBA,1:PRINT"[147][144]":R=24:C=0:GOSUB30
240 FORZ=1TOX
245 PRINTZ;AA$(Z):WAIT653,1,1
250 PRINTZ;BB$(Z):WAIT653,1,1
252 FORI=1TO150:NEXTI:NEXTZ
260 PRINT"          HIT RETURN TO EXIT           ";
270 IFPEEK(197)=1THENPOKE198,0:GOTO119
275 GOTO270
328 REM ##### SAVE #####
330 PRINT"[147][151]"
335 GOSUB20:PRINT"      1-EXIT     2-TAPE     3-DISK      ";:GOSUB20
337 PRINT"                  SAVE                  [146]";
340 GETA$:IFA$=""THEN340
342 IFA$="1"THENGOTO37
345 R=10:C=0:GOSUB30:POKE19,64:INPUT"FILE NAME ";N$:PRINT:POKE19,0
350 IFA$="2"THENOPEN2,1,1,N$:GOTO360
355 OPEN2,8,2,"@0:Q"+N$+",S,W"
360 FORI=1TOX
365 PRINT#2,AA$(I)
370 PRINT#2,BB$(I)
375 NEXT:PRINT#2,"QQ":CLOSE2:PRINT"[147]":GOTO40
377 REM ##### LOAD #####
380 PRINT"[147]"
385 GOSUB20:PRINT"      1-EXIT     2-TAPE     3-DISK      ";:GOSUB20
387 PRINT"                  LOAD                  [146]";
390 GETA$:IFA$=""THEN390
392 IFA$="1"THENGOTO37
395 R=10:C=0:GOSUB30:POKE19,64:INPUT"FILE NAME ";N$:POKE19,0:IFX<>0THENX=X+1
397 IFX=0THENX=1
398 I=X
400 IFA$="2"THENOPEN2,1,0,N$:GOTO415
405 OPEN2,8,2,"0:Q"+N$+",S,R"
415 INPUT#2,A$
417 IFA$="QQ"THENCLOSE2:X=X-1:PRINT"[147]":GOTO40
418 AA$(I)=A$
420 INPUT#2,B$
422 IFB$="QQ"THENCLOSE2:X=X-1:PRINT"[147]":GOTO40
423 BB$(I)=B$
425 I=I+1:X=I:IFX>101THENX=101:CLOSE2:PRINT"[147]":GOTO40
430 GOTO415
435 REM ###### CLEAR ######
440 R=10:C=0:GOSUB30:PRINT"ARE YOU SURE YOU WANT TO CLEAR? (Y/N)"
445 GETA$:IFA$=""THEN445
450 IFA$="N"THEN37
455 CLR:GOTO10
456 REM ###### PRINT ######
458 POKEBO,3:POKEBA,3:PRINT"[147][144]"
460 GOSUB20:PRINT"    1-EXIT   2-QUESTIONS AND ANSWERS    ";
465 PRINT"                                        ";
470 PRINT"   3-QUESTIONS ONLY    4-ANSWERS ONLY   ";:GOSUB20
475 GETA$:IFA$=""THEN475
480 IFA$="1"THEN35
485 R=10:C=0:GOSUB30:POKE19,64:PRINT"HOW MANY COPYS? ";:INPUTB:OPEN4,4
490 IFA$="3"THENFORT=1TOB:GOTO560
495 IFA$="4"THENFORT=1TOB:GOTO590
500 IFA$="2"THENFORT=1TOB:GOTO520
510 GOTO475
520 L=2:FORI=1TOX
530 PRINT#4,"Q. ";AA$(I)
535 PRINT#4
540 PRINT#4,"A. ";BB$(I)
545 PRINT#4:L=L+4
547 IFL>64THENFORR=1TO3:PRINT#4:NEXTR:L=2
550 NEXTI:FORR=LTO67:PRINT#4:NEXTR:L=2:NEXTT:CLOSE4:GOTO458
560 L=2:FORI=1TOX
570 PRINT#4,I". ";AA$(I)
575 PRINT#4:PRINT#4:L=L+3
577 IFL>64THENFORR=1TO3:PRINT#4:NEXTR:L=2
580 NEXTI:FORR=LTO67:PRINT#4:NEXTR:L=2:NEXTT:CLOSE4:GOTO458
590 L=2:FORI=1TOX
600 PRINT#4,I". ";BB$(I)
605 PRINT#4:L=L+2
607 IFL>64THENFORR=1TO3:PRINT#4:NEXTR:L=2
610 NEXTI:FORR=LTO67:PRINT#4:NEXTR:L=2:NEXTT:CLOSE4:GOTO458
620 REM ##### QUIZ #####
625 FORT=1TOX:C$(T)="1":NEXT:Z=1:L=0:W=0
630 POKE53280,1:POKE53281,1:PRINT"[147]"
640 GOSUB20:PRINT"              ULTRAQUIZ 64              ";:GOSUB20
650 R=10:C=0:GOSUB30:IFZ>XTHEN730
660 K=INT(RND(1)*X)+1
670 IFC$(K)=""THEN660
680 C$(K)="":R=10:C=0:GOSUB30
690 PRINTZ;AA$(K):Z=Z+1
700 PRINT:POKE19,64:INPUTA$:POKE19,0
710 IFA$=BB$(K)THENPRINT:PRINT"CORRECT":L=L+1:FORI=1TO500:NEXT:GOTO630
720 PRINT:PRINT"WRONG ANSWER, THE CORRECT ANSWER IS ":PRINTBB$(K):W=W+1
722 PRINT" HIT ANY KEY TO CONTINUE"
723 GETL$:IFL$=""THEN723
724 GOTO630
730 PRINT"YOU GOT"L"RIGHT AND"W"WRONG."
735 S=L/(L+W)*100
740 PRINT:PRINT"YOUR SCORE IS"S
750 PRINT:PRINT"TRY AGAIN (Y/N)?"
760 GETA$:IFA$=""THEN760
770 IFA$="Y"THEN625
780 GOTO37
999 REM **** MODIFY ****
1000 PRINT:PRINTTAB(13)"1":POKE19,64
1010 PRINT"[145][145]":INPUT"MODIFY FROM  ";Z:POKE19,0:PRINT"":GOTO1035
1015 PRINT""
1020 PRINT"[147]":GOSUB20:PRINT"    1-EXIT  2-MODIFY TEXT  3-SKIP       ";:GOSUB20
1030 R=9:C=0:GOSUB30:RETURN
1035 IFZ>XTHEN119
1040 GOSUB1015:PRINT"[144]QUESTION #"Z:PRINTAA$(Z)
1050 GETA$:IFA$=""THEN1050
1060 IFA$="1"THEN119
1070 IFA$="2"THEN1100
1080 IFA$="3"THEN1120
1090 GOTO1050
1100 POKE19,64:R=9:C=19:GOSUB30:PRINT" ENTER NEW QUESTION ":INPUTA$:POKE19,0
1110 AA$(Z)=A$
1120 GOSUB1015:PRINT"[144]ANSWER #"Z:PRINTBB$(Z)
1130 GETA$:IFA$=""THEN1130
1140 IFA$="1"THEN119
1150 IFA$="2"THEN1200
1160 IFA$="3"THENZ=Z+1:GOTO1035
1170 GOTO1130
1200 POKE19,64:R=9:C=19:GOSUB30:PRINT"  ENTER NEW ANSWER  ":INPUTA$:POKE19,0
1210 BB$(Z)=A$:Z=Z+1:GOTO1035