In this tutorial, you will learn how to use the Virtual Events data mode to display an array of variants. This tutorial covers reading, updating, adding and deleting records in the Virtual Events mode. 

1. Read Data

• From the Visual Basic« File menu, choose New Project.
• Press Ctrl+T or select Components from Project menu. Check the Stinga BeeGrid Control 1.0 (OLEDB) checkbox.
• Place a BeeGrid control on the form.
• Set the DataMode property to 2 - sgVirtualEvents.
• Insert the following declarations into the Declaration section of Form1:
  
   Copy Code

  
  'variable to hold the data to be displayed in the grid
  Private arData As Variant
  'current rows count
  Private mlRowsCount As Long
  'max row count
  Private Const MAX_ROWS = 100
  

• Initialize data array into the Form_Load event:
  
   Copy Code

  
  Private Sub Form_Load()
     mlRowsCount = 4
     ReDim arData(SGGrid1.DataColCount - 1, mlRowsCount)
  
     SGGrid1.DataRowCount = mlRowsCount
  End Sub
  

• Right-click on the SGGrid1 and select Properties... to display the Property Pages dialog. Select the Columns Tab and create the following columns: "Band", "Album", "Song", "Time".
• Insert the following code into the VirtualReadData event:
  
   Copy Code

  
  Private Sub SGGrid1_VirtualReadData(ByVal RowBuffer As IsgRowBuffer)
     Dim i As Integer
        
     For i = 0 To RowBuffer.ColumnCount - 1
        RowBuffer.Value(i) = arData(i, RowBuffer.RowIndex)
     Next
  
     If RowBuffer.RowIndex = mlRowsCount Then
        RowBuffer.RowIndex = -1
     End If
  End Sub
  	

2. Write Data

• Set the AllowEdit property to True.
• Insert the following code into the VirtualWriteData event:
  
   Copy Code

  
  Private Sub SGGrid1_VirtualWriteData _
     (ByVal RowBuffer As IsgRowBuffer, Cancel As Boolean)
     Dim i As Integer
  
     For i = 0 To RowBuffer.ColumnCount - 1
        arData(i, RowBuffer.RowIndex) = RowBuffer.Value(i)
     Next
  End Sub
  	

3. Add New Row

• Set the AllowAddNew property to True.
• Insert the following code into the VirtualAddRow event:
  
   Copy Code

  
  Private Sub SGGrid1_VirtualAddRow _
     (ByVal RowBuffer As IsgRowBuffer, Cancel As Boolean)
     Dim i As Integer
  
     If MAX_ROWS = mlRowsCount Then
        Cancel = True
        Exit Sub
     End If
  
     mlRowsCount = mlRowsCount + 1
  
     If mlRowsCount > UBound(arData, 2) Then
        ReDim Preserve arData(RowBuffer.ColumnCount - 1, mlRowsCount + 10)
     End If
  
     For i = 0 To RowBuffer.ColumnCount - 1
        arData(i, mlRowsCount - 1) = RowBuffer.Value(i)
     Next
  End Sub
  	

3. Delete Row

• Set the AllowDelete property to True.
• Insert the following code into the VirtualDeleteRow event:
  
   Copy Code

  
  Private Sub SGGrid1_VirtualDeleteRow _
     (ByVal RowIndex As Long, ByVal RowBookmark As Variant, _
     Cancel As Boolean)
     Dim i As Integer, j As Integer
  
     mlRowsCount = mlRowsCount - 1
  
     For i = RowIndex To mlRowsCount
        For j = 0 To UBound(arData, 1)
           arData(j, i) = arData(j, i + 1)
        Next
     Next
  End Sub
  	

4. Group and Sort Data

Grouping and sorting is the same as in all other modes.

• Set the CacheAllRecords property to True. This is required by the ColumnClickSort property.
• Set the ColumnClickSort property to True.
• Add group to the Groups collection. You can do it from the code:
  SGGrid1.Groups.Add "Band", sgSortAscending, sgSortTypeString, False, True