In this tutorial, you will learn how to use the unbound mode of the BeeGrid control.

1. Create Columns

• From the Visual Basic« File menu, choose New Project.
• Press Ctrl+T or select Components from Project menu. Check the Stinga BeeGrid Control 1.0 (OLEDB) checkbox.
• Place a BeeGrid control on the form.
• By default, the DataMode property is set  to 1 - sgUnbound.
• Set the AllowAddNew property  to True.
• Right-click on the SGGrid1 and select Properties... to display the Property Pages dialog. Select the Columns Tab and create the following columns: Rank, Trend, Name, Country, Points, Tours and Next Off. See picture.
  
  
  
  
  The following block creates columns from the code:
  
   Copy Code

  
  Private Sub CreateColumns()
     Dim i As Integer, arKeys As Variant
     
     With SGGrid1
        .Columns.RemoveAll False
        .DataRowCount = 0
        .HeadingColCount = 1         
        
        With .Columns.Add("Rank")
           .DBField = "Rank"
           .Width = 850
           .SortType = sgSortTypeNumber
           .DataType = sgtLong
           .Style.TextAlignment = sgAlignRightCenter
        End With
        
        With .Columns.Add("Trend")
           .DBField = "Trend"
           .Caption = ""
           .HeadingPicture = sgbipFirst + 6
           .HeadingStyle.DisplayType = sgDisplayPicture
        End With
        
        With .Columns.Add("Name")
           .DBField = "Name"
           .Caption = "Name"
           .Width = 2850
        End With
        
        With .Columns.Add("Country")
           .DBField = "Country"
           .Caption = "Country"
           .Width = 1850
        End With
        
        arKeys = Array("Points", "Tournament", "Next Off")
        For i = 5 To 7
           With .Columns.Add(arKeys(i - 5))
              .DBField = .Key: .Caption = .Key
              .Width = 900
              .DataType = sgtLong
              .SortType = sgSortTypeNumber
              .Style.TextAlignment = sgAlignRightCenter
           End With
        Next
     End With
  End Sub
  	

2. Enable Editing

• Set the AllowAddNew property to True.
• Set the AllowDelete property to True.
• Set the EnterKeyBehavior property to sgEnterKeyColumns to speed up keyboard navigation.
• Set the TabKeyBehavior property to True if you prefer using the Tab key for the grid's column navigation rather to the control navigation.

  These properties can also be set using the following code:

  
   Copy Code

  
  With SGGrid1
     .AllowAddNew = True
     .AllowDelete = True
     'keyboard navigation
     .EnterKeyBehavior = sgEnterKeyColumns
     .TabKeyBehavior = sgTabColumns 
  End With
  	

3. Load and Save Data

• Load data with the following line:
  SGGrid1.ImportData App.Path & "\Tennis.txt", sgFormatCharSeparatedValue, , vbCr.
• Save data with the following line:
  SGGrid1.ExportData App.Path & "\Tennis.txt", sgFormatCharSeparatedValue, sgExportOverwrite, , vbCr

4. Value Items

• You can add value items by using the Property Pages dialog or from code.
  The following code adds value items:
  
   Copy Code

  	
  WithSGGrid1.Columns("Trend")
     .Width = 305
     'change columns style
     .Style.DisplayType = sgDisplayPicture
     .Style.PictureAlignment = sgPicAlignCenterCenter
     'set columns control properties
     .Control.PopUpStyle.DisplayType = sgDisplayTextAndPicture
     .Control.Type = sgCellDropList
     .Control.ShowButton = sgHideButton
     .Control.Width = 1600
     .Control.PopupAlignment = sgPopupLeft
     'add value items. Use built-in pictures
     .ValueItems.Add 0, "Unchanged", sgbipFirst
     .ValueItems.Add 1, "Up", sgbipFirst + 3
     .ValueItems.Add 2, "Down", sgbipFirst + 2
     .ValueItems.Add 3, "New", sgbipFirst + 5
     .ValueItems.Translate = True
  End With
  	

5. Group by the "Country" Column 

• Add group to the Groups collection. Do it by using the property pages or from the code:
  SGGrid1.Groups.Add "Country", sgSortAscending, sgSortTypeString, False, True
• Hide the CategoryName column with property pages or from the code:
  SGGrid1.Columns("Country").Hidden = True
• Enable sorting by setting the ColumnClickSort property to True.
  The following code groups data by the "Country" column and enables sorting:
  
   Copy Code

  
  With SGGrid1
     .Groups.Add "Country", sgSortAscending, sgSortTypeString, False, True
     .Columns("Country").Hidden = True
     .ColumnClickSort = True
  End With
  	

6. Change Styles

• Heading - change heading by changing the HeadingBackColor, HeadingForeColor and HeadingFont properties.
• Even-Odd Style - set the EvenOddStyle to sgEvenOddRows. Change default even/odd colors by setting the ColorEven and ColorOdd properties.
• Enable row heading numbers by setting the RowNumbering property to True.
• Fill in the empty space between cells and the grid's right border by setting the FitLastColumn to True.
• Set the GridLines property to sgGridLineNone to hide grid lines.
• Modify the "GroupHeader" style.
  To change the styles, use the following code:
  
   Copy Code

  
  With SGGrid1
     'set heading style
     .HeadingBackColor = RGB(8, 105, 148)
     .HeadingForeColor = vbWhite
     .HeadingFont.Bold = True
     'even-odd stuff
     .ColorEven = vbWhite
     .ColorOdd = RGB(239, 239, 239)
     .EvenOddStyle = sgEvenOddRows
     'misc
     .FitLastColumn = True
     .RowNumbering = True
     .GridLines = sgGridLineNone	
     .Styles("GroupHeader").BackColor = &HDDFFFF
  End With