0 REM *** THE 64 SPELLER ***
10 POKE53281,1:POKE53280,1:PRINTCHR$(144);CHR$(14);CHR$(147)
15 CLR
20 S=54272:V=53248
25 RESTORE
49 REM *** TITLE ***
50 FORX=1TO6:PRINT:NEXTX
55 PRINTTAB(13)"[212]HE 64 [211]PELLER"
60 PRINT:PRINTTAB(13)"BY [199]ARY [198]IELDS"
70 PRINT:PRINT:PRINT:PRINT
75 PRINTCHR$(18)"   [206][207][212][197] TO PARENT/TEACHER               "
80 PRINT:PRINTTAB(4)"[212]O CHANGE [215][207][210][196][211]/[196][197][198][201][206][201][212][201][207][206][211] - [198]1"
85 FORX=1TO40:PRINTCHR$(183);:NEXTX:GOSUB2000
87 FOR PR=0TO62:READPQ:POKE832+PR,PQ:NEXTPR
90 FOR X=1TO100
92 GETF1$:IFF1$=""THEN95
93 IFF1$=CHR$(133)THEN2500
95 NEXTX
99 REM *** DISPLAY WORDS ***
100 PRINTCHR$(147)
105 PRINT:PRINTCHR$(18)"[200]ERE ARE THE WORDS YOU WILL BE SPELLING":PRINTCHR$(146)
110 READA1$
120 IFA1$="-1"THEN150
125 READB1$,A2$,B2$
130 PRINTA1$:GOSUB2000
135 PRINTCHR$(145);TAB(20)A2$:GOSUB2000
140 GOTO110
150 PRINT:PRINTCHR$(18)" [208][210][197][211][211] ANY KEY TO BEGIN                "
155 PRINT:PRINT:PRINTTAB(3)"[212]O CHANGE [215][207][210][196][211]/[196][197][198][201][206][201][212][201][207][206][211] - [198]1"
158 FORX=1TO40:PRINTCHR$(183);:NEXTX:GOSUB2000
160 GETF1$:IFF1$=""THEN160
165 IFF1$=CHR$(133)THEN2500
190 RESTORE:FORPR=0TO62:READPQ:NEXTPR
200 PRINTCHR$(147)
210 READ A$,B$:CC=0
215 IF A$="-1"GOTO 1500
219 REM *** DISPLAY OF B$ 220-245
225 FORX=1TO6:PRINT:NEXTX
227 PRINT:PRINT
229 PRINT"[212]HIS DEFINES A WORD YOU KNOW."
230 FORX=1TO40:PRINTCHR$(183);:NEXTX:PRINT:PRINT
232 FORI=0TOLEN(B$)
235 POKES+24,6:POKES+1,126:POKES,6:POKES+5,120:POKES+6,30:POKES+4,33
240 PRINTLEFT$(B$,I+1):POKES+24,0
245 PRINTCHR$(145);CHR$(145):FORX=1TO40:NEXTX
247 POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0:NEXTI
270 PRINT:PRINT:FORX=1TO100:NEXTX
280 INPUT"[195]AN YOU SPELL THE WORD";C$
290 FORX=1TO50:NEXTX
300 IFC$=A$GOTO600
310 IFC$<>A$GOTO800
599 REM *** WINNING ROUTINE ***
600 PRINTCHR$(147):FORX=1TO9:PRINT:NEXTX
605 SM=24:REM *** START SMOKE LOCATION **
610 POKEV+4,200:POKEV+21,4:POKE2042,13:POKEV+29,4:REM EXPAND AND POSITION SPRITE
612 POKEV+41,0:REM MAKES TRAIN (SPRITE 2)BLACK
620 PRINT;A$:FORX=1TO200:NEXTX
622 PRINTCHR$(152);:FORX=1TO7:PRINTCHR$(178);:NEXTX
623 PRINT"[217]OU'RE ON THE RIGHT TRACK";:FORX=1TO6:PRINTCHR$(178);:NEXTX
624 PRINTCHR$(144)
625 FORTN=200TO24STEP-8:REM SPRITE MOVEMENT COUNTER
644 POKES+24,15:POKES+1,145:POKES,0:POKES+5,0:POKES+6,240:POKES+4,129
645 POKEV+4,TN:POKEV+5,120:REM ** SPRITEMOVER X AND Y LOCATION
646 IFSM<1THENSM=1
647 SM=SM-1:REM *** MOVES SMOKE RIGHT TO LEFT
648 GOSUB750
650 FORPU=1TO40:NEXT PU
651 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0:NEXTTN
653 POKES+24,15:POKES+1,155:POKES,255:POKES+5,0:POKES+6,240:POKES+4,17:REM TOOT
655 PRINTCHR$(19):FORX=1TO6:PRINT:NEXTX:PRINTTAB(14)"[217]OU GOT IT!!"
657 FORX=1TO500:NEXTX
658 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
659 FORX=1TO300:NEXTX:REM PAUSE BETWEEN TOOTS
660 POKES+24,15:POKES+1,155:POKES,255:POKES+5,0:POKES+6,240:POKES+4,17:REM TOOT
661 FORX=1TO500:NEXTX
662 POKEV+21,0:REM *** TURNS SPRITE OFF
663 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
664 PRINTCHR$(147):FORX=1TO6:PRINT:NEXTX
670 PRINTCHR$(18)A$;CHR$(146);" IS THE CORRECT SPELLING"
675 GOSUB2000
680 FORX=1TO1000:NEXTX:PRINTCHR$(147):FORX=1TO6:PRINT:NEXT
700 GOTO200
730 REM **** SMOKE ROUTINE ***
750 PRINTCHR$(19);:FORX=1TO8:PRINT:NEXTX:REM MOVES SMOKE DOWN 6 LINES
760 PRINTTAB(SM);CHR$(31);CHR$(42);CHR$(32);CHR$(42):REM PRINTS SMOKE
780 PRINTCHR$(144)
790 RETURN
799 REM *** INCORRECT ROUTINE ***
800 PRINTCHR$(147)
801 FORX=1TO6:PRINT:NEXTX
802 PRINT"[217]OUR ANSWER ";CHR$(18);C$;CHR$(146);" IS INCORRECT."
805 REM *** BUZZ SOUND ***
810 POKES+24,15:POKES+1,3:POKES,255:POKES+5,0:POKES+6,240:POKES+4,33
820 FORX=1TO600:NEXTX
825 POKES+24,15:POKES+1,34:POKES,75:POKES+5,128:POKES+6,128:POKES+4,39
830 FORX=1TO600:NEXTX
840 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
865 PRINT:PRINT"[212]RY AGAIN"
870 FORX=1TO800:NEXTX
880 PRINTCHR$(147):FORX=1TO6:PRINT:NEXTX
890 PRINTB$:PRINT:FORX=1TO500:NEXTX
892 PRINTCHR$(18);"[215]OULD YOU LIKE A CLUE? [208]RESS [198]1 "
893 GETCL$:IFCL$=""THEN893
894 IFCL$<>CHR$(133)THEN900
895 CC=CC+1:PRINT:PRINT:PRINTTAB(15);LEFT$(A$,CC):FORX=1TO500:NEXTX
896 PRINTCHR$(147):FORX=1TO6:PRINT:NEXTX
898 PRINTB$:PRINT:PRINT
900 INPUT"[208]LEASE SPELL THE WORD ";C$
910 GOTO290
1499 REM *** END ROUTINE ***
1500 FORX=1TO500:NEXT:C=0
1510 PRINTCHR$(147):FORX=1TO6:PRINT:NEXTX
1790 POKES+24,15:POKES+1,130:POKES,0:POKES+5,9:POKES+6,240:POKES+4,21
1795 PRINT"[199][210][197][193][212] YOU GOT THEM ALL [210][201][199][200][212]!!":C=C+1
1797 FORX=1TO600:NEXTX:PRINTCHR$(147)
1800 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
1810 FORX=1TO6:PRINT:NEXTX
1820 IFC<4GOTO1790
1830 PRINTCHR$(147):RESTORE:FORPR=0TO62:READPQ:NEXTPR
1840 PRINTCHR$(18)" [200]ERE ARE YOUR SPELLING WORDS AGAIN. "
1850 READA1$
1855 IFA1$="-1"THENEND
1860 READB1$,A2$,B2$
1880 PRINTA1$;:PRINTTAB(20)A2$
1890 GOTO1850
1999 REM **** BEEP SOUND ****
2000 POKES+24,15:POKES+1,45:POKES,0:POKES+5,9:POKES+6,0:POKES+4,17
2010 FORX=1TO400:NEXTX
2020 POKES+24,0:POKES+1,0:POKES,0:POKES+5,0:POKES+6,0:POKES+4,0
2030 RETURN
2499 REM **** ADD DATA ROUTINE ***
2500 PRINTCHR$(147)
2510 PRINT:PRINT:PRINT
2520 PRINT"[215]ORDS AND DEFINITIONS ARE STORED IN     [196]ATA LINES"
2525 PRINT"[212]HESE ARE LINES 2999-4999"
2530 PRINT:PRINT"[215]HEN REPLACING, BE SURE TO ENTER:"
2540 PRINT:PRINT" [196][193][212][193] LINE FOLLOWED BY 'DATA'"
2545 PRINT" THEN THE [215][207][210][196] FOLLOWED BY ACOMMA"
2550 PRINT" THEN THE [196][197][198][201][206][201][212][201][207][206] NO COMMA"
2555 PRINT:PRINT"[210]EMEMBER- THE DEFINITON CAN NOT BE OVER 39 CHARACTERS LONG"
2600 PRINT:PRINTCHR$(18)"[208]RESS [210]ETURN TO LIST DATA LINES";:INPUTF2$
2900 LIST2999-4999
2950 DATA0,0,0,25,191,255,31,191,255,31,156,6,15,12,244, 15
2951 DATA45,244,95,252,180,127,252,116,255,252,52,255,255,252,127, 255
2952 DATA254,95,255,255,3,255,255,3,255,255,15,254,0,31,252, 254
2953 DATA63,253,131,120,61,57,243,157,57,246,193,131,3,128,254
2999 REM *** DATA LINES ***
3000 DATA "DOG","[193] FOUR LEGGED PET THAT BARKS"
3002 DATA "PENCIL","[217]OU USE IT TO WRITE AT SCHOOL"
3004 DATA "ELEPHANT","[212]HE BIGGEST ANIMAL ON LAND"
3006 DATA "ALPHABET","[215]HAT ALL THE A,B,C'S ARE CALLED"
3024 DATA "MORNING","[212]IME OF DAY WHEN YOU FIRST WAKE UP"
3028 DATA "FRIEND","[211]OMEONE YOU LIKE VERY MUCH"
5000 DATA "-1","-1","-1","-1"