1 POKE53280,10:POKE53281,1:GOSUB135:DIMH$(4,10),C$(51),U(51),Q(51):POKE788,52
2 A=200:A$="A122334455667788990:J;Q<K=":S$(1)="[218]":S$(0)="[211]"
3 S$(2)="[144][216]":S$(3)="[144][193]":FORI=0TO3:FORJ=1TO26STEP2:C$(X)=MID$(A$,J,2)+S$(I)
4 X=X+1:NEXT:NEXT:GOSUB150
9 POKE53280,7:POKE53281,12:PRINT"[147]";SPC(13);"[144]ANTE IS $";A
10 PRINT"[159]          [197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197]"
12 PRINT"    FOUR OF A KIND         PAYS [214] 15"
13 PRINT"    FULL HOUSE             PAYS [214] 10"
14 PRINT"    FLUSH                  PAYS [214] 8":PRINT"    STRAIGHT      ";
15 PRINT"         PAYS [214] 6":PRINT"    THREE OF A KIND        PAYS [214] 4"
16 PRINT"    TWO PAIR               PAYS [214] 2":PRINT"    PAIR (TENS OR BETT";
17 PRINT"ER)  PAYS [214] 1.5":PRINT"[159]          [210][210][210][210][210][210][210][210][210][210][210][210][210][210][210][210][210][210][210][210][144]"
18 PRINTSPC(15);"SHUFFLING":FORJ=1TON:B(J)=A:NEXT
19 FORJ=0TO51:U(J)=0:NEXT:FORJ=0TO2500:NEXT:FORI=1TO4:FORJ=1TO10
20 X=RND(0)*51:IFU(X)=1THEN20
22 H$(I,J)=C$(X):U(X)=1:NEXT:NEXT:GETX$:IFX$=""THEN26
23 PRINT"[145]       DEPRESS C[146]ONTINUE  OR  E[146]ND"
24 GETX$:IFX$<>""ANDX$<>"C"ANDX$<>"E"THEN24
25 IFX$=""ORX$="E"THEN125
26 FORJ=1TON:M(J)=M(J)-A:NEXT:PRINT"[147]":GOSUB500:GOSUB550:FORI=1TO5
27 PRINT"";SPC(I*5);:FORH=1TON:GOSUB475:FORK=1TO400:NEXT
28 PRINT"[157][157][157][157]";:NEXT:NEXT:GOSUB200
33 GOSUB300:FORH=1TON:PRINT"";:
35 FORJ=1TOH:PRINT"";:NEXT:PRINT"[145][145]";SPC(12);
37 FORI=1TO5:GOSUB475:PRINT"[145][145][145][145]";:NEXT
38 PRINT"":PRINT"[152]";
48 FORJ=1TO14:Q(J)=Z:NEXT
52 FORJ=1TO5:P(J)=ASC(MID$(H$(H,J),2,1))-48:Q(P(J))=Q(P(J))+1:NEXT
54 B=Z:C=Z:D=Z:FORJ=1TO13:IFQ(J)=2THEND=D+1
58 IFQ(J)=3THENB=1
60 IFQ(J)=4THENC=1
62 NEXT:IFC=1THENPRINT"4 OF A KIND":M(H)=M(H)+B(H)*15:GOTO108
64 IFB=1ANDD=1THENPRINT" FULL HOUSE":M(H)=M(H)+B(H)*10:GOTO108
66 IFB=1THENPRINT"3 OF A KIND":M(H)=M(H)+B(H)*4:GOTO108
68 IFD>1THENPRINT"  2  PAIR  ":M(H)=M(H)+B(H)*2:GOTO108
70 IFD=ZTHEN77
72 PRINT"  1  PAIR  [157][157][157][157][157][157][157][157][157][157][157]";:X=Z:FORJ=2TO9:IFQ(J)=2THENX=1
74 NEXT:IFX=ZTHENM(H)=M(H)+B(H)*1.5:PRINT:GOTO108
76 FORJ=0TO1200:NEXT:PRINT" BET TAKEN ":GOTO108
77 Y=Z
78 S=Z:LO=14:HI=Z:FORJ=1TO5:IFP(J)>HITHENHI=P(J)
84 IFLO>=P(J)THENLO=P(J):IFP(J)=1ANDY=0THENY=J
86 NEXT:IFLO=1ANDHI=13THENP(Y)=14:GOTO78
94 IFLO+4=HITHENS=1
96 X=0:FORJ=2TO5:IFMID$(H$(H,1),4,1)=MID$(H$(H,J),4,1)THENX=X+1
98 NEXT:IFS=0ANDX<4THENPRINT" BET TAKEN ":GOTO108
100 IFS=1ANDX<4THENPRINT" STRAIGHT  ":M(H)=M(H)+B(H)*6:GOTO108
102 IFS=0ANDX=4THENPRINT"  FLUSH    ":M(H)=M(H)+B(H)*8:GOTO108
104 IFLO=10THENPRINT"ROYAL FLUSH":M(H)=M(H)+B(H)*25:GOTO108
106 PRINT"STRAIGHT FL":M(H)=M(H)+B(H)*20
108 M(H)=INT(M(H)):PRINT"[145][145] $";M(H):FORJ=1TO1500:NEXT
109 NEXT:GOSUB555
110 B=0:FORJ=1TON:B=B+M(J):NEXT:A=INT((B/N)/5):IFA<1THEN125
112 X=.:FORI=1TON:IFM(I)<AANDX=0THENX=I
114 NEXT:IFX=0THEN9
116 Y=1:FORJ=1TON:IFJ<>XTHENE$(Y)=P$(J):F(Y)=M(J):Y=Y+1:GOTO120
118 PRINT"[147]";P$(J);" YOU'RE OUT":FORK=1TO2500:NEXT
120 NEXT:N=N-1:FORJ=1TON:P$(J)=E$(J):M(J)=F(J):NEXT:IFN>0THEN112
125 POKE53280,4:POKE53281,4:PRINT"[147]";SPC(14);"GAME OVER[144]"
127 FORJ=1TON:PRINTP$(J);" COLLECTS";M(J);"":NEXT
130 POKE788,49:FORDL=1TO3000:NEXTDL:GOTO63000
135 PRINT"[147]                                       ";
137 FORJ=0TO22:PRINT"  ";:NEXT
139 PRINT"                                        [157][148] "
140 PRINT"";SPC(17);"[144]POKER"
144 PRINTSPC(12);"BY DJB SHIBLEY":PRINT"[158]";
145 PRINT"[197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197][197]":RETURN
150 PRINT"[155]DEPRESS THE NUMBER OF PLAYERS (1-4)"
155 GETX$:IFVAL(X$)<1ORVAL(X$)>4THEN155
160 N=VAL(X$):PRINT"[147]":IFN=1THENM(1)=1000:P$(1)="PLAYER 1 ":RETURN
165 POKE53280,4:POKE53281,6:FORJ=1TON:M(J)=1000:P$(J)="PLAYER"+STR$(J)
170 PRINT"[159]";P$(J);" RETURN YOUR NAME ";:INPUTP$(J):P$(J)=LEFT$(P$(J),9)
175 IFLEN(P$(J))<9THENP$(J)=P$(J)+" ":GOTO175
176 PRINT"":NEXT:RETURN
200 PRINT"[144]RAISE YOUR BET ?   (TIMES 2, 3, OR NO)"
205 FORH=1TON:PRINT"";:FORJ=1TOH:PRINT"";:NEXT:PRINT"[145]";
210 PRINT"          [145]":FORJ=1TO20:GETX$
212 IFX$="2"ORX$="3"ORX$="N"THENJ=20
215 NEXT:PRINT" ";P$(H);"[145]":IFX$="2"ORX$="3"ORX$="N"THEN222
218 FORJ=1TO45:GETX$:IFX$="2"ORX$="3"ORX$="N"THENJ=45
220 NEXT:IFX$<>"2"ANDX$<>"3"ANDX$<>"N"THEN210
222 IFX$="N"THEN225
223 M(H)=M(H)-A*(VAL(X$)-1):B(H)=B(H)+A*(VAL(X$)-1):PRINT"":GOSUB505
225 NEXT:RETURN
300 FORH=1TON:PRINT"[144]   ";P$(H);" PRESS [D]RAW  OR  [H]OLD  ":PRINT"";
305 FORJ=1TOH:PRINT"";:NEXT:PRINT"";
310 FORI=1TO5:D(I)=0:PRINTSPC(9+(I*5));"[144]^[157]";
315 GETX$:IFX$<>"_"ANDX$<>"[157]"ANDX$<>"H"ANDX$<>"D"ANDX$<>CHR$(20)THEN315
320 IFI=1AND(X$="_"ORX$="[157]"ORX$=CHR$(20))THEN315
325 IFX$="_"ORX$="[157]"ORX$=CHR$(20)THENI=I-2:GOTO330
327 IFX$="D"THEND(I)=1:PRINT"[144][214]";
330 PRINT"[183][145]":NEXT
335 FORJ=1TO5:IFD(J)=1THENH$(H,J)=H$(H,J+5)
336 NEXT:FORJ=0TO9:GETX$:NEXT:NEXT
338 PRINT"[144]                                      ":RETURN
475 PRINT"";:X$=H$(H,I):PRINT"[175][175][175][157][157][157][157][170]   [180][157][157][157][157][157][170] ";LEFT$(X$,1);
477 IFASC(X$)=48THENPRINT"[157][157]1";
480 PRINT" [180][157][157][157][157][157][170] ";RIGHT$(X$,3);" [180][157][157][157][157][183][183][183]";
485 RETURN
500 POKE53281,15:POKE53280,0:PRINT"[144]                                        ";
501 PRINT"[156]                                        [145]"
502 FORJ=1TO22:PRINTSPC(38);" [146][157][148] ":NEXT
505 PRINT"[156]           "
510 FORJ=1TON:PRINT"[156]           ":PRINT" ";P$(J);" ":PRINT" $";
514 PRINTM(J);"[157]";
515 IFLEN(STR$(M(J)))<9THENFORK=1TO9-LEN(STR$(M(J))):PRINT" ";:NEXT
525 PRINT:PRINT"[152] BET=";B(J);"[157]";
530 IFLEN(STR$(B(J)))<6THENFORK=1TO6-LEN(STR$(B(J))):PRINT" ";:NEXT
540 PRINT:PRINT"[156]           "
545 NEXT:PRINT"[156]           ":IFN<4THENFORJ=1TO(4-N)*5:PRINT"           ":NEXT
546 RETURN
550 PRINT"[156]                                       [157][148] ":FORJ=0TO500:NEXT:RETURN
555 PRINT"[144]PRESS ANY KEY TO CONTINUE (Q TO QUIT)"
556 FORJ=1TO90:GETX$:IFX$<>""THENJ=90
558 NEXT:IFX$<>""THEN565
560 PRINT"[144]                                     "
562 FORJ=1TO40:GETX$:IFX$<>""THENJ=40
564 NEXT:IFX$=""THEN555
565 IFX$="Q"THEN125
566 RETURN
63000 REM    CONNECT BACK TO L.S.
63002 PRINT"[147]LOAD"CHR$(34)"PAYLOAD"CHR$(34)",8":PRINT"RUN"
63004 POKE198,0:POKE631,13:POKE632,13:POKE198,2:END