100 SYS700
110 ;
120 .OPT OO
130 ;
140 ; 'COLOR CHASER', BY SCOTT E. RESH
150 ;
160 ;
170 ; CODE WILL BE AT $C000 (49152)
180 ;
190 LCMEM = $D800 - 40
200 R0L = $FB
210 R0H = R0L + 1
220 R1L = R0H + 1
230 R1H = R1L + 1
240 BKGRND = $D021
250 ;
260 ;
270 JMP INIT ;
280 JMP PAST ;
290 ;
300 ;
310 INIT LDX #3 ; COPY VALUES TO
320 L1 LDA R0L,X ;  LOCAL STORAGE
330 STA LOCAL,X ;
340 DEX ;
350 BPL L1 ;
360 ;
370 LDA R1L ; IF EITHER LENGTH = 0,
380 BEQ OOH ;  THEN EXIT, ELSE OK
390 LDA R1H ;
400 BNE OK1 ;
410 ;
420 OOH RTS ; RETURN TO BASIC
430 ;
440 OK1 DEC COLUMN ;
450 DEC ROW ;
460 ;
470 CLC ;
480 LDA XC ; IF X+COLUMN>39 THEN ERROR
490 ADC COLUMN ;
500 CMP #40 ;
510 BCS OOH ;
520 LDA YC ; IF Y+ROW>24 THEN ERROR
530 ADC ROW ;
540 CMP #25 ;
550 BCS OOH ;
560 ;
570 LDA #>LCMEM ; INIT COLORMEM PNTR
580 STA R0H ;
590 LDA #<LCMEM ;
600 STA R0L ;
610 LDX YC ; X = ROW COUNT
620 ;
630 CLC ; ADD IN ROW OFFSET
640 L2 LDA #40 ;  TO COLORMEM POINTER
650 ADC R0L ;
660 STA R0L ;
670 BCC OK2 ;
680 INC R0H ;
690 CLC ;
700 OK2 DEX ;
710 BPL L2 ;
720 ;
730 LDA XC ; ADD IN X-COORD TO
740 ADC R0L ;  COLORMEM POINTER
750 STA R0L ;
760 BCC OK3 ;
770 INC R0H ;
780 OK3 LDA R0L ; PRESERVE BASE PNTR
790 STA TEMP ;
800 LDA R0H ;
810 STA TEMP+1 ;
820 ;
830 LDY #0 ; FETCH COLOR SEED VALUE
840 LDA (R0L),Y ;
850 STA MAINC ;
860 ;
870 ;==================================
880 ;
890 PAST LDA TEMP ; INIT COLORMEM PNTR
900 STA R0L ;
910 LDA TEMP+1 ;
920 STA R0H ;
930 ;
940 LDA MAINC ; INIT COLOR VALUE FOR
950 STA COLOR ;  THIS ROUND
960 ;
970 DEC MAINC ; UPDATE COLOR VALUE
980 ; (NOTE: CHANGE 'DEC' TO 'INC' TO
990 ; MOVE COLORS COUNTER-CLOCKWISE)
1000 ;
1010 LDA BKGRND ; FETCH BACKGRND COLOR
1020 AND #15 ;  FOR 'CFETCH' ROUTINE
1030 STA BTEMP ;
1040 ;
1050 LDY #0 ;
1060 LDX COLUMN ; # CHARACTERS ACROSS
1070 ;
1080 L3 JSR FCOLOR ; MOVE COLOR LEFT TO
1090 STA (R0L),Y ;  RIGHT ALONG THE TOP
1100 INY ;
1110 DEX ;
1120 BPL L3 ;
1130 ;
1140 LDX ROW ;
1150 DEX ;
1160 LDY COLUMN ;
1170 ;
1180 L4 LDA R0L ; MOVE COLOR 'DOWN'
1190 CLC ;  ALONG THE RIGHT SIDE
1200 ADC #40 ;
1210 STA R0L ;
1220 BCC NC1 ;
1230 INC R0H ;
1240 NC1 JSR FCOLOR ;
1250 STA (R0L),Y ;
1260 DEX ;
1270 BNE L4 ;
1280 ;
1290 LDX COLUMN ;
1300 TXA ;
1310 CLC ;
1320 ADC #40 ;
1330 TAY ;
1340 ;
1350 DL JSR FCOLOR ; MOVE THE COLOR
1360 STA (R0L),Y ;  RIGHT TO LEFT ALONG
1370 DEY ;  THE BOTTOM
1380 DEX ;
1390 BPL DL ;
1400 ;
1410 LDY #0 ;
1420 LDX ROW ;
1430 DEX ;
1440 ;
1450 FINAL JSR FCOLOR ; MOVE THE COLOR
1460 STA (R0L),Y ;  'UP' ALONG THE
1470 LDA R0L ;  LEFT COLUMN
1480 SEC ;
1490 SBC #40 ;
1500 STA R0L ;
1510 BCS NBORROW ; DEC R0H ONLY IF A
1520 DEC R0H ;  'BORROW' COND. EXISTS
1530 NBORROW DEX
1540 BNE FINAL
1550 ;
1560 RTS ; RETURN TO BASIC
1570 ;
1580 FCOLOR LDA COLOR ; 'FETCH COLOR'
1590 INC COLOR ;  ROUTINE, GETS NEXT
1600 AND #15 ;  COLOR (WON'T ALLOW
1610 CMP BTEMP ;  BACKGROUND COLOR)
1620 BEQ FCOLOR ;
1630 RTS ;
1640 ;
1650 LOCAL .BYTE 0,0,0,0
1660 ;
1670 XC = LOCAL
1680 YC = LOCAL+1
1690 COLUMN = LOCAL+2
1700 ROW = LOCAL+3
1710 ;
1720 TEMP .WORD 0
1730 COLOR .BYTE 0
1740 MAINC .BYTE 0
1750 BTEMP .BYTE 0