10 OPEN15,8,15:PRINT#15,"I":CLOSE15:PRINT"[147]":POKE53265,PEEK(53265)OR16:POKE198,0
15 OPEN8,8,8,"DISK,S,R":INPUT#8,XI:CLOSE8:POKE832,XI
20 POKE53280,6:POKE53281,6
23 IFXI=0THENUX=1:GOSUB44
25 IFDE=0ANDXI=9THENDE=1:GOTO100
26 PRINT"[147]INSERT DATA DISK. [RETURN]":GOSUB99
30 GETA$:IFA$<>""THEN30
35 GETA$
40 IFA$="_"THEN44
42 IFA$<>CHR$(13)ANDPEEK(56320)<>111THEN35
43 GOTO100
44 POKE53280,0:POKE53281,0:IFDE=0ANDXI=9THENDE=1:GOTO900
45 PRINT"[147]INSERT 'DUNGEON' DISK. [RETURN]":GOSUB99
46 GETA$
47 IFA$="_"THENPRINT"[147]":RUN
48 IFA$<>CHR$(13)ANDPEEK(56320)<>111THEN46
49 GOTO900
50 REM
55 FORG=1TOZ:PRINTA$(G);:NEXTG:E=1
57 PRINT "";A$(E);"[146]"
60 A=PEEK(56320):IFA<>127THENFORG=1TO10:NEXTG:GOTO70
65 GETA$:IFA$="" THEN 60
70 IFA=126ORA$="[145]"THENK=-1:GOTO90
75 IFA=125ORA$=""THENK=1:GOTO90
80 IFA=111ORA$=CHR$(13) THEN RETURN
88 GOTO60
90 PRINTA$(E);:E=E+K:IFE=0THENE=Z
95 IFE=Z+1THENE=1
98 GOTO57
99 PRINT"PRESS [_] TO ESCAPE.":RETURN
100 XI=PEEK(832)
102 A=0:PRINT"[147]":OPEN8,XI,8,"MASTER DISK,S,R":INPUT#8,A:CLOSE8:IFA<>1THEN20
103 OPEN8,XI,8,"TREASURE,S,R":INPUT#8,TW,TM,TP,TT:CLOSE8:DE=0
105 POKE53280,12:POKE53281,0:F$="                          "
110 PRINT"[147][152]                                        ";
115 PRINT"           PRINT DIRECTORIES            ";
120 PRINT"                                        ";:PRINT"[146]"
130 PRINT"[193][183][183][183][183][183][183][183][183][183][183][183][183][183][183][183][211]"
135 FORG=1TO9:PRINT"[180][170]":NEXTG
140 PRINT"[218][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][216]"
150 A$(1)="  CHARACTERS   "
152 A$(2)="  MONSTERS     "
154 A$(3)="  MAGIC ITEMS  "
156 A$(4)="  WEAPONS      "
158 A$(5)="  ARMOR        "
160 A$(6)="  TRAPS        "
162 A$(7)="  DUNGEONS     "
168 A$(8)="  CHANGE DISK  "
170 A$(9)="  FINISHED     "
175 Z=9:GOSUB50
180 IFE=8THENRUN100
183 IFE=9THEN44
185 ONEGOTO200,300,400,500,600,700,800
200 PRINT"[147][PRINT CHARACTERS]"
220 OPEN8,8,8,"@0:CHA. DATA,S,R":INPUT#8,X:IFX=0THENCLOSE8:GOTO290
225 DIMPL$(X),NA$(X),SR$(X),IN$(X),DE$(X),LU$(X),HP$(X),HD$(X),RA$(X),LE$(X)
230 DIMAC$(X),TD$(X):FORG=1TOX
235 INPUT#8,PL$(G),NA$(G),SR$(G),IN$(G),DE$(G),LU$(G),HP$(G),HD$(G),RA$(G)
240 INPUT#8,LE$(G),AC$(G),TD$(G),A,A$:NEXTG:CLOSE8
245 OPEN4,4,0
247 A$="CHARACTER        PLAYER           RACE      ST IN DE LU HP LV DIED "
248 A$=A$+"POINTS":PRINT#4,A$
249 D$="----------------------------------------------------------------------"
250 D$=D$+"---":PRINT#4,D$
255 FORG=1TOX
260 A$=NA$(G)+LEFT$(F$,17-LEN(NA$(G)))+PL$(G)+LEFT$(F$,17-LEN(PL$(G)))
265 B$=HD$(G)+LEFT$(F$,3-LEN(HD$(G)))
267 C$=RA$(G)+LEFT$(F$,10-LEN(RA$(G)))
268 E$=TD$(G)+LEFT$(F$,5-LEN(TD$(G)))
270 PRINT#4,A$;C$;SR$(G);IN$(G);DE$(G);LU$(G);HP$(G);B$;E$;LE$(G)
275 NEXTG
280 PRINT#4,D$:CLOSE4:RUN100
290 PRINT"THERE ARE NO CHARCTERS HERE!"
295 FORG=1TO2000:NEXTG:GOTO110
300 PRINT"[147][PRINT MONSTERS]"
310 OPEN8,XI,8,"MONSTER,S,R":INPUT#8,X:IFX=0THEN350
312 DIMD$(X),B$(X):FORG=1TOX
315 INPUT#8,D$(G),B$(G):NEXTG:CLOSE8
317 OPEN4,4,0:PRINT#4,"#   MONSTER NAME       X.P"
318 PRINT#4,"----------------------------"
320 FORG=1TOX:A$=STR$(G):A$=RIGHT$(A$,LEN(A$)-1):A$=A$+LEFT$(F$,4-LEN(A$))
330 A$=A$+D$(G)+LEFT$(F$,19-LEN(D$(G)))
335 A$=A$+B$(G):PRINT#4,A$:NEXTG
340 PRINT#4,"----------------------------":CLOSE4:RUN100
350 CLOSE8:PRINT"THERE IS NO DATA HERE!":FORG=1TO2000:NEXTG:GOTO110
400 PRINT"[147][PRINT MAGIC ITEMS]":IFTM=0THEN350
410 X=TM:DIMNA$(X),FC$(X):OPEN3,XI,3,"MAGIC":OPEN15,XI,15:FORG=1TOX
420 PRINT#15,"P"CHR$(3)CHR$(G)CHR$(0)CHR$(1):INPUT#3,NA$(G)
425 PRINT#15,"P"CHR$(3)CHR$(G)CHR$(0)CHR$(19):INPUT#3,FC$(G):NEXTG
430 CLOSE15:CLOSE3:OPEN4,4,0
435 PRINT#4,"#   NAME OF ITEM       SPELLS"
440 PRINT#4,"--------------------------------------------------------"
445 FORG=1TOX:A$=STR$(G+199):A$=RIGHT$(A$,LEN(A$)-1)
450 A$=A$+" "+NA$(G)+LEFT$(F$,19-LEN(NA$(G)))+FC$(G)
455 PRINT#4,A$:NEXTG
460 PRINT#4,"--------------------------------------------------------"
465 CLOSE4:RUN100
500 PRINT"[147][PRINT WEAPONS]":IFTW=0THEN350
510 OPEN3,XI,3,"WEAPONS":OPEN15,XI,15:X=TW:DIMWE$(X),RE$(X)
515 FORG=1TOX:PRINT#15,"P"CHR$(3)CHR$(G)CHR$(0)CHR$(1):INPUT#3,WE$(G)
520 PRINT#15,"P"CHR$(3)CHR$(G)CHR$(0)CHR$(23):INPUT#3,RE$(G):NEXTG
525 CLOSE3:CLOSE15:OPEN4,4,0
530 PRINT#4,"#   WEAPON          DAMAGE RATE"
535 PRINT#4,"-------------------------------"
540 FORG=1TOX:B=1:C=1:D=1:Y$=WE$(G)
545 A$=MID$(Y$,B,1):IFA$="[166]"THENA$(C)=MID$(Y$,D,B-D):C=C+1:D=B+1:IFC=3THEN555
550 B=B+1:GOTO545
555 A$=STR$(G):A$=RIGHT$(A$,LEN(A$)-1):A$=A$+LEFT$(F$,4-LEN(A$))
560 A$=A$+A$(1)+LEFT$(F$,16-LEN(A$(1)))
565 A$=A$+"1-"+A$(2)+LEFT$(F$,5-LEN(A$(2)))+RE$(G)
570 PRINT#4,A$:NEXTG
575 PRINT#4,"-------------------------------":CLOSE4:RUN100
600 PRINT"[147][PRINT ARMOR]":IFTP=0THEN350
610 OPEN3,XI,3,"ARMOR":OPEN15,XI,15:X=TP:DIMWE$(X),RE$(X)
615 FORG=1TOX:PRINT#15,"P"CHR$(3)CHR$(G)CHR$(0)CHR$(1):INPUT#3,WE$(G)
620 PRINT#15,"P"CHR$(3)CHR$(G)CHR$(0)CHR$(22):INPUT#3,RE$(G):NEXTG
625 CLOSE3:CLOSE15:OPEN4,4,0
630 PRINT#4,"#   ITEM            RATE TYPE"
635 PRINT#4,"-----------------------------"
640 FORG=1TOX:B=1:C=1:D=1:Y$=WE$(G)
645 A$=MID$(Y$,B,1):IFA$="[166]"THENA$(C)=MID$(Y$,D,B-D):C=C+1:D=B+1
650 IFC=3THEN660
655 B=B+1:GOTO645
660 A$(3)=RIGHT$(WE$(G),LEN(WE$(G))-B):A$=STR$(G+699):A$=RIGHT$(A$,LEN(A$)-1)
665 IFA$(3)="A"THENL$="ARM":GOTO675
670 L$="SHD"
675 A$=A$+" "+A$(1)+LEFT$(F$,16-LEN(A$(1)))
680 A$=A$+RE$(G)+LEFT$(F$,5-LEN(RE$(G)))+L$:PRINT#4,A$:NEXTG
685 PRINT#4,"-----------------------------"
690 CLOSE4:RUN100
700 PRINT"[147][PRINT TRAPS]":IFTT=0THEN350
720 X=TT:DIMTR$(X):OPEN3,XI,3,"TRAPS":OPEN15,XI,15:FORG=1TOX
730 PRINT#15,"P"CHR$(3)CHR$(G)CHR$(0)CHR$(1):INPUT#3,TR$(G):NEXTG:CLOSE3
735 CLOSE15:OPEN4,4,0
737 PRINT#4,"#   TRAP            EFFECT"
738 PRINT#4,"--------------------------":FORG=1TOX
740 B$=RIGHT$(TR$(G),2):IFVAL(B$)<>0THEN755
745 IFB$="BK"THENB$="BLOCK":GOTO760
750 B$="TELE":GOTO760
755 B=VAL(B$):B$=STR$(B):B$=RIGHT$(B$,LEN(B$)-1):B$="1-"+B$
760 C$=LEFT$(TR$(G),LEN(TR$(G))-2):C$=C$+LEFT$(F$,16-LEN(C$))
765 A$=STR$(G):A$=RIGHT$(A$,LEN(A$)-1):A$=A$+LEFT$(F$,4-LEN(A$))
770 A$=A$+C$+B$:PRINT#4,A$:NEXTG
775 PRINT#4,"--------------------------":CLOSE4:RUN100
800 PRINT"[147][LIST DUNGEONS]"
820 OPEN8,XI,8,"LIST,S,R":INPUT#8,X:IFX=0THEN870
825 DIMDU$(X),CR$(X):FORG=1TOX:INPUT#8,DU$(G),CR$(G):NEXTG:CLOSE8
830 OPEN4,4,0:PRINT#4,"DUNGEONS ON THIS DISK:"
835 PRINT#4,"---------------------------------------":F$=".................."
840 FORG=1TOX:A$=DU$(G)+LEFT$(F$,19-LEN(DU$(G)))+"BY "+CR$(G)
845 PRINT#4,A$:NEXTG
850 PRINT#4,"---------------------------------------":CLOSE4:RUN100
870 PRINT"THERE ARE NO DUNGEONS ON THIS DISK!":FORG=1TO2000:NEXTG:GOTO110
900 PRINT"[147]":A1=0:OPEN8,8,8,"MASTER DISK,S,R":INPUT#8,A1:CLOSE8:IFA1<>7THEN44
905 IFUX=1THENUX=0:RETURN
910 POKE53280,0:POKE53265,PEEK(53265)AND239
915 CLR:FORG=631TO634:POKEG,13:NEXTG:POKE198,4
920 PRINT"[147]LOAD";CHR$(34);"ME";CHR$(34);",8":PRINT"RUN":END