10 POKE51,0:POKE52,96:POKE55,0:POKE56,96:GOSUB1200
20 INPUT"WHAT LEVEL-2,4,6,OR 8";WG:WG=INT(WG)
30 IF WG<2THENWG=2
40 IFWG>8THENWG=8
50 IFWG=3ORWG=5ORWG=7THENWG=WG+1
60 PRINT"LEVEL=";WG
70 RU= 24784:AU=28927:LU=28926:IU=28908:RT=24576
80 GOSUB370
90 CC=1:BQ=0
100 PRINT"YOU FIRST?"
110 GETA$:IFA$=""THEN110
120 IFA$="Y"THENAQ=1:GOTO140
130 AQ=-1:BQ=1:GOSUB530:GOSUB720:GOTO150
140 GOSUB530
150 PRINT"                                   ";
160 IFBQ>0THENPRINT"MY MOVE "V$(BQ);
170 PRINT" YOUR MOVE?  [157]"
180 GETA$
190 IFA$=""THEN180
200 PRINT"          YOUR MOVE ";A$
210 IF(A$>"0"ANDA$<"6")THENBQ=ASC(A$)-48:GOTO240
220 IF(A$>="A"ANDA$<="E")THENBQ=ASC(A$)-59:GOTO240
230 GOTO150
240 AQ=1:GOSUB720
260 POKELZ,0:SYSRT:IFPEEK(CZ)=1THENPRINT"YOU WIN!      ":T4=T4+1:GOTO1080
270 IFPEEK(CZ+1)=1THENPRINT"I WIN!              ":S4=S4+1:GOTO1080
280 IFCC<4THEN350
290 SYS25008
300 BQ=PEEK(28940):IFBQ=0THENBQ=1
310 AQ=-1:GOSUB720
320 POKELZ,0:SYSRT:IFPEEK(CZ+1)=1THENPRINT"I WIN!     ":S4=S4+1:GOTO1080
330 IFPEEK(CZ)=1THENPRINT"YOU WIN!         ":T4=T4+1:GOTO1080
340 GOTO150
350 CC=CC+1:BQ=INT(RND(XX)*10+1)
360 GOTO310
370 REM INITIALIZE
380 S=1024:DN=40:REM FOR 40-COLUMN SCREEN USE DN=40
400 MR=8:MC=13
410 POKE28958,WG
420 LC=S+DN*MR+MC:D2=2*DN
430 VB=93:HB=64:XX=91:TH=114:BH=113:LH=107:RH=115
440 PRINTCHR$(142)
450 UL=112:UR=110:BL=109:BR=125
460 WH=81:BK=86
470 A=28416:CZ=28872:PZ=28874:LZ=28897
490 DATA1,2,3,4,5,A,B,C,D,E
500 FORI=1TO10:READV$(I):NEXT
510 FORI=0TO24:POKEA+I,0:NEXTI
520 RETURN
530 REM BUILD SCREEN
540 PRINT"[147]":SYS25344
550 FORI=1TO5
560 POKELC+2*I,48+I
570 POKELC+D2*I,I
580 FORJ=0TO5
590 POKELC+D2*I+1+2*J,VB
600 POKELC+2*I+D2*J+DN,HB
610 NEXTJ:NEXTI
620 FORI=1TO4:FORJ=1TO4
630 POKELC+DN+1+2*I+D2*J,XX
640 NEXTJ
650 POKELC+DN+1+2*I,TH
660 POKELC+11*DN+1+2*I,BH
670 POKELC+DN+1+D2*I,LH
680 POKELC+DN+11+D2*I,RH
690 NEXTI
700 POKELC+1+DN,UL:POKELC+DN+11,UR:POKELC+11*DN+1,BL:POKELC+11*DN+11,BR
705 PRINT"[154]":PRINTTAB(25);"YOUR TOKEN [209]":PRINTTAB(25);"MY   TOKEN [214]"
710 RETURN
720 REM INSERT TOKEN INTO CURRENT COPY OF GAME AND ALSO SCREEN.
730 REM ON ENTRY AQ=1 IF PLAYER IS WHITE, -1 IF BLACK.
740 REM BQ IN RANGE 1-5 FOR COLUMN, 6-10 FOR ROW.
750 TQ=WH:NQ=1:IFAQ=-1THENTQ=BK:NQ=255
760 CQ=BQ-1:IFBQ>5THEN870
770 GOSUB980:IFQQ=0THEN840
780 FORI=QQTO1STEP-1
790 IQ=I-1
800 EQ=PEEK(A+5*IQ+CQ):POKEA+5*I+CQ,EQ
810 VQ=PEEK(LC+D2*I+BQ*2)
820 POKELC+D2+D2*I+BQ*2,VQ
830 NEXTI
840 POKEA+CQ,NQ
850 POKELC+D2+BQ*2,TQ
860 GOTO970
870 CQ=BQ-6:RQ=5*CQ:GOSUB1030
880 IFQQ=0THEN950
890 FORI=QQTO1STEP-1
900 IQ=I-1
910 EQ=PEEK(A+RQ+IQ):POKEA+RQ+I,EQ
920 VQ=PEEK(LC+D2+D2*CQ+I*2)
930 POKELC+D2+D2*CQ+I*2+2,VQ
940 NEXTI
950 POKEA+RQ,NQ
960 POKELC+D2+D2*CQ+2,TQ
970 RETURN
980 QQ=4
990 FORI=0TO3
1000 IFPEEK(A+5*I+CQ)=0THENQQ=I:I=4
1010 NEXTI
1020 RETURN
1030 QQ=4
1040 FORI=0TO3
1050 IFPEEK(A+RQ+I)=0THENQQ=I:I=4
1060 NEXTI
1070 RETURN
1080 PRINT"GAMES: YOU ";T4;"   ME ";S4
1090 PRINT"WANT ANOTHER GAME?"
1100 GETA$
1110 IFA$=""THEN1100
1120 IFA$><"N"THENGOSUB510:GOTO90
1130 PRINT"THANK YOU":STOP
1200 PRINT"[147]                 SLIDE"
1210 PRINT"            BY ROBERT ROSSA"
1220 PRINT"       ARKANSAS STATE UNIVERSITY"
1230 PRINT:PRINT:PRINT"    GET FIVE TOKENS IN A ROW TO WIN"
1240 FORI=1TO2000:NEXT
1250 RETURN