50 IFLL>0THEN63005
100 REM ***********************
110 REM   SIMPLE WINDOWING
120 REM   FOR THE COMMODORE 64
140 REM ***********************
160 REM
170 PRINTCHR$(147):POKE53280,0:POKE53281,0
180 CC$=CHR$(19):FORX=1TO23:CC$=CC$+CHR$(17):NEXT:REM CURSOR CONTROL
190 BL$="                                     ":REM 38 SPACES
200 FORX=1TO39:LINE$=LINE$+CHR$(192):NEXT
210 GOSUB810 :REM POKE IN ML ROUTINE
220 REM
230 REM ************************
240 REM PRINT SAMPLE TEXT SCREEN
250 REM ************************
260 REM
270 PRINTCHR$(147);:REM CLEAR SCREEN
280 PRINTCHR$(5);:REM WHITE
290 PRINTCHR$(14);:REM LOWERCASE
300 PRINT"[212]HIS IS A SAMPLE TEXT SCREEN."
310 PRINT
320 PRINTCHR$(153);:REM LIGHT GREEN
330 PRINT"[198]OURSCORE AND SEVEN YEARS AGO OUR"
340 PRINT"FATHERS BROUGHT FORTH ON THIS CONTI-"
350 PRINT"NENT A NEW NATION CONCEIVED IN"
360 PRINT"LIBERTY AND DEDICATED TO THE PRO-"
370 PRINT"POSITION THAT ALL MEN ARE CREATED"
380 PRINT"EQUAL.  [206]OW WE ARE ENGAGED IN A GREAT"
390 PRINT"CIVIL WAR TESTING WHETHER THAT NATION,"
400 PRINT"OR ANY NATION SO CONCEIVED AND SO"
410 PRINT"DEDICATED, CAN LONG ENDURE.  [215]E ARE"
420 PRINT"MET ON A GREAT BATTLEFIELD OF THAT WAR."
430 PRINT"[215]E HAVE COME TO DEDICATE A PORTION OF"
440 PRINT"THAT FIELD AS A FINAL RESTING-PLACE"
450 PRINT"FOR THOSE WHO HERE GAVE THEIR LIVES"
460 PRINT"THAT THAT NATION MIGHT LIVE.  [201]T IS"
470 PRINT"ALTOGETHER FITTING AND PROPER THAT"
480 PRINT"WE SHOULD DO THIS..."
490 PRINT
500 PRINTCHR$(150);:REM LIGHT RED
510 PRINT"([198]ROM [193]. [204]INCOLN'S [199][197][212][212][217][211][194][213][210][199] [193][196][196][210][197][211][211])"
520 PRINTCC$;CHR$(18);CHR$(5);
530 PRINT"[145][208]RESS SPACEBAR FOR WINDOW."
531 PRINT"[208]RESS _ TO EXIT.";
540 PRINTCHR$(19)
550 POKE198,0:WAIT198,1:GETA$:IFA$="_"THEN63000
555 IFA$<>" "THEN550
560 SYS49152:REM MEMORIZE SCREEN
570 REM
580 REM **********************
590 REM PRINT WINDOW OVER TEXT
600 REM **********************
610 REM
620 PRINTLEFT$(CC$,8);
630 PRINTCHR$(158);:REM YELLOW
640 PRINTTAB(6);CHR$(18);CHR$(176);LEFT$(LINE$,19);CHR$(174)
650 PRINTTAB(6);CHR$(18);CHR$(221);" [208]RESS ANY KEY TO  ";CHR$(221)
660 PRINTTAB(6);CHR$(18);CHR$(221);" ELIMINATE WINDOW  ";CHR$(221)
670 PRINTTAB(6);CHR$(18);CHR$(221);" AND GO BACK TO    ";CHR$(221)
680 PRINTTAB(6);CHR$(18);CHR$(221);" THE TEXT SCREEN.  ";CHR$(221)
690 PRINTTAB(6);CHR$(18);CHR$(173);LEFT$(LINE$,19);CHR$(189)
700 PRINTCC$;"[145]"BL$:PRINTBL$CHR$(19)
710 POKE198,0:WAIT198,1:GETA$
720 SYS49214:REM RECALL SCREEN
730 GOTO520
740 REM
750 REM
760 REM **************************
770 REM POKE IN SAVE/SWAP ROUTINE
780 REM SYS 49152 TO SAVE SCREEN
790 REM SYS 49214 TO RECALL SCREEN
800 REM **************************
810 FORJ=49152TO49289:READA:POKEJ,A:NEXT:RETURN
820 DATA 32,124,192,162,0,189,0,4,157,0,193,189,0,5,157,0
830 DATA 194,189,0,6,157,0,195,189,0,216,157,0,197,189,0,217
840 DATA 157,0,198,189,0,218,157,0,199,202,208,217,162,216,189,0
850 DATA 7,157,0,196,189,0,219,157,0,200,202,208,241,96,32,124
860 DATA 192,162,0,189,0,193,157,0,4,189,0,194,157,0,5,189
870 DATA 0,195,157,0,6,189,0,197,157,0,216,189,0,198,157,0
880 DATA 217,189,0,199,157,0,218,202,208,217,162,216,189,0,196,157
890 DATA 0,7,189,0,200,157,0,219,202,208,241,96,162,0,181,217
900 DATA 9,128,149,217,232,224,25,208,245,96
63000 REM   RETURN TO LS
63005 IFLL=0THENLL=1:LOAD"SIDIRQ V3",8,1
63006 IFLL=1THENLL=2:LOAD"ROMUSIC",8,1
63007 POKE51200,75:POKE52106,33
63010 PRINT"[147]LOAD"CHR$(34)"PAYLOAD"CHR$(34)",8":PRINT"RUN"
63020 POKE631,13:POKE632,13:POKE198,2:END