10 REM *** SPECTRUM BY DONNA K. WOODY  7-18-84 ***
15 POKE783,PEEK(783)AND254:F=54272:POKEF+24,8:POKEF+6,0:POKEF+1,255:POKEF+4,8
20 GOSUB40000:GOSUB20000
30 GOSUB20200:GOTO9000
98 :
99 REM *** UPDATE SOURCE & DROP PILES ***
100 CD=CD-1:C$(SP,0,0)=STR$(CD):REM REMOVE CARD FROM SOURCE PILE
110 LF=LF+1:REM INC DROP PILE
120 C$(DP,0,0)=STR$(LF):C$(DP,LF,0)=C$(SP,CD+1,0):RETURN:REM TRANSFER CARD
148 :
149 REM *** PRINT SOURCE CARD ***
150 IFQF=1THENRETURN
155 XP=SP:XC=CD:GOSUB200:Q$=CA$:GOSUB5000
160 Q=Q+1:W=W+1:Q$=C$(SP,CD,0):GOSUB5000:GOSUB300:RETURN
198 :
199 REM *** GET POSITION TO UPDATE CARD ***
200 Q1=VAL(P$(XP,1)):W1=VAL(P$(XP,0)):REM READ Q & W START POSITIONS
210 Q2=VAL(P$(XP,3)):W2=VAL(P$(XP,2)):REM READ Q & W OFFSET VALUES
220 MX=VAL(P$(XP,4)):C2=XC:REM VALUE OF MAX # CARDS IN PILE
230 IFXC>MXTHENIFMX<>0THENC2=MX
233 C2=C2-1
240 Q=Q1+(Q2*C2):W=W1+(W2*C2):RETURN
298 :
299 REM *** SOUND ROUTINE ***
300 POKEF+24,6:POKEF+5,128:POKEF+4,129:FORI=1TO50:NEXT:POKEF+4,128:POKEF+5,0
310 POKEF+24,0:POKEF+24,15:POKEF+4,129:POKEF+4,128:RETURN
798 :
799 REM *** DROP ON SAME SUIT ***
800 FLAG=1:LC$=C$(SP,CD,0):SS$=RIGHT$(LC$,1)
810 LF=VAL(C$(DP,0,0)):LF$=C$(DP,LF,0):DS$=RIGHT$(LF$,1)
820 IFSS$=DS$THENFLAG=1:RETURN
830 FLAG=-1:RETURN
998 :
999 REM *** DROP ON CORRECT INCREMENT ***
1000 FLAG=1:CJ=VAL(P$(DP,7)):CJ$=P$(DP,8):IFCJ$="0"THENFLAG=-1:RETURN
1010 IFCJ$="-"THENCJ=-1*CJ
1020 RP$=MID$(C$(SP,CD,0),2,1):GOSUB5100:RS=RP
1030 RP$=MID$(C$(DP,LF,0),2,1):GOSUB5100:RD=RP
1040 IFRD=RS+CJTHENGOTO1070
1050 IFRD=13THENIFRS=1THENGOTO1056
1052 IFRD=1THENIFRS=13THENGOTO1060
1054 GOTO1072
1056 IF(DP=1ORDP=2ORDP=3ORDP=4)THENGOTO1070
1058 GOTO1072
1060 IF(DP=1ORDP=2ORDP=3ORDP=4)THENGOTO1072
1062 GOTO1070
1070 FLAG=1:RETURN
1072 FLAG=-1:RETURN
1098 :
1099 REM *** DROP ON OPPOSITE COLOR ***
1100 FLAG=1:IFLEFT$(C$(SP,CD,0),1)<>LEFT$(C$(DP,LF,0),1)THENFLAG=1:RETURN
1110 FLAG=-1:RETURN
4998 :
4999 REM *** PRINT STRING ***
5000 POKE781,Q:POKE782,W:SYS65520:PRINTQ$:RETURN
5098 :
5099 REM *** GET RANK AND VALUE ***
5100 IFRP$="1"THENRP$="10":RP=VAL(RP$):RETURN
5110 IFRP$="J"THENRP$="11":RP=VAL(RP$):RETURN
5120 IFRP$="Q"THENRP$="12":RP=VAL(RP$):RETURN
5130 IFRP$="K"THENRP$="13":RP=VAL(RP$):RETURN
5140 IFRP$="A"THENRP$="1":RP=VAL(RP$):RETURN
5141 RP=VAL(RP$):RETURN
5148 :
5149 REM *** KEYBOARD MOVEMENT ***
5150 IFVAL(C$(10,0,0))=0ANDVAL(C$(11,0,0))=0THEN5170
5155 POKE1820,30:POKE56092,0:GOSUB5300:IFQF=1THENRETURN
5157 IFA<>32ANDA<>13THEN5150
5158 POKE1820,32:IFA=13THENPI=11:RETURN
5160 POKE1540,30:POKE55812,0:GOSUB5300:IFQF=1THENRETURN
5162 IFA<>32ANDA<>13THEN5160
5165 POKE1540,32:IFA=13THENPI=10:RETURN
5170 IFVAL(C$(5,0,0))=0THEN5180
5172 POKE1426,30:POKE55698,0:GOSUB5300:IFQF=1THENRETURN
5174 IFA<>32ANDA<>13THEN5170
5175 POKE1426,32:IFA=13THEN PI=5:RETURN
5180 POKE1833,30:POKE56105,0:GOSUB5300:IFQF=1THENRETURN
5182 IFA<>32ANDA<>13THEN5180
5185 POKE1833,32:IFA=13THEN PI=6:RETURN
5190 POKE1840,30:POKE56112,0:GOSUB5300:IFQF=1THENRETURN
5192 IFA<>32ANDA<>13THEN5190
5195 POKE1840,32:IFA=13THEN PI=7:RETURN
5200 POKE1847,30:POKE56119,0:GOSUB5300:IFQF=1THENRETURN
5202 IFA<>32ANDA<>13THEN5200
5205 POKE1847,32:IFA=13THEN PI=8:RETURN
5210 POKE1854,30:POKE56126,0:GOSUB5300:IFQF=1THENRETURN
5212 IFA<>32ANDA<>13THEN5210:
5215 POKE1854,32:IFA=13THEN PI=9:RETURN
5220 POKE1116,31:POKE55388,0:GOSUB5300:IFQF=1THENRETURN
5222 IFA<>32ANDA<>13THEN5220
5225 POKE1116,32:IFA=13THEN PI=1:RETURN
5230 POKE1123,31:POKE55395,0:GOSUB5300:IFQF=1THENRETURN
5232 IFA<>32ANDA<>13THEN5230
5235 POKE1123,32:IFA=13THEN PI=2:RETURN
5240 POKE1130,31:POKE55402,0:GOSUB5300:IFQF=1THENRETURN
5242 IFA<>32ANDA<>13THEN5240
5245 POKE1130,32:IFA=13THEN PI=3:RETURN
5250 POKE1137,31:POKE55409,0:GOSUB5300:IFQF=1THENRETURN
5252 IFA<>32ANDA<>13THEN5250
5255 POKE1137,32:IFA=13THEN PI=4:RETURN
5260 GOTO5150
5298 :
5299 REM *** GET KEY PRESS ***
5300 IFQF=1THENRETURN
5310 POKE198,0:WAIT198,1:GETA$:A=ASC(A$)
5320 IFA=42ANDCH=-1THEN5310
5340 IFA=42THENGOSUB9400:GOTO5300
5350 RETURN
5398 :
5399 REM *** DROP CARD ON FOUNDATIONS ***
5400 LF=VAL(C$(DP,0,0)):IFLF>0THEN5410
5405 IFP$(DP,5)=MID$(C$(SP,CD,0),2,1)THEN5430
5410 GOSUB800:IFFLAG=-1THENGOSUB150:RETURN
5420 GOSUB1000:IFFLAG=-1THENGOSUB150:RETURN
5430 Q=VAL(P$(DP,1)):W=VAL(P$(DP,0)):Q$=CA$:GOSUB5000
5440 Q=Q+1:W=W+1:Q$=C$(SP,CD,0):GOSUB5000:GOSUB300
5450 GOSUB100:XP=SP:XC=CD:GOSUB200
5460 IFCD=0THENRETURN
5470 Q$=CA$:GOSUB5000:Q=Q+1:W=W+1:Q$=C$(SP,CD,0):GOSUB5000:GOSUB300:RETURN
5498 :
5499 REM *** PICK UP CARD ***
5500 CD=VAL(C$(SP,0,0)):XC=CD:XP=SP:GOSUB200
5510 Q$=ER$:GOSUB5000:IFCD=1THENRETURN
5520 IF(SP=5ORSP=10)THEN5535
5525 XC=CD-1:XP=SP:GOSUB200:Q$=CA$:GOSUB5000:Q$=C$(SP,CD-1,0)
5530 Q=Q+1:W=W+1:GOSUB5000:GOSUB300:RETURN
5535 Q$=CA$:GOSUB5000:Q$=BL$:XC=CD:XP=SP:GOSUB200:GOSUB5000:RETURN
5598 :
5599 REM *** DROP CARD ON BUILDING PILE ***
5600 LF=VAL(C$(DP,0,0)):IFLF=0THEN5660
5620 GOSUB1100:IFFLAG=-1THENGOSUB150:RETURN
5630 GOSUB1000:IFFLAG=-1THENGOSUB150:RETURN
5640 XP=DP:XC=LF+1:GOSUB200:Q$=CA$:GOSUB5000:Q=Q+1:W=W+1:Q$=C$(SP,CD,0)
5650 GOSUB5000:GOSUB300:GOTO5680
5660 Q=VAL(P$(DP,1)):W=VAL(P$(DP,0)):Q$=CA$:GOSUB5000:Q=VAL(P$(DP,1))
5670 W=VAL(P$(DP,0)):Q$=C$(SP,CD,0):Q=Q+1:W=W+1:GOSUB5000:GOSUB300
5680 GOSUB100
5690 IFCD=0THENRETURN
5700 IFSP=5ORSP=10THENXP=SP:GOSUB150:RETURN
5710 XP=SP:XC=CD:GOSUB200:Q$=C$(SP,CD,0):Q=Q+1:W=W+1:GOSUB5000:GOSUB300:RETURN
5798 :
5799 REM *** PICK UP CARD FROM HAND & DROP ON WASTE PILE ***
5800 CD=VAL(C$(SP,0,0)):DP=10:LF=VAL(C$(DP,0,0))
5802 IFCD=0ANDLF=0THENRETURN
5804 IFCD=0ANDD2=1THENGOSUB6000:RETURN
5805 IFCD=0THEND2=D2+1:GOSUB5900
5810 Q=VAL(P$(DP,1)):W=VAL(P$(DP,0)):Q$=CA$:GOSUB5000
5820 Q=Q+1:W=W+1:Q$=C$(SP,CD,0):GOSUB5000:GOSUB300
5830 GOSUB100:IFCD=0THENQ=VAL(P$(SP,1)):W=VAL(P$(SP,0)):Q$=ER$:GOSUB5000
5840 RETURN
5898 :
5899 REM *** REDEAL ***
5900 C$(11,0,0)=STR$(LF):C$(10,0,0)=STR$(CD):FORX=1TO40:C$(11,X,0)="":NEXT
5920 FORX=LFTO1STEP-1:C$(11,X,0)=C$(10,LF-X+1,0):NEXT:CD=LF:LF=0
5930 Q=VAL(P$(10,1)):W=VAL(P$(10,0)):Q$=BL$:GOSUB5000
5940 Q=VAL(P$(11,1)):W=VAL(P$(11,0)):Q$=CA$:GOSUB5000:Q$=BA$:GOSUB5000:GOSUB300
5950 RETURN
5998 :
5999 REM *** NO MORE REDEALS ***
6000 Q=22:W=0:Q$=SP$+SP$:GOSUB5000
6010 Q=22:W=0:Q$="NO MORE RE-DEALS ALLOWED.  YOU MUST USE THE CARDS YOU HAVE."
6020 Q$=Q$+"       -- * TO QUIT":GOSUB5000:RETURN
8888 :
8889 REM *** INITIAL SET UP ***
9000 PRINTCHR$(147):FLAG=1:CH=1:W=VAL(P$(1,0)):Q=VAL(P$(1,1)):Q$=CA$:GOSUB5000
9005 Q=Q+1:W=W+1:Q$=C$(1,1,0):GOSUB5000:GOSUB300
9010 W=VAL(P$(5,0)):Q=VAL(P$(5,1)):Q$=CA$:GOSUB5000
9015 Q=Q+1:W=W+1:Q$=C$(5,7,0):GOSUB5000:GOSUB300
9020 FORX=6TO9:W=VAL(P$(X,0)):Q=VAL(P$(X,1)):Q$=CA$:GOSUB5000
9022 Q=Q+1:W=W+1:Q$=C$(X,1,0):GOSUB5000:GOSUB300:NEXT
9030 W=VAL(P$(11,0)):Q=VAL(P$(11,1)):Q$=CA$:GOSUB5000:Q$=BA$:GOSUB5000:GOSUB300
9040 Q=22:W=0
9045 Q$="[144]MOVE ARROW WITH SPACE BAR - USE RETURN  TO PICK UP OR DROP CARD"
9050 Q$=Q$+"   - * TO QUIT":GOSUB5000
9052 D$=P$(1,5):IFD$="1"THEND$="10"
9055 Q=1:W=0:Q$="[156]BASE[157][157][157][157]CARD[157][157][157][157]IS "+D$:GOSUB5000
9060 IFQF=1THENGOTO30
9063 IFVAL(C$(1,0,0))<>13THEN9068
9064 IFVAL(C$(2,0,0))<>13THEN9068
9065 IFVAL(C$(3,0,0))<>13THEN9068
9066 IFVAL(C$(4,0,0))<>13THEN9068
9067 GOTO9300
9068 IFCH=1THENQ=12:W=0:Q$="PICK UP[157][157][157][157][157][157][157]CARD":GOSUB5000:GOSUB5150:SP=PI
9069 IFPI=99THENGOTO9060
9072 IFCH=-1THENQ=12:W=0:Q$="[129]DROP   [157][157][157][157][157][157][157]CARD":GOSUB5000:GOSUB5180:DP=PI
9073 IFPI=99THENGOTO9060
9075 IF(PI=1ORPI=2ORPI=3ORPI=4)ANDCH=1THEN9060
9080 IF(PI=1ORPI=2ORPI=3ORPI=4)ANDCH=-1THENGOSUB5400:CH=1:GOTO9060
9085 IFPI=5ANDCH=1ANDVAL(C$(SP,0,0))=0THEN9060
9090 IFPI=5ANDCH=1THENGOSUB5500:CH=-1:GOTO9060
9100 IFPI=5ANDCH=-1THENGOSUB150:CH=1:GOTO9060
9105 IF(PI=6ORPI=7ORPI=8ORPI=9)ANDCH=1ANDVAL(C$(SP,0,0))=0THEN9060
9110 IF(PI=6ORPI=7ORPI=8ORPI=9)ANDCH=1THENGOSUB5500:CH=-1:GOTO9060
9120 IF(PI=6ORPI=7ORPI=8ORPI=9)ANDCH=-1THENGOSUB5600:CH=1:GOTO9060
9125 IFPI=10ANDCH=1ANDVAL(C$(SP,0,0))=0THEN9060
9130 IFPI=10ANDCH=1THENGOSUB5500:CH=-1:GOTO9060
9140 IFPI=10ANDCH=-1THENGOSUB150:CH=1:GOTO9060
9150 IFPI=11ANDCH=1THENGOSUB5800:CH=1:GOTO9060
9160 IFPI=11ANDCH=-1THENGOSUB150:CH=1:GOTO9060
9170 GOTO9060
9298 :
9299 REM *** WIN GAME ***
9300 PRINTCHR$(147):FORX=1TO30:PRINT"[144]CONGRATULATIONS!!  YOU WON!!!";:NEXT
9310 Q=10:W=5:Q$="CONGRATULATIONS!!  YOU WON!!!":GOSUB5000
9320 Q=23:W=6:Q$="PRESS SPACE BAR TO CONTINUE.":GOSUB5000:GOSUB5300
9330 PRINTCHR$(147):PRINT"[144]DO YOU WANT TO PLAY AGAIN (Y/N)?[160]":GOSUB5300
9340 IFA$="N"THEN 9500
9350 IFA$="Y"THENFLAG=2:GOTO 9490
9360 GOTO9330
9398 :
9399 REM *** END GAME ***
9400 Q=22:W=0:Q$=SP$+SP$:GOSUB5000:Q=22:W=0
9410 Q$="[144]DO YOU WANT TO END THIS GAME (Y/N)?[160]":GOSUB5000:GOSUB5300
9420 IFA$="Y"THEN 9450
9430 IFA$="N"THEN9530
9440 GOTO9410
9450 SC=VAL(C$(1,0,0))+VAL(C$(2,0,0))+VAL(C$(3,0,0))+VAL(C$(4,0,0))
9460 PRINTCHR$(147):PRINT"THERE WERE "SC" CARDS IN THE BASE PILES."
9480 Q=11:W=0:Q$="DO YOU WANT TO PLAY AGAIN (Y/N)?[160]":GOSUB5000:GOSUB5300
9490 IFA$="Y"ANDFLAG=2THENRUN
9495 IFA$="Y"THENQF=1:PI=99:RETURN
9500 IFA$="N"THENQ=14:W=0:Q$="COME BACK AND PLAY AGAIN.":GOSUB5000:GOTO9520
9510 GOTO9480
9520 PRINT"[147]LOAD"CHR$(34)"HELLO"CHR$(34)",8":PRINT"RUN"
9525 POKE198,0:POKE631,13:POKE632,13:POKE198,2:END
9530 Q=22:W=0
9540 Q$="[144]MOVE ARROW WITH SPACE BAR - USE RETURN  TO PICK UP OR DROP CARD"
9550 Q$=Q$+"   - * TO QUIT":GOSUB5000:RETURN
19998 :
19999 REM *** SET UP DECK ***
20000 FORX=1TO13:X$=STR$(X):D$(X)=RIGHT$(X$,LEN(X$)-1):NEXT
20060 FORX=14TO26:X$=STR$(X-13):D$(X)=RIGHT$(X$,LEN(X$)-1):NEXT
20070 FORX=27TO39:X$=STR$(X-26):D$(X)=RIGHT$(X$,LEN(X$)-1):NEXT
20080 FORX=40TO52:X$=STR$(X-39):D$(X)=RIGHT$(X$,LEN(X$)-1):NEXT
20090 D$(11)="J":D$(24)="J":D$(37)="J":D$(50)="J"
20100 D$(12)="Q":D$(25)="Q":D$(38)="Q":D$(51)="Q"
20110 D$(13)="K":D$(26)="K":D$(39)="K":D$(52)="K"
20120 D$(1)="A":D$(14)="A":D$(27)="A":D$(40)="A"
20130 FORX=1TO13:D$(X)=""+D$(X)+"[211]":NEXT
20140 FORX=14TO26:D$(X)=""+D$(X)+"[218]":NEXT
20150 FORX=27TO39:D$(X)="[144]"+D$(X)+"[193]":NEXT
20160 FORX=40TO52:D$(X)="[144]"+D$(X)+"[216]":NEXT
20168 :
20169 REM *** INITIALIZE STRINGS ***
20170 SP$="                                       "
20180 RETURN
20198 :
20199 REM *** SHUFFLE DECK ***
20200 PRINTCHR$(147):Q=22:W=13:Q$="[144]SHUFFLING DECK":GOSUB5000:RD=0
20210 FORC9=1TO52:C%=(RND(Q9)*52)+1
20220 T$=D$(C9):D$(C9)=D$(C%):D$(C%)=T$
20230 Q=8:W=17:Q$=CA$:GOSUB5000:Q=Q+1:W=W+1:Q$=D$(C9):GOSUB5000:GOSUB300:NEXT
20240 Q=8:W=17:Q$=BA$:GOSUB5000:GOSUB300
20318 :
20319 REM *** SET UP CARD ARRAY ***
20320 FORX=1TO11:C$(X,0,0)="":NEXT:D2=0:QF=0
20325 C9=1:C$(1,1,0)=D$(C9):C9=C9+1:C$(1,0,0)="1"
20330 FORY=1TO7:C$(5,Y,0)=D$(C9):C9=C9+1:NEXT:C$(5,0,0)="7"
20340 FORY=1TO4:C$(Y+5,1,0)=D$(C9):C9=C9+1:NEXT:FORY=1TO4:C$(Y+5,0,0)="1":NEXT
20350 FORY=1TO40:C$(11,Y,0)=D$(C9):C9=C9+1:NEXT:C$(11,0,0)="40":C$(11,0,1)="-1"
20355 FORX=1TO4:P$(X,5)=MID$(C$(1,1,0),2,1):NEXT
20360 RETURN
40000 POKE53280,14:POKE53281,1:POKE53272,21:PRINTCHR$(144)
40002 DIMD$(52),P$(11,9),C$(11,40,1)
40005 PRINTCHR$(147)
40010 CA$="[144][176][195][195][195][174][157][157][157][157][157][194]   [194][157][157][157][157][157][194]   [194][157][157][157][157][157][194]   [194][157][157][157][157][157][173][195][195][195][189]"
40020 BA$="[166][166][166][157][157][157][157][157][166][166][166][157][157][157][157][157][166][166][166][157][157][157][157][157]"
40030 BL$="   [157][157][157][157][157]   [157][157][157][157][157]   [157][157][157][157][157][146]"
40040 ER$="     [157][157][157][157][157]     [157][157][157][157][157]     [157][157][157][157][157]     [157][157][157][157][157]     [146]"
40050 B1$="[166][166][157][157][157][157][166][166][157][157][157][157][166][166][157][157][157][157]"
40060 FORX=1TO8:Q=6:W=(3*X)+5:Q$=CA$:GOSUB5000
40070 Q$=BA$:GOSUB5000
40100 GOSUB300:NEXT
40110 C$="[159][153][156][150][158][155]":S$="SPECTRUM":FORX=1TO8:SP$=MID$(S$,X,1):CP$=MID$(C$,X,1)
40115 SP$=CP$+SP$
40120 FORX1=1TO5+(X*3):Q=23:W=X1:Q$="[156] "+SP$:GOSUB5000:NEXT
40130 FORX2=23TO12STEP-1:Q=X2:W=X1:Q$=" ":GOSUB5000:Q$="[156][145]"+SP$:GOSUB5000
40140 NEXT
40145 Q=Q-6:W=W-1:Q$=CP$+B1$:GOSUB5000
40147 POKEF+24,0:POKEF+24,15
40150 NEXT
40155 W=W+1:Q$=CP$+B1$:GOSUB5000
40160 PRINT"      A SOLITAIRE GAME FOR THE C-64"
40162 PRINT"                    BY"
40164 PRINT"              DONNA K. WOODY"
40168 :
40169 REM *** SET UP PILE ARRAY ***
40170 FORC1=1TO11:FORC2=0TO9:READP$(C1,C2):NEXT:NEXT
40172 DATA7,0,0,0,0,0,0,1,-,0,14,0,0,0,0,0,0,1,-,0,21,0,0,0,0,0,0,1,-,0
40174 DATA28,0,0,0,0,0,0,1,-,0,0,5,0,0,0,0,1,0,0,0,7,5,0,2,6,0,1,1,+,0
40176 DATA14,5,0,2,6,0,1,1,+,0,21,5,0,2,6,0,1,1,+,0,28,5,0,2,6,0,1,1,+,0
40178 DATA34,7,0,0,0,0,1,0,0,11,34,14,0,0,0,0,1,0,0,10
40180 Q=23:W=0:Q$="     DO YOU NEED INSTRUCTIONS (Y/N)?[160]":GOSUB5000:GOSUB5300
40190 IFA$="N"THEN40196
40192 IFA$<>"Y"THEN40180
40194 GOTO40220
40196 Q=23:W=0:Q$="[144]          .....PLEASE WAIT.....      ":GOSUB5000:RETURN
40218 :
40219 REM *** INSTRUCTIONS ***
40220 PRINTCHR$(147):PRINT"  S[159]P[156]ECT[158]R[150]U[155]M[129] IS A CARD GAME PLAYED WITH A":PRINT
40230 PRINT"STANDARD DECK OF 52 CARDS.":PRINT
40240 PRINT"  THE COMPUTER WILL SHUFFLE THE CARDS":PRINT
40250 PRINT"AND DEAL THEM INTO 6 PILES.  THE FIRST":PRINT
40260 PRINT"CARD IN THE TOP ROW IS THE BASE CARD.":PRINT
40270 PRINT"THIS CARD IS TO BE BUILT UP IN SUIT":PRINT
40280 PRINT"UNTIL THE PILE CONTAINS 13 CARDS.":PRINT
40290 PRINT"  THE FOUR CARDS DEALT IN THE ROW":PRINT
40300 PRINT"BELOW THE BASE CARD ARE THE BUILDING":PRINT
40310 PRINT"PILES.  THESE CAN BE BUILT IN":PRINT
40312 Q=23:W=6:Q$="PRESS SPACE BAR TO CONTINUE.":GOSUB5000:GOSUB5300:PRINTCHR$(147)
40320 PRINT"DESCENDING SEQUENCE AND ALTERNATING":PRINT
40330 PRINT"COLORS.  KINGS CAN BE BUILT ON ACES.":PRINT
40340 PRINT"  7 CARDS ARE DEALT IN A SINGLE PILE":PRINT
40350 PRINT"TO THE LEFT OF THE BUILDING PILES TO":PRINT
40360 PRINT"FORM THE STOCK.  CARDS FROM THE STOCK":PRINT
40370 PRINT"MAY BE BUILT ON BASE CARDS, BUILDING":PRINT
40380 PRINT"PILES OR USED TO FILL EMPTY SPACES IN":PRINT
40390 PRINT"THE BUILDING PILES ROW.":PRINT
40400 PRINT"  THE REMAINING CARDS ARE PLACED IN":PRINT
40410 PRINT"THE HAND AND MAY BE PLAYED TO THE WASTE":PRINT
40412 Q=23:W=6:Q$="PRESS SPACE BAR TO CONTINUE.":GOSUB5000:GOSUB5300:PRINTCHR$(147)
40420 PRINT"PILE ONE CARD AT A TIME.":PRINT
40430 PRINT"  CARDS FROM THE WASTE PILE MAY BE":PRINT
40440 PRINT"BUILT ON THE BUILDING PILES OR THE BASE":PRINT
40450 PRINT"PILES.":PRINT
40460 PRINT"  ONLY ONE CARD MAY BE MOVED FROM A":PRINT
40470 PRINT"PILE AT A TIME.":PRINT
40480 PRINT"  CARDS MAY NOT BE PLACED ON THE STOCK":PRINT
40490 PRINT"FROM ANY PILE.  THE WASTE PILE WILL":PRINT
40500 PRINT"ONLY ACCEPT CARDS FROM THE HAND.":PRINT
40510 PRINT"  YOU MAY GO THROUGH THE CARDS IN THE":PRINT
40512 Q=23:W=6:Q$="PRESS SPACE BAR TO CONTINUE.":GOSUB5000:GOSUB5300:PRINTCHR$(147)
40520 PRINT"HAND TWICE.":PRINT
40530 PRINT"  THE OBJECT OF THE GAME IS TO BUILD":PRINT
40540 PRINT"THE BASE CARDS UP IN SUIT UNTIL EACH":PRINT
40550 PRINT"PILE CONTAINS 13 CARDS.":PRINT
40560 PRINT"  YOU MAY END THE GAME AT ANY TIME BY":PRINT
40570 PRINT"PRESSING THE '*' KEY.  THE ARROW POINTS":PRINT
40580 PRINT"TO THE CARD YOU WANT TO MOVE.  USE THE":PRINT
40590 PRINT"SPACE BAR TO MOVE THE ARROW AND THE":PRINT
40600 PRINT"RETURN KEY TO PICK UP OR DROP A CARD."
40612 Q=22:W=6:Q$="PRESS SPACE BAR TO CONTINUE.":GOSUB5000:GOSUB5300
40620 Q=22:W=5:Q$=".......ONE MOMENT PLEASE.......    ":GOSUB5000
40630 RETURN