10 IFY=0THENY=1:LOAD"FILECOPY.O",8,1
11 POKE56,32:CLR:DIM F$(100),T$(100)
12 GOSUB500
15 FL$="":F=32768
17 A=PEEK(F):IFA<>0THENFL$=FL$+CHR$(A):F=F+1:GOTO17
18 PRINT:PRINT"[208]RESS [211][208][193][195][197] TO START COPYING; [210][197][212][213][210][206] TO"
19 PRINT" RETURN TO [204][207][193][196][211][212][193][210]."
20 GETA$:IFA$<>" "ANDA$<>CHR$(13)THEN20
22 IFA$=CHR$(13)THEN131
25 OPEN2,8,2,"FILES ON SIDE "+SI$
30 INPUT#2,A$:I=ST:INPUT#2,NF$:NF=VAL(NF$)
35 FORX=1TONF:INPUT#2,F$(X),T$(X):NEXT
40 IFA$<>FL$ANDI=0THEN30
45 IFA$=FL$THEN50
47 PRINT"ERROR....FILE "FL$" NOT FOUND IN FILE!":STOP
48 :
50 CLOSE2:FORD=1TONF
55 POKE51,0:POKE52,32
56 PRINT"[145]                                       "
57 PRINT"[145][154][210]EADING:"F$(D)
60 OPEN1,8,2,F$(D):SYS49152
70 IFST<>64THENPRINT"ERROR..."ST:CLOSE1:STOP
80 CLOSE1
90 PRINT"       [201]NSERT [196]ESTINATION [196]ISK...      "
92 PRINT"    [208]RESS [211][208][193][195][197] WHEN READY TO COPY.":POKE198,.
94 GETA$:IFA$<>" "THEN94
95 PRINT"[145][145]";:FORA=1TO2:PRINT"                                      ":NEXT
96 PRINT"[145][145][145][145][154][215]RITING:"F$(D):GOSUB700
97 IFMM=1THEN90
98 IFMM=2THEN96
100 OPEN1,8,2,F$(D)+","+T$(D)+",W":SYS49196:CLOSE1
120 PRINT"          [201]NSERT [211]OURCE [196]ISK...      "
122 PRINT" [208]RESS [211][208][193][195][197] WHEN READY TO CONTINUE.":POKE198,.
124 GETA$:IFA$<>" "THEN124
125 GOSUB600:REM    IF(MM$<>DN$)THENGOSUB2000
126 PRINT"[145][145]";:FORA=1TO2:PRINT"                                       ":NEXT
127 PRINT"[145][145][145]";
129 NEXTD
130 PRINTSPC(13)"[196]ONE COPYING..."
131 OPEN15,8,15,"R0:HELLO CONNECT=HELLO CONNECT":INPUT#15,ER:CLOSE15
132 IFER<>63THENEND
133 POKE55,.:POKE56,160
134 LOAD"HELLO CONNECT",8:END
500 POKE53280,.:POKE53281,.
510 SYS51459:PRINT"[147]         [158][204][207][193][196][211][212][193][210] [198]ILE [195]OPIER"
520 GOSUB600:SI$=RIGHT$(DN$,1):MM$=DN$
550 PRINT" [154][208]LEASE [215]AIT -- [210]EADING [198]ILES [207]N [211]IDE "SI$:RETURN
600 OPEN15,8,15,"I0":OPEN8,8,8,"#"
610 PRINT#15,"UA:8 0 18 0"
620 PRINT#15,"B-P:8 144"
630 DN$="":FORA=1TO16:GET#8,A$:DN$=DN$+A$:NEXT:CLOSE8:CLOSE15:RETURN
700 OPEN15,8,15,"R0:"+F$(D)+"="+F$(D):INPUT#15,ER:CLOSE15
710 IFER<>63THENMM=.:RETURN
715 PRINT"[145]                                     "
720 PRINT"[145]"F$(D)" [154]ALREADY EXISTS..."
730 PRINT"     [212][154]RY AGAIN WITH ANOTHER DISK."
740 PRINT"     [211][154]CRATCH AND REPLACE FILE."
760 PRINT"[195]HOOSE [212][154], OR [211][154]."
770 GETA$:IFA$=""THEN770
780 IFA$="T"ORA$="[212]"THEN820
790 IFA$="S"ORA$="[211]"THEN840
810 GOTO770
820 GOSUB1000:MM=1:RETURN
840 GOSUB1000:PRINT"[154][211]CRATCHING:"F$(D)
850 OPEN15,8,15,"S0:"+F$(D):CLOSE15:PRINT"[145]                                    "
860 MM=2:RETURN
1000 PRINT"[145][145][145][145][145][145]";:FORA=1TO6:PRINT"                                       "
1010 NEXT:PRINT"[145][145][145][145][145]";:RETURN
2000 PRINT"[145][145]"MM$" IS NOT IN THE DRIVE."