0 GOSUB60000
1 PRINT"[146]":DIMW$(600),Z(49),A$(6,10),U$(6,10),S$(14),S(6,10),G(6,50):W=1
2 Q$(1)="OFF":FW=1:DE=.:RV=1:FL(0)=1:FL(1)=0:Z=1:RE=.:NU=10:F=1:REM
3 S$(2)="             ":S$(3)="            ":S$(4)="           ":POKE788,52
4 S$(6)="         ":S$(7)="        ":S$(8)="       ":S$(9)="      "
5 S$(10)="     ":S$(11)="    ":S$(12)="   ":S$(13)="  ":Q$(0)="ON "
6 S$(5)="          ":S$(1)="              ":S$(0)="               ":S$(14)=" "
10 POKE53280,3:POKE53281,3:PRINT"[144][147]                 FLASH                  ";
11 PRINT"           BY D.J.B. SHIBLEY             ";:REM
12 FORJ=1TO22:PRINT"  ";:NEXT:REM
13 PRINT"                                      [157][148] [146]";:GOTO100
20 X$=W$(RND(0)*T):IFX$=L3$ORX$=L2$ORX$=L1$ORX$=L0$THEN20
22 L3$=L2$:L2$=L1$:L1$=L0$:L0$=X$:L=LEN(X$):A$(H,I)=X$:POKE788,49
25 X=RND(0)*(39-L):Y=RND(0)*25:IFRS=1THENX=(40-L)/2:Y=11
28 PRINT"[147]";:FORJ=1TOX:PRINT"";:NEXT:FORJ=1TOY:PRINT"";:NEXT
30 X=DE*60+TI
32 IFTI<XTHEN32
35 IFRV=0THENPRINT"";
40 IFFW=0THENPRINT"*[157]";:FORJ=0TO600:NEXT:PRINT" [157]";
42 FORJ=0TO9:GETX$:NEXT:PRINT"[180]";L0$;"[170]";:FORJ=1TOL+1:PRINT"[157]";:NEXT
45 X=TI+C:Y$=""
46 IFTI<XTHEN46
48 FORJ=1TOL:PRINT" ";:NEXT:FORJ=1TOL:PRINT"[157]";:NEXT:B=TI
50 GETX$:X=ASC(X$+CHR$(0)):Y=LEN(Y$):IFX=13THEN69
52 IF(X=20ORX=157)ANDY<1THEN50
55 IFX=20ORX=157THENY$=LEFT$(Y$,Y-1):PRINT"[157] [157]";:GOTO50
57 IF(X<65ORX>90)ANDX$<>" "ANDX$<>"-"THEN50
60 Y$=Y$+X$:PRINTX$;:IFY<L-1THEN50
69 U$(H,I)=Y$:POKE788,52:RETURN
70 PRINT"[144] # WORD           GUESS           SCORE ";
72 PRINT"[144][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184]";
74 FORJ=1TONU:PRINTJ;:IFJ=10THENPRINT"[157]";
75 PRINTA$(H,J);U$(H,J);S(H,J);"[157]% "
76 NEXT
77 PRINT"          YOUR AVERAGE IS";INT(G(H,Z));"[157]%  ":RETURN
100 PRINT"  PRESS  1 - 6  FOR NUMBER OF PLAYERS"
102 PRINT"  PRESS   '[207]'   FOR THE  OPTION  MENU"
104 GETX$:IF(VAL(X$)<1ORVAL(X$)>6)ANDX$<>"O"ANDX$<>"0"THEN104
110 IFX$<>"O"ANDX$<>"0"THEN180
115 POKE53280,10:POKE53281,2:PRINT"[147]"
120 PRINT"1 - NUMBER OF WORDS PER ROUND IS";NU;"[157] "
122 PRINT"2 - RANDOM SCREEN IS TURNED ";Q$(RS);""
125 PRINT"3 - FOREWARN IS TURNED ";Q$(FW);""
128 PRINT"4 - REVERSE VIDEO IS TURNED ";Q$(RV);""
130 PRINT"5 - DELAY BETWEEN WORDS IS";DE;"SEC.";""
135 PRINT"   PRESS NUMBER TO CHANGE  OR RETURN   [145]"
140 GETX$:IF(VAL(X$)<1ORVAL(X$)>5)ANDX$<>CHR$(13)THEN140
145 IFX$=CHR$(13)THEN10
148 IFX$="2"THENRS=FL(RS):GOTO120
150 IFX$="3"THENFW=FL(FW):GOTO120
153 IFX$="4"THENRV=FL(RV):GOTO120
155 IFX$="5"THEN170
158 PRINT"  RETURN NUMBER OF WORDS  (10 MAX)  [157]";
160 GETX$:IFVAL(X$)<1ANDX$<>CHR$(13)ANDX$<>"0"THEN160
161 IFX$=CHR$(13)THENNU=10:GOTO120
162 PRINTX$;
165 GETY$:IFVAL(Y$)<1ANDY$<>"[157]"ANDY$<>CHR$(13)ANDY$<>CHR$(20)ANDY$<>"0"THEN165
166 IFY$="[157]"ORY$=CHR$(20)THENPRINT"[157] [157]";:GOTO160
167 PRINTY$;:NU=VAL(X$+Y$):IFNU>10THENNU=10
168 IFNU<1THENNU=1
169 GOTO120
170 PRINT"       PRESS 0 - 5 FOR NEW DELAY      "
172 GETX$:IF(VAL(X$)<1ORVAL(X$)>5)ANDX$<>"0"THEN172
175 DE=VAL(X$):GOTO120
180 N=VAL(X$):IFN=1THENN$(N)="PLAYER 1":GOTO190
185 POKE53280,4:PRINT"[147]":FORJ=1TON:N$(J)="PLAYER"+STR$(J):PRINT"";N$(J)
187 INPUT"RETURN YOUR NAME";N$(J):N$(J)=LEFT$(N$(J),8)
188 IFLEN(N$(J))<8THENN$(J)=N$(J)+" ":GOTO188
189 NEXT
190 POKE53280,7:PRINT"[147]  DEPRESS DESIRED SKILL LEVEL  (1-3)"
192 GETK$:IFVAL(K$)<1ORVAL(K$)>3THEN192
200 OPEN2,8,2,"0:RCLST"+K$+",S,R":INPUT#2,T:POKE53280,2:IFST=0THEN250
210 PRINT"INSERT - PROPER DISK FOR VOCABULARY LOAD":CLOSE2:GOTO200
250 POKE53281,15:PRINT"[147][144] [208]LEASE WAIT WHILE [201] LOAD MY VOCABULARY"
255 FORJ=0TOT:INPUT#2,W$(J):NEXT:CLOSE2
260 FORH=1TON:FORJ=0TO9:GETX$:NEXT:C=40
261 PRINT"[147][144]   PRESS ANY KEY WHEN READY TO START[145][145][145][145]"
262 PRINTSPC((40-LEN(N$(H)))/2);N$(H);"[145]"
264 FORJ=1TO100:GETX$:IFX$<>""THENJ=100
266 NEXT:IFX$<>""THEN305
268 PRINT"                                       [145]"
270 FORJ=1TO50:GETX$:IFX$<>""THENJ=50
274 NEXT:IFX$=""THEN262
305 GETX$:GETX$:GETX$:FORI=1TONU:GOSUB20
350 B=TI-B:M=0:FORJ=1TOL:IFMID$(A$(H,I),J,1)<>MID$(U$(H,I),J,1)THENM=M+1
365 NEXT:S(H,I)=((L-M)/L)*75
370 IFB<L/(VAL(K$)*2.1)*60THENS(H,I)=S(H,I)+25:GOTO390
375 S(H,I)=S(H,I)+(((L/(VAL(K$)*2.1))*60)/B)*25
390 C=C*.9:IFI<2THEN480
410 V=(S(H,I)+S(H,I-1)+S(H,I-2))/3:IFV>85THENC=C-(1/(101-V))*(C/10)
411 IFV<70THENC=C+(70-V)/70*(C/5)
480 NEXT
482 G(H,Z)=.:FORJ=1TONU:G(H,Z)=G(H,Z)+S(H,J):S(H,J)=INT(S(H,J))
483 IFLEN(A$(H,J))<14THENA$(H,J)=A$(H,J)+S$(LEN(A$(H,J)))
485 IFLEN(U$(H,J))<14THENU$(H,J)=U$(H,J)+S$(LEN(U$(H,J)))
486 NEXT:G(H,Z)=G(H,Z)/NU
490 PRINT"[147]":GOSUB70
538 PRINT" ";N$(H);" PRESS SHIFT KEY TO HOLD FRAM [157][148]E"
540 FORJ=1TO4000:NEXT
545 IFPEEK(653)=1THEN545
550 NEXT:PRINT"[157][157] [157][148] ":FORJ=0TO9:GETX$:NEXT
555 FORH=1TON:PRINT" ";N$(H):GOSUB70:X=0
560 FORJ=1TO5
562 FORDL=1TO100:NEXTDL
565 PRINT"  PRESS STOP KEY TO END OR N-NEXT ROUND[145]"
570 FORK=1TO70:GETX$:IFX$=""ORX$="N"ORX$="[206]"THENK=70
572 NEXT:IFX$=""ORX$="N"ORX$="[206]"THENJ=5:GOTO590
575 PRINT"                                       "
576 IFPEEK(653)=0ANDX=1THENJ=5:GOTO590
577 FORK=1TO40:GETX$:IFX$=""ORX$="N"THENK=40
580 NEXT:IFX$=""ORX$="N"THENJ=5
582 IFPEEK(653)=0ANDX=1THENJ=5
590 NEXT:IFPEEK(653)=1THENX=1:GOTO560
592 IFX$=""ORX$="N"THENH=N
595 NEXT:IFX$<>""ANDX$<>"N"THEN555
598 IFX$="N"ANDZ<50THENZ=Z+1:GOTO260
600 POKE53280,4:POKE53281,3:PRINT"[147][158]";
605 PRINT"                                         ";
610 FORJ=0TO22:PRINT"  ";:NEXT
615 PRINT"                                      [157][148] [144]"
617 PRINT"GAME OVER"
618 PRINT"";Z;"ROUNDS PLAYED"
619 PRINT"[184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][144]"
620 FORJ=1TON:FORK=1TOZ:X(J)=X(J)+G(J,K):NEXT:X(J)=X(J)/Z:NEXT
625 FORJ=1TON:X=.:Y=.:FORK=1TON:IFX(K)>XTHENY=K:X=X(K)
628 NEXT:PRINT"";N$(Y);" YOUR OVERALL AVERAGE IS";INT(X(Y));"[157]%"
630 X(Y)=.:NEXT:GOTO63000
60000 T$="                         ":C=0:C$="":PRINT"[147]":POKE53281,0
60030 PRINTSPC(7)""T$:PRINTSPC(7)"         [198]LASH           [146]"
60051 PRINTSPC(7)""T$:PRINT:PRINTTAB(18)"BY"
60060 PRINT:PRINTSPC(14)"[196][202][194] [211]HIBLEY"
60070 PRINT:PRINTSPC(12)"[195]OPYRIGHT 1985"
60080 PRINT:PRINT:PRINT:PRINT"     [204][207][193][196][211][212][193][210] IS NOT PUBLIC DOMAIN."
60090 PRINT:PRINT"  [208]LEASE RESPECT THE AUTHOR'S RIGHTS."
60100 PRINT:PRINT"      [208]RESS SPACE BAR TO CONTINUE."
60110 FORCC=1TO48:GETK$:IFK$=" "THEN60130
60120 IFCC=1THENPRINTMID$(C$,C+2,1)"[145][145]";:C=NOT(C)
60125 NEXT:GOTO60100
60130 PRINTC$:RETURN
63000 REM   CONNECT BACK TO LOADSTAR
63002 PRINT"          [208]LEASE PRESS A KEY"
63003 POKE198,0:WAIT198,1
63010 PRINT"[147]LOAD"CHR$(34)"PAYLOAD"CHR$(34)",8":PRINT"RUN"
63020 POKE631,13:POKE632,13:POKE198,2:POKE788,49:END