1 GOSUB50000
3 Q$="[205][194][206]-"
5 Z=7440:Y=41261
6 W=9:PAU=4
10 PRINT"[147]"
1000 PRINT"[147]FIND THE GREATEST COMMON DIVISOR."
1010 PRINT:PRINT"GIVE ME TWO NUMBERS IN THE FORMAT A,B   OR HIT RETURN FOR";
1011 PRINT" AN EXAMPLE."
1015 INPUT">";A$,B$:A=VAL(A$):B=VAL(B$)
1020 IFLEN(A$)>11 OR LEN(B$)>11 THEN10000
1021 IFA=0ORB=0THENA=Z:B=Y
1022 A=ABS(A):B=ABS(B)
1023 Z=A:Y=B
1024 PRINTTAB(13);A","B
1025 PRINT
1030 X=A
1040 IFB<XTHENX=B:B=A:A=X
1050 X=INT(B/A)
1060 R=B-X*A
1061 PRINTSPC(12-LEN(STR$(B)))
1065 PRINTB" ="X" * "A" + "R
1070 IFR=0THENGCD=A:GOTO1200
1080 B=A:A=R
1090 GOTO1050
1200 PRINT:PRINT"THE GREATEST DIVISOR IS:"GCD
1202 PRINT:PRINT"THE LEAST COMMON MULTIPLE IS:"Z*Y/GCD:PRINT
1203 PRINT"";
1205 PRINTTAB(W);"[ ] TOUCH ANY KEY [ ] Q-QUITS";
1206 FORI=1TOLEN(Q$)
1207 POKE783,PEEK(783)AND253:POKE781,22:POKE782,W+1:SYS65520:PRINTMID$(Q$,I,1);
1208 PRINTSPC(17)MID$(Q$,LEN(Q$)+1-I,1);:FORS=0TOPAU:IFPEEK(197)<>64 THEN1210
1209 NEXT:NEXT:GOTO1206
1210 GETA$:IFA$<>"Q"THEN1000
1300 PRINT"[147]BYE.":FORDL=1TO500:NEXTDL
1305 PRINT"[147]LOAD"CHR$(34)"PRESENTER"CHR$(34)",8":PRINT"RUN"
1310 POKE54296,0:POKE631,13:POKE632,13:POKE65535,23:POKE198,2:END
1400 :
10000 REM   ERROR ROUTINE
10010 PRINT"[147]WE HAVE ENCOUNTERED AN ERROR."
10020 PRINT"PLEASE BE SURE YOU ARE ENTERING VALID"
10030 PRINT"VALUES FOR THE NUMBERS REQUESTED."
10040 PRINT"PRESS <SPACE BAR> TO CONTINUE."
10050 POKE198,0:WAIT198,1:GETA$:POKE198,0:RUN
50000 T$="                         ":C=0:C$="":PRINT"[147]"CHR$(142):POKE53281,0
50030 PRINTSPC(7)""T$:PRINTSPC(7)"           GCD           [146]"
50051 PRINTSPC(7)""T$:PRINT:PRINTTAB(18)"BY"
50060 PRINT:PRINTSPC(12)"BRYAN VEKOVIUS"
50061 PRINT" TRANSLATED TO THE C-64 BY ALAN GARDNER"
50070 PRINT:PRINTSPC(12)"COPYRIGHT 1985"
50080 PRINT:PRINT:PRINT:PRINT"     LOADSTAR IS NOT PUBLIC DOMAIN."
50090 PRINT:PRINT"  PLEASE RESPECT THE AUTHOR'S RIGHTS."
50100 PRINT:PRINT"      PRESS SPACE BAR TO CONTINUE."
50110 FORCC=1TO48:GETK$:IFK$=" "THEN50130
50120 IFCC=1THENPRINTMID$(C$,C+2,1)"[145][145]";:C=NOT(C)
50125 NEXT:GOTO50100
50130 PRINTC$:RETURN