1 DIMDA$(25,29),FC$(25,29),CU$(2),DA(25,29)
5 CU$(1)=CHR$(18)+" "+CHR$(146)+CHR$(157):CU$(2)=" "+CHR$(157)
6 PA=1:Z=0:P=100
20 GOSUB10000
30 PRINTCHR$(19);
40 FORT=1TO10:GETG$:NEXT
50 IN$=""
52 DE=0
54 PRINTCU$(PA);
56 DE=DE+1
60 GETG$
61 IFG$=CHR$(34)THEN60
62 IFG$<>""THEN70
65 IFDE<24THEN54
68 PA=3-PA
70 IFG$=CHR$(29)THENIFC<27THENC=C+1:GOSUB10000:GOTO30
71 IFG$=CHR$(145)THENIFRD>0THENRD=RD-1:GOSUB10000:GOTO30
72 IFG$=CHR$(19)THENC=0:RD=0:GOTO9900
73 IFG$="_"THEN22000
74 IFG$=CHR$(147)THEN350
75 IFG$=CHR$(17)THENIFRD<6THENRD=RD+1:GOSUB10000:GOTO30
76 IFG$=CHR$(29)ORG$=CHR$(145)ORG$=CHR$(17)THEN60
77 IFG$=CHR$(136)AND(PEEK(53281)AND15)<15THENPOKE53281,(PEEK(53281)+1):GOTO60
78 IFG$=CHR$(136)AND(PEEK(53281)AND15)=15THENPOKE53281,0:GOTO60
79 IFG$=CHR$(137)THEN400
80 IFG$=CHR$(157)THENIFC>0THENC=C-1:GOSUB10000:GOTO30
81 IFG$=CHR$(133)THENPRINTCHR$(18);"F";CHR$(146);:GOTO140
82 IFG$=CHR$(139)THEN13000
83 IFG$=CHR$(140)AND(PEEK(53280)AND15)=15THENPOKE53280,0:GOTO60
84 IFG$=CHR$(140)AND(PEEK(53280)AND15)<15THENPOKE53280,PEEK(53280)+1:GOTO60
85 IFG$=CHR$(134)THEN24000
86 IFG$=CHR$(138)THEN25000
87 IFG$=CHR$(135)THEN13400
90 IFG$=CHR$(13)THEN300
100 IFG$=CHR$(20)THEN200
125 IFLEN(IN$)>30THEN52
130 PRINTG$;
140 IN$=IN$+G$
199 GOTO52
200 IFLEN(IN$)=0THEN60
210 IFLEN(IN$)=1THENPRINTCHR$(20);:GOTO50
220 IN$=LEFT$(IN$,LEN(IN$)-1):PRINTCHR$(20);
230 GOTO60
300 IFLEFT$(IN$,1)<"A"ORLEFT$(IN$,1)>"Z"THEN20000
305 IFMID$(IN$,2,1)<"0"ORMID$(IN$,2,1)>"9"THEN20000
306 IFMID$(IN$,3,1)<"0"ORMID$(IN$,3,1)>":"THEN20000
310 IFVAL(MID$(IN$,2,2))<0ORVAL(MID$(IN$,2,2))>29THEN20000
320 IFMID$(IN$,3,1)<>":"ANDMID$(IN$,4,1)<>":"THEN20000
330 GOTO500
350 GOSUB12500:IFG$="N"THEN9900
355 GOSUB12550
360 FORR=0TO25:FORCD=0TO29
370 DA$(R,CD)="":FC$(R,CD)="":DA(R,CD)=0
380 NEXT:NEXT:Z=0
390 GOTO9900
400 PRINTCHR$(19);:PRINT
410 PRINTCHR$(18);" MAXIMUM PRECISION (0 TO 6) PRESS KEY "
420 GETG$:IFG$<"0"ORG$>"6"THEN420
430 P=10^VAL(G$)
440 GOTO9900
500 GOSUB12000
520 IFMID$(IN$,3,1)=":"THENS=4:GOTO540
530 IFMID$(IN$,4,1)=":"THENS=5
540 IFMID$(IN$,S,1)=CHR$(133)THEN2000
550 IFMID$(IN$,S,1)=""THENDA$(R,CD)="":DA(R,CD)=0:GOTO9900
1450 IFFC$(R,CD)<>""THENGOTO11000
1500 T$=MID$(IN$,S,1)
1510 IFT$<"0"ORT$>"9"THENIFT$<>"+"ANDT$<>"-"THEN1560
1512 DA(R,CD)=VAL(MID$(IN$,S,19))
1513 DA$(R,CD)=MID$(IN$,S,19)
1515 IFLEN(DA$(R,CD))=9THEN1590
1518 IFLEN(DA$(R,CD))>9THEN1580
1520 FORX=1TO9-LEN(DA$(R,CD))
1530 DA$(R,CD)=" "+DA$(R,CD)
1540 NEXT
1545 GOTO9900
1560 DA$(R,CD)=MID$(IN$,S,9):GOTO9900
1580 DA$(R,CD)="*********"
1590 GOTO9900
2000 IFMID$(IN$,S+1,1)="T"ANDLEN(IN$)=S+1THEN2010
2005 GOTO2020
2010 IFCD<>0ANDR<>0THEN20000
2015 Z=1:CT=CD:RT=0:GOTO9900
2020 IFMID$(IN$,S+1,1)="O"ANDLEN(IN$)=S+1THEN2030
2025 GOTO2040
2030 Z=0:GOTO9900
2040 IFMID$(IN$,S+1,3)="SUM"THENGOSUB14000:GOTO9900
2050 IFMID$(IN$,S+1,3)="MIN"THENGOSUB14000:GOTO9900
2060 IFMID$(IN$,S+1,3)="MAX"THENGOSUB14000:GOTO9900
2070 IFMID$(IN$,S+1,3)="AVG"THENGOSUB14000:GOTO9900
2080 IFMID$(IN$,S+1,3)="COP"THENGOSUB14000:GOSUB26010:GOTO2085
2081 GOTO2110
2085 IFR1=R2THEN2100
2088 FORX=R1TOR2
2090 DA(X,C1)=DA(R,CD):DA$(X,C1)=DA$(R,CD)
2095 NEXT:GOTO9900
2100 FORX=C1TOC2
2103 DA(R1,X)=DA(R,CD):DA$(R1,X)=DA$(R,CD)
2106 NEXT:GOTO9900
2110 IFMID$(IN$,S+1,1)="C"ANDLEN(IN$)=S+1THEN2120
2115 GOTO2130
2120 GOSUB12500
2125 IFG$="N"THENGOTO9900
2128 DA(R,CD)=0:DA$(R,CD)="":FC$(R,CD)="":GOTO9900
2130 IFMID$(IN$,S+1,1)="V"ANDLEN(IN$)=S+1THEN2140
2135 GOTO2150
2140 GOSUB12600:GOTO9900
2145 GOTO9900
2150 IFMID$(IN$,S+1,1)="J"ANDLEN(IN$)=S+1THEN2160
2155 GOTO2500
2160 C=VAL(MID$(IN$,2,2)):IFC>27THENC=27
2162 IFASC(LEFT$(IN$,1))>84THENRD=6
2163 IFASC(LEFT$(IN$,1))<=84THENRD=0
2165 GOTO9900
2500 IFMID$(IN$,S+1,1)<"A"ORMID$(IN$,S+1,1)>"Z"THEN20000
2505 IFMID$(IN$,S+2,1)<"0"ORMID$(IN$,S+2,1)>"9"THEN20000
2510 IFVAL(MID$(IN$,S+2,2))<0ORVAL(MID$(IN$,S+2,2))>29THEN20000
2580 T$=MID$(IN$,S+3,1)
2590 IFT$="+"ORT$="-"ORT$="*"ORT$="/"ORT$="^"THEN2650
2600 T$=MID$(IN$,S+4,1)
2610 IFT$="+"ORT$="-"ORT$="*"ORT$="/"ORT$="^"THEN2670
2620 GOTO20000
2650 S1=S+4:GOTO2680
2670 S1=S+5
2680 IFMID$(IN$,S1,1)<"A"ORMID$(IN$,S1,1)>"Z"THEN3000
2690 IFMID$(IN$,S1+1,1)<"0"ORMID$(IN$,S1+1,1)>"9"THEN20000
2700 IFVAL(MID$(IN$,S1+1,2))<0ORVAL(MID$(IN$,S1+1,2))>29THEN20000
2710 GOTO3100
3000 IFT$="/"ANDVAL(MID$(IN$,S1,19))=0THEN20000
3100 FC$(R,CD)=MID$(IN$,S,19)
9900 GOSUB10000
9910 PRINTCHR$(19);
9999 GOTO50
10000 PRINTCHR$(147)
10010 PRINTCHR$(18);"                                        "
10015 IFZ=1THENPRINTTAB(5);CT;TAB(16);C+1;TAB(27);C+2:GOTO10021
10020 PRINTTAB(5);C;TAB(16);C+1;TAB(27);C+2
10021 IFZ=1THEN10026
10022 PRINTCHR$(65+RD);:PRINTTAB(2);DA$(RD,C);
10023 PRINTTAB(13);DA$(RD,C+1);
10024 PRINTTAB(24);DA$(RD,C+2)
10025 GOTO10030
10026 PRINTCHR$(65+RT);:PRINTTAB(2);DA$(RT,CT);
10027 PRINTTAB(13);DA$(RT,C+1);
10028 PRINTTAB(24);DA$(RT,C+2)
10030 FORR=RD+1TORD+19
10040 PRINTCHR$(65+R);
10045 IFZ=1THENPRINTTAB(2);DA$(R,CT);:GOTO10060
10050 PRINTTAB(2);DA$(R,C);
10060 PRINTTAB(13);DA$(R,C+1);
10070 PRINTTAB(24);DA$(R,C+2)
10080 NEXT
10090 RETURN
11000 PRINTCHR$(19);:PRINT
11005 PRINTCHR$(18);"PROTECTED FORMULA  ";FC$(R,CD)
11010 GETG$:IFG$=""THEN11010
11020 GOTO20
12000 R=ASC(LEFT$(IN$,1))-65
12010 CD=VAL(MID$(IN$,2,2))
12020 RETURN
12500 PRINTCHR$(19);:PRINT
12505 PRINTCHR$(18);" ARE YOU SURE PRESS 'Y' OR 'N' "
12510 GETG$:IFG$<>"Y"ANDG$<>"N"THEN12510
12520 RETURN
12550 PRINTCHR$(19);:PRINT
12555 PRINTCHR$(18);" WORKING    PLEASE WAIT...        "
12560 RETURN
12600 PRINTCHR$(19);:PRINT
12605 PRINTCHR$(18);
12606 IFFC$(R,CD)<>""THENPRINT"FORM. ";FC$(R,CD);" - ";
12607 PRINT"VAL.";DA(R,CD)
12610 GETG$:IFG$=""THEN12610
12620 RETURN
13000 PRINTCHR$(19);:PRINT
13005 PRINTCHR$(18);"PRESS 'SPACE' TO PRINT-'RETURN' TO EXIT"
13010 GETG$:IFG$<>CHR$(32)ANDG$<>CHR$(13)THEN13010
13020 IFG$=CHR$(13)THEN9900
13030 OPEN4,4
13040 R=0:CD=0
13050 IFFC$(R,CD)<>""THEN13080
13060 CD=CD+1:IFCD=30THENCD=0:R=R+1:IFR=26THEN13300
13070 GOTO13050
13080 PRINT#4,CHR$(R+65);CD;
13090 PRINT#4,CHR$(16)"06";FC$(R,CD);
13100 CD=CD+1:IFCD=30THENCD=0:R=R+1:IFR=26THEN13300
13110 IFFC$(R,CD)<>""THEN13140
13120 CD=CD+1:IFCD=30THENCD=0:R=R+1:IFR=26THEN13300
13130 GOTO13110
13140 PRINT#4,CHR$(16)"20";CHR$(R+65);CD;
13150 PRINT#4,CHR$(16)"26";FC$(R,CD);
13160 CD=CD+1:IFCD=30THENCD=0:R=R+1:IFR=26THEN13300
13170 IFFC$(R,CD)<>""THEN13200
13180 CD=CD+1:IFCD=30THENCD=0:R=R+1:IFR=26THEN13300
13190 GOTO13170
13200 PRINT#4,CHR$(16)"40";CHR$(R+65);CD;
13210 PRINT#4,CHR$(16)"46";FC$(R,CD);
13220 CD=CD+1:IFCD=30THENCD=0:R=R+1:IFR=26THEN13300
13230 IFFC$(R,CD)<>""THEN13260
13240 CD=CD+1:IFCD=30THENCD=0:R=R+1:IFR=26THEN13300
13250 GOTO13230
13260 PRINT#4,CHR$(16)"60";CHR$(R+65);CD;
13270 PRINT#4,CHR$(16)"46";FC$(R,CD)
13280 GOTO13060
13300 PRINT#4,CHR$(10)
13310 PRINT#4
13320 CLOSE4:GOTO9900
13400 PRINTCHR$(147):PRINT"          PRINT SPREADSHEET"
13410 PRINT:PRINT
13420 PRINT"     ENTER THE TOP LEFT CELL
13430 [153]"         TO BE PRINTED OR
13440 PRINT"      PRESS 'RETURN' TO EXIT"
13450 PRINT:G$=""
13460 INPUT"              ";G$:IFG$=""THEN9900
13465 IFG$<"A0"ORG$>"Z9"THEN13400
13467 R1=ASC(LEFT$(G$,1))-65:TC=VAL(MID$(G$,2)):IFTC>29THEN13400
13470 PRINTCHR$(147):PRINT"          PRINT SPREADSHEET"
13472 PRINT:PRINT
13474 PRINT"    ENTER THE BOTTOM RIGHT CELL
13476 [153]"         TO BE PRINTED OR
13478 PRINT"      PRESS 'RETURN' TO EXIT"
13480 PRINT:T$=""
13482 INPUT"              ";T$:IFT$=""THEN9900
13484 IFT$<"A0"ORT$>"Z9"THEN13470
13486 R2=ASC(LEFT$(T$,1))-65:T=VAL(MID$(T$,2)):IFT<TCTHEN13470
13487 IFR2<R1THEN13470
13488 GOSUB13700
13490 T$=CHR$(16)
13500 OPEN4,4
13505 PRINT#4,CHR$(10)
13525 FORR=R1TOR2
13535 IFTC>TTHEN13700
13540 PRINT#4,T$;"03";DA$(R,TC);
13545 IFTC+1>TTHEN13600
13550 PRINT#4,T$;"14";DA$(R,TC+1);
13555 IFTC+2>TTHEN13600
13560 PRINT#4,T$;"25";DA$(R,TC+2);
13565 IFTC+3>TTHEN13600
13570 PRINT#4,T$;"36";DA$(R,TC+3);
13575 IFTC+4>TTHEN13600
13577 PRINT#4,T$;"47";DA$(R,TC+4);
13580 IFTC+5>TTHEN13600
13585 PRINT#4,T$;"58";DA$(R,TC+5);
13590 IFTC+6>TTHEN13600
13595 PRINT#4,T$;"69";DA$(R,TC+6);
13600 PRINT#4,CHR$(13);:NEXT
13610 TC=TC+7:IFTC>TTHENPRINT#4:CLOSE4:GOTO9900
13620 PRINTCHR$(147):PRINT:PRINT
13630 PRINT"      ...... MORE TO COME ......"
13635 PRINT
13640 PRINT"      PLEASE ALIGN PRINTER PAPER"
13650 PRINT"     AND PRESS 'SPACE' TO CONTINUE"
13655 GETG$:IFG$<>" "THEN13655
13656 GOSUB13700
13660 GOTO13505
13700 PRINTCHR$(147):PRINT:PRINT
13710 PRINT"      ......    WORKING   ......"
13720 RETURN
14000 S=S+3
14010 IFMID$(IN$,S+1,1)<"A"ORMID$(IN$,S+1,1)>"Z"THEN20000
14020 IFMID$(IN$,S+2,1)<"0"ORMID$(IN$,S+2,1)>"9"THEN20000
14030 IFMID$(IN$,S+3,1)<"-"ORMID$(IN$,S+3,1)>"9"THEN20000
14040 IFVAL(MID$(IN$,S+2,2))<0ORVAL(MID$(IN$,S+2,2))>29THEN20000
14050 IFMID$(IN$,S+3,1)<>"-"ANDMID$(IN$,S+4,1)<>"-"THEN20000
14060 IFMID$(IN$,S+4,1)="-"THENS1=5:GOTO14070
14065 S1=4
14070 IFMID$(IN$,S+S1,1)<"A"ORMID$(IN$,S+S1,1)>"Z"THEN20000
14090 IFMID$(IN$,S+S1+1,1)<"0"ORMID$(IN$,S+S1+1,1)>"9"THEN20000
14100 IFVAL(MID$(IN$,S+S1+1,2))<0ORVAL(MID$(IN$,S+S1+1,2))>29THEN20000
14101 IFMID$(IN$,S+1,1)>MID$(IN$,S+S1,1)THEN20000
14102 IFMID$(IN$,S+1,1)=MID$(IN$,S+S1,1)THEN14110
14103 IFMID$(IN$,S+1,1)>MID$(IN$,S+S1,1)THEN20000
14104 IFVAL(MID$(IN$,S+2,2))<>VAL(MID$(IN$,S+S1+1,2))THEN20000
14107 IFMID$(IN$,S+1,1)>=MID$(IN$,S+S1,1)THEN20000
14108 IFMID$(IN$,S-2,3)="COP"THENT$=MID$(IN$,S-3,17):RETURN
14109 FC$(R,CD)=MID$(IN$,S-3,17):RETURN
14110 IFVAL(MID$(IN$,S+2,2))>=VAL(MID$(IN$,S+S1+1,2))THEN20000
14115 GOTO14108
20000 PRINTCHR$(19);:PRINT
20005 PRINTCHR$(18);" FORMAT ERROR-PRESS ANY KEY TO CONTINUE"
20010 GETG$:IFG$=""THEN20010
20020 GOTO20
22000 GOSUB12550:FORCD=0TO29
22010 FORR=0TO25
22020 IFFC$(R,CD)<>""THENGOSUB22060
22030 NEXTR:NEXTCD
22040 GOTO9900
22060 IFMID$(FC$(R,CD),2,3)="SUM"THEN23000
22070 IFMID$(FC$(R,CD),2,3)="MIN"THEN23140
22080 IFMID$(FC$(R,CD),2,3)="MAX"THEN23340
22090 IFMID$(FC$(R,CD),2,3)="AVG"THEN23500
22100 GOSUB28000
22999 RETURN
23000 GOSUB26000
23060 DA=0:IFR1=R2THEN23100
23065 FORX=R1TOR2
23070 DA=DA+DA(X,C1)
23080 NEXT:GOSUB27000
23090 RETURN
23100 FORX=C1TOC2
23110 DA=DA+DA(R1,X)
23120 NEXT:GOSUB27000
23130 RETURN
23140 GOSUB26000
23200 IFR1=R2THEN23235
23204 DA=DA(R1,C1)
23205 FORX=R1TOR2
23207 IFDA(X,C1)=0ANDDA$(X,C1)<>"        0"THEN23220
23210 IFDA>DA(X,C1)THENDA=DA(X,C1)
23220 NEXT:GOSUB27000
23230 RETURN
23235 DA=DA(R1,C1)
23240 FORX=C1TOC2
23245 IFDA(R1,X)=0ANDDA$(R1,X)<>"0"THEN23260
23250 IFDA>DA(R1,X)THENDA=DA(R1,X)
23260 NEXT:GOSUB27000
23270 RETURN
23340 GOSUB26000
23400 IFR1=R2THEN23435
23404 DA=DA(R1,C1)
23405 FORX=R1TOR2
23407 IFDA(X,C1)=0ANDDA$(X,C1)<>"        0"THEN23420
23410 IFDA<DA(X,C1)THENDA=DA(X,C1)
23420 NEXT:GOSUB27000
23430 RETURN
23435 DA=DA(R1,C1)
23440 FORX=C1TOC2
23445 IFDA(X,C1)=0ANDDA$(X,C1)<>"0"THEN23460
23450 IFDA<DA(R1,X)THENDA=DA(R1,X)
23460 NEXT:GOSUB27000
23470 RETURN
23500 GOSUB26000
23560 DA=0:TC=0:IFR1=R2THEN23600
23565 FORX=R1TOR2
23568 IFDA(X,C1)=0ANDDA$(X,C1)<>"        0"THEN23580
23570 DA=DA+DA(X,C1):TC=TC+1
23580 NEXT:IFTC=0THENDA$(R,CD)="        0":RETURN
23585 DA=DA/TC:GOSUB27000
23590 RETURN
23600 FORX=C1TOC2
23605 IFDA(R1,X)=0ANDDA$(R1,X)<>"0"THEN23620
23610 DA=DA+DA(R1,X):TC=TC+1
23620 NEXT:IFTC=0THENDA$(R,CD)="        0":RETURN
23628 DA=DA/TC:GOSUB27000
23630 RETURN
24000 PRINTCHR$(147)
24010 PRINT:PRINT"                LOAD":PRINT
24020 PRINT"        ENTER FILE NAME OR "
24030 PRINT"      PRESS 'RETURN' TO EXIT."
24035 PRINT
24040 IN$="":INPUT"              ";IN$
24050 IFIN$=""THEN9900
24060 PRINT:PRINT"      TAPE OR DISK  (T/D)"
24070 GETG$
24080 IFG$="T"THEN24200
24090 IFG$="D"THENOPEN15,8,15:GOTO24110
24100 GOTO24070
24110 OPEN2,8,2,"0:"+IN$+",S,R":GOSUB24500
24115 INPUT#2,Z:INPUT#2,P:GOSUB24500
24120 FORR=0TO25:FORCD=0TO29
24130 INPUT#2,DA$(R,CD)
24140 IFDA$(R,CD)="*"THENDA$(R,CD)=""
24150 INPUT#2,FC$(R,CD)
24160 IFFC$(R,CD)="*"THENFC$(R,CD)=""
24165 INPUT#2,DA(R,CD)
24170 NEXT:NEXT:GOSUB24500:CLOSE2:CLOSE15
24180 GOTO24280
24200 OPEN1,1,0,+IN$
24210 INPUT#1,Z:INPUT#1,P
24220 FORR=0TO25:FORCD=0TO29
24230 INPUT#1,DA$(R,CD)
24240 IFDA$(R,CD)="*"THENDA$(R,CD)=""
24250 INPUT#1,FC$(R,CD)
24260 IFFC$(R,CD)="*"THENFC$(R,CD)=""
24265 INPUT#1,DA(R,CD)
24270 NEXT:NEXT:CLOSE1
24280 FORR=0TO25:FORCD=0TO29
24285 IFLEN(DA$(R,CD))=0THEN24360
24290 IFLEN(DA$(R,CD))=9THEN24360
24300 IFLEN(DA$(R,CD))>9THEN24350
24305 IFDA(R,CD)=0ANDDA$(R,CD)<>"0"THEN24360
24310 FORX=1TO9-LEN(DA$(R,CD))
24320 DA$(R,CD)=" "+DA$(R,CD)
24330 NEXT
24340 GOTO24360
24350 DA$(R,CD)=LEFT$(DA$(R,CD),9)
24360 NEXT:NEXT
24370 GOTO9900
24500 INPUT#15,E,E$:IFE<>0THEN24520
24510 RETURN
24520 PRINTCHR$(147)
24525 PRINT"      ";
24530 PRINTCHR$(18);:PRINT"     DISK ERROR      "
24540 PRINT"      ";
24550 PRINTE$
24560 PRINT:PRINT:PRINT
24570 PRINT"  PRESS ANY KEY TO CONTINUE  "
24580 GETG$:IFG$=""THEN24580
24590 CLOSE2:CLOSE15:GOTO9900
25000 PRINTCHR$(147)
25010 PRINT:PRINT"                SAVE":PRINT
25020 PRINT"        ENTER FILE NAME OR "
25030 PRINT"      PRESS 'RETURN' TO EXIT."
25035 PRINT
25040 IN$="":INPUT"              ";IN$
25050 IFIN$=""THEN9900
25060 PRINT:PRINT"      TAPE OR DISK  (T/D)"
25070 GETG$
25080 IFG$="T"THEN25200
25090 IFG$="D"THENOPEN15,8,15:GOTO25110
25100 GOTO25070
25110 OPEN2,8,2,"0:"+IN$+",S,W":GOSUB24500
25115 PRINT#2,Z:PRINT#2,P
25120 FORR=0TO25:FORCD=0TO29
25130 IFDA$(R,CD)=""THENPRINT#2,"*":GOTO25150
25140 PRINT#2,DA$(R,CD)
25150 IFFC$(R,CD)=""THENPRINT#2,"*":GOTO25165
25160 PRINT#2,FC$(R,CD)
25165 PRINT#2,DA(R,CD)
25170 NEXT:NEXT:GOSUB24500:CLOSE2:CLOSE15
25180 GOTO9900
25200 OPEN1,1,1,+IN$
25210 PRINT#1,Z:PRINT#1,P
25220 FORR=0TO25:FORCD=0TO29
25230 IFDA$(R,CD)=""THENPRINT#1,"*":GOTO25250
25240 PRINT#1,DA$(R,CD)
25250 IFFC$(R,CD)=""THENPRINT#1,"*":GOTO25265
25260 PRINT#1,FC$(R,CD)
25265 PRINT#1,DA(R,CD)
25270 NEXT:NEXT:CLOSE1
25280 GOTO9900
26000 T$=FC$(R,CD)
26010 R1=ASC(MID$(T$,5,1))-65
26020 C1=VAL(MID$(T$,6,2))
26030 IFMID$(T$,7,1)="-"THENR2=ASC(MID$(T$,8,1))-65:GOTO26050
26040 R2=ASC(MID$(T$,9,1))-65:C2=VAL(MID$(T$,10,2)):GOTO26060
26050 C2=VAL(MID$(T$,9,2))
26060 RETURN
27000 DA(R,CD)=DA:DA=INT(DA*P+.5)/P
27005 IFLEN(STR$(DA))<9THENDA$(R,CD)=STR$(DA):GOTO27070
27010 IFLEN(STR$(DA))=9THENDA$(R,CD)=STR$(DA):RETURN
27020 IFDA>0THENT$=RIGHT$(STR$(DA),LEN(STR$(DA))-1):GOTO27050
27030 GOTO27060
27050 IFLEN(T$)=9THENDA$(R,CD)=T$:RETURN
27055 IFLEN(T$)<9THENDA$(R,CD)=T$:GOTO27070
27060 DA$(R,CD)="*********":RETURN
27070 FORX=1TO9-LEN(DA$(R,CD))
27080 DA$(R,CD)=" "+DA$(R,CD)
27090 NEXT
27100 RETURN
28000 R1=ASC(MID$(FC$(R,CD),2,1))-65
28010 C1=VAL(MID$(FC$(R,CD),3,2))
28020 T$=MID$(FC$(R,CD),4,1)
28030 IFT$="+"ORT$="-"ORT$="*"ORT$="^"ORT$="/"THENS=5:GOTO28050
28040 S=6
28045 T$=MID$(FC$(R,CD),5,1)
28050 TC=0
28060 IFMID$(FC$(R,CD),S,1)<"A"THENTC=1:GOTO28200
28070 R2=ASC(MID$(FC$(R,CD),S,1))-65
28080 C2=VAL(MID$(FC$(R,CD),S+1,2))
28100 IFT$="+"THENDA=DA(R1,C1)+DA(R2,C2):GOSUB27000:RETURN
28110 IFT$="-"THENDA=DA(R1,C1)-DA(R2,C2):GOSUB27000:RETURN
28120 IFT$="*"THENDA=DA(R1,C1)*DA(R2,C2):GOSUB27000:RETURN
28130 IFT$="^"THEN28380
28140 IFDA(R2,C2)=0THENDA$(R,CD)="DIV. BY 0":DA(R,CD)=0:RETURN
28150 IFT$="/"THENDA=DA(R1,C1)/DA(R2,C2):GOSUB27000:RETURN
28160 RETURN
28200 DA=VAL(MID$(FC$(R,CD),S,19))
28210 IFT$="+"THENDA=DA(R1,C1)+DA:GOSUB27000:RETURN
28220 IFT$="-"THENDA=DA(R1,C1)-DA:GOSUB27000:RETURN
28230 IFT$="*"THENDA=DA(R1,C1)*DA:GOSUB27000:RETURN
28240 IFT$<>"/"THEN28270
28250 IFDA=0THENDA$(R,CD)="DIV. BY 0":DA(R,CD)=0:RETURN
28260 IFT$="/"THENDA=DA(R1,C1)/DA:GOSUB27000:RETURN
28270 IFT$<>"^"THENRETURN
28280 IFDA(R1,C1)>5ANDDA>40THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28290 IFDA(R1,C1)>10ANDDA>20THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28292 IFDA(R1,C1)>20ANDDA>15THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28294 IFDA(R1,C1)>1000ANDDA>5THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28296 IFDA(R1,C1)>1000000ANDDA>2THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28300 DA=ABS(DA(R1,C1))^DA:GOSUB27000:RETURN
28380 IFDA(R1,C1)>5ANDDA(R2,C2)>40THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28390 IFDA(R1,C1)>10ANDDA(R2,C2)>20THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28392 IFDA(R1,C1)>20ANDDA(R2,C2)>15THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28394 IFDA(R1,C1)>1000ANDDA(R2,C2)>5THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28396 IFDA(R1,C1)>100000ANDDA(R2,C2)>2THENDA$(R,CD)="OVERFLOW":DA(R,CD)=0:RETURN
28400 DA=ABS(DA(R1,C1))^DA(R2,C2):GOSUB27000:RETURN