10 REM   THE BUNNY HOP-BY JC HILTY-5/87
15 POKE 45,PEEK(174):POKE 46,PEEK(175):CLR:POKE53281,0:POKE53280,0
20 POKE147,0:SYS57812"BUNNY.ML",8,1:SYS62631
25 POKE147,0:SYS57812"BUNNY.SP",8,1:SYS62631
26 POKE147,0:SYS57812"BUNNY.FONT",8,1:SYS62631
30 DIMS$(4),E(9),C$(4)
35 C$(0)="[158]":C$(1)="[155]":C$(2)="[150]":C$(3)="[156]":C$(4)="[153]"
40 A$="#$%[157][157][157]&'([157][157][157])*+"
45 S$(0)="":FORX=1TO4:S$(X)=S$(X-1)+"":NEXT
50 FORX=0TO9:E(X)=(X*4)+3:NEXT
52 V=53248:S=54272:SC=0:LE=1:LI=4:BO=240:L=1:CD=2:HS=0
54 FORX=49601TO49616:POKEX,0:NEXT:POKE49700,255:POKE49600,0:SYS49376
59 POKE53272,(PEEK(53272)AND240)OR14
60 GOSUB500
64 GOSUB380
65 W1=PEEK(V+30):W2=PEEK(V+32)
70 POKE49600,30
75 SYS49501
80 ONLGOSUB110,135,110,200,230,205,110,210,110,215,110,230
85 IFBO=0THEN290
90 L=L+1:IFL=13THENL=1
95 W1=PEEK(V+30):IFW1AND1THEN245
100 W2=PEEK(V+31):IFW2AND1THEN290
105 GOTO75
110 IFPEEK(V+5)>100THENPOKE49606,254:POKE49700,4
115 IFPEEK(V+5)<60THENPOKE49606,2:POKE49700,4
120 IFPEEK(V+7)<176THENPOKE49608,2:POKE49700,8
125 IFPEEK(V+7)>220THENPOKE49608,254:POKE49700,8
130 RETURN
135 G=INT(09*RND(9)+1):ONGGOTO140,145,150,155,160,165,170,175,180
140 POKE49603,1:POKE49604,0:POKE49700,2:POKE2041,195:GOTO185
145 POKE49603,255:POKE49604,0:POKE49700,2:POKE2041,194:GOTO185
150 POKE49603,0:POKE49604,1:POKE49700,2:GOTO185
155 POKE49603,0:POKE49604,255:POKE49700,2:GOTO185
160 POKE49603,1:POKE49604,1:POKE49700,2:POKE2041,195:GOTO185
165 POKE49603,255:POKE49604,255:POKE49700,2:POKE2041,194:GOTO185
170 POKE49603,1:POKE49604,255:POKE49700,2:POKE2041,195:GOTO185
175 POKE49603,255:POKE49604,1:POKE49700,2:POKE2041,194:GOTO185
180 POKE49603,0:POKE49604,0:POKE49700,2:GOTO185
185 IFPEEK(V+3)<75THENPOKE49604,1:POKE49700,2
190 IFPEEK(V+3)>220THENPOKE49604,255:POKE49700,2
195 RETURN
200 FORX=2042TO2044:POKEX,197:NEXT:RETURN
205 FORX=2042TO2044:POKEX,196:NEXT:RETURN
210 BO=BO-CD:PRINT"[153]"TAB(6)"   ":PRINT""TAB(5)BO:RETURN
215 IFPEEK(V+3)<PEEK(V+1)THENPOKE49604,255:POKE49700,2:POKE2041,194
220 IFPEEK(V+3)>PEEK(V+1)THENPOKE49604,1:POKE49700,2:POKE2041,195
225 RETURN
230 IFPEEK(V+2)<40THENPOKE49603,1:POKE49700,2:RETURN
231 IFPEEK(V+16)AND2THENPOKE49603,255:POKE49700,2:RETURN
232 RETURN
245 IFW1=3THEN255
250 GOTO290
255 SC=SC+BO:BO=240:L=1:Y=194:CD=CD+2:IFCD=14THENCD=2
260 LE=LE+1:IFLE=13THENSC=SC+(250*LI):POKES+4,16:GOTO335
265 POKE49600,0
270 FORX=0TO24:POKES+X,0:NEXT:POKES+24,15:POKES+5,80:POKES+6,243:POKES+3,4
275 POKES+4,65
280 FORX=20TO140STEP4:POKES+1,X:POKE2041,Y:Y=Y+1:IFY=196THENY=194
285 NEXT:POKES+4,64:POKEV+21,0:GOTO64
290 POKE49600,0:L=1:LI=LI-1:BO=240
295 FORX=0TO24:POKES+X,0:NEXT:POKE2040,193
300 POKEV+23,28:POKEV+29,28
305 Y=196:POKES+24,15:POKES+5,80:POKES+6,243:POKES+3,7
310 FORJ=60TO12STEP-1:POKES+4,65:POKES+1,J
315 FORX=2042TO2044:POKEX,Y:NEXTX:Y=Y+1:IFY=198THENY=196
320 POKES+4,64:NEXTJ
325 IFLI=0THENPOKEV+23,0:POKEV+29,0:GOTO335
330 POKEV+21,0:POKEV+23,0:POKEV+29,0:GOTO64
335 POKE49600,0:POKEV+21,0
336 PRINT"[147]<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<"
337 PRINT"[129]======================================="
338 FORT=0TO9:PRINT"<"TAB(38)"<":PRINT"[129]="TAB(38)"=":NEXT
339 PRINT"<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<"
340 PRINT"[129]======================================="
341 PRINT"[155]"TAB(15)"GAME OVER":PRINT
345 IFSC>HSTHENHS=SC
350 PRINTTAB(16)"SCORE"SC:PRINTTAB(16)"HIGH "HS:PRINT
355 PRINTTAB(6)"WOULD YOU LIKE TO PLAY AGAIN"
357 PRINTTAB(16)"[Y / N]"
360 POKE 198,0
365 GETK$:IFK$=""THEN365
366 IFK$="Y"THENBO=240:LI=4:L=1:LE=1:SC=0:CD=2:GOTO64
370 IFK$<>"N"THEN365
372 OPEN15,8,15:OPEN1,8,2,"0:REBOOT,P,R":INPUT#15,E:CLOSE1:CLOSE15
373 IFE=0THENLOAD"REBOOT",8
374 PRINT"THE UPTIME DISK IS NOT IN THE DRIVE"
375 PRINTSPC(8);"PRESS SPACE[146] TO CONTINUE"
376 GETK$:IFK$<>" "THEN376
377 GOTO336
380 POKE53281,0:PRINT"[147][153]BONUS      LIVES  [154],    ,[153]SCR      LEV"
385 PRINT"[154],,,,,,,,,,,,,,,,,,,    ,,,,,,,,,,,,,,,,"
390 FORX=0TO7:PRINT","TAB(38)",":NEXT
395 FORX=0TO3:PRINT:NEXT:FORX=0TO8:PRINT","TAB(38)",":NEXT
400 PRINT",,,,,,,,,,,,,,,,,,,    ,,,,,,,,,,,,,,,,"
405 PRINT"[153]"TAB(5)BO;TAB(16)LI;TAB(27)SC;TAB(36)LE
410 GOSUB465
411 POKEV+37,1:POKEV+38,9
415 POKEV+16,9:POKE2040,192:POKEV+28,29:POKEV+39,5:POKEV,46:POKEV+1,134
420 POKE2041,195:POKEV+40,15:POKEV+2,160:POKEV+3,136
425 POKE2042,196:POKEV+41,0:POKEV+4,40:POKEV+5,80
430 POKE2043,196:POKEV+42,0:POKEV+6,44:POKEV+7,210
435 POKE2044,196:POKEV+43,0:POKEV+8,50:POKEV+9,144
440 FORX=49601TO49616:POKEX,0:NEXT
445 POKE49605,2:POKE49606,2:POKE49607,253:POKE49608,254:POKE49609,1
450 POKE49700,31:W1=PEEK(V+30):W2=PEEK(V+31)
455 POKEV+21,31:RETURN
460 REM    CREATE NEW FOREST
465 QQ=INT(RND(9)*10+5)
470 FORX=0TOQQ
475 C=INT(RND(9)*5):H=INT(RND(9)*8):VE=INT(RND(9)*5)
480 PRINTC$(C)S$(VE)TAB(E(H))A$:NEXT
485 RETURN
499 REM    INSTRUCTIONS
500 PRINT"[147]<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<"
502 PRINT"[129]======================================="
504 FORT=0TO9:PRINT"<"TAB(38)"<":PRINT"[129]="TAB(38)"=":NEXT
505 PRINT"<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<"
506 PRINT"[129]======================================="
507 PRINT"[155]"TAB(2)"USE A JOYSTICK IN PORT 2 TO MOVE"
508 PRINTTAB(2)"FARMER JONES AS HE CHASES THE BUNNY"
509 PRINTTAB(2)"WHO HAS BEEN EATING HIS CARROTS."
510 PRINTTAB(2)"YOUR OBJECT IS TO CATCH THE BUNNY"
511 PRINTTAB(2)"BEFORE TIME RUNS OUT ON THE CLOCK.":PRINT
512 PRINTTAB(2)"YOU MUST NOT RUN INTO A TREE OR FALL"
514 PRINTTAB(2)"INTO THE BLUE CREEK SURROUNDING THE"
515 PRINTTAB(2)"FOREST.  IF YOU DO THEN YOU LOSE ONE"
516 PRINTTAB(2)"OF THE FOUR LIVES THAT YOU START"
517 PRINTTAB(2)"THE GAME WITH."
518 PRINT:PRINTTAB(2)"YOU ARE NOT IN THE FOREST ALONE."
519 PRINTTAB(2)"ROAMING AROUND ARE THE INFAMOUS"
520 PRINTTAB(2)"THREE BEARS!  IF A BEAR CAPTURES"
521 PRINTTAB(2)"YOU A LIFE IS LOST.":PRINT:PRINTTAB(9)"PLEASE PRESS SPACEBAR"
522 POKE198,0
523 GET K$:IF K$<>" " THEN 523
524 PRINT"[147]<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<"
525 PRINT"[129]======================================="
526 FORT=0TO9:PRINT"<"TAB(38)"<":PRINT"[129]="TAB(38)"=":NEXT
527 PRINT"<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<"
528 PRINT"[129]======================================="
530 PRINT"[155]"TAB(2)"THE GAME CONSISTS OF 12 LEVELS WITH"
531 PRINTTAB(2)"THE CLOCK COUNTING DOWN FASTER ON"
532 PRINTTAB(2)"EACH LEVEL FROM 1 TO 6 THEN REPEATS"
533 PRINTTAB(2)"FROM LEVELS 7 TO 12.  YOU MUST"
534 PRINTTAB(2)"CAPTURE THE BUNNY ON EACH LEVEL"
535 PRINTTAB(2)"BEFORE PROGRESSING TO THE NEXT."
536 PRINT:PRINTTAB(2)"YOUR SCORE ON EACH LEVEL IS THE"
537 PRINTTAB(2)"TIME REMAINING ON THE CLOCK WHEN"
538 PRINTTAB(2)"YOU CAPTURE THE BUNNY.  IF YOU"
539 PRINTTAB(2)"COMPLETE ALL 12 LEVELS YOU RECEIVE"
540 PRINTTAB(2)"BONUS POINTS FOR THR LIVES THAT"
541 PRINTTAB(2)"YOU HAVE REMAINING.":PRINT
542 PRINTTAB(2)"GOOD LUCK WITH THAT CWAZY WABBIT!!":PRINT
544 PRINTTAB(9)"PLEASE PRESS SPACEBAR"
545 POKE198,0
550 GET K$:IF K$<>" " THEN 550
560 RETURN