10 IFPEEK(2)<>222THENPRINT"[147]   BITTE ERST BOOT-PROGRAMM LADEN...":NEW
20 IFAS<>0THEN90
30 CLR:POKE53280,0:POKE53281,0:PRINT"[147][158]           TYGUS HORX EDITOR"
40 PRINT"       (W) BY TOBIAS HOFMANN IN 1991"
50 PRINT"       (C) BY 64'ER IN 1991"
60 INPUT"CHARAKTER-NAME ";N$
70 NA$="_"+N$+"*":NB$=N$
80 AS=1:LOADNA$,8,1
90 PRINT"[147]ST----------->";:INPUTIN$:SR=VAL(IN$)
100 IFSR>255THENSR=255
110 PRINT:PRINT"IQ----------->";:INPUTIN$:IQ=VAL(IN$)
120 IFIQ>255THENIQ=255
130 PRINT:PRINT"DX----------->";:INPUTIN$:DX=VAL(IN$)
140 IFDX>255THENDX=255
150 PRINT:PRINT"CN----------->";:INPUTIN$:CN=VAL(IN$)
160 IFCN>255THENCN=255
170 PRINT:PRINT"LK----------->";:INPUTIN$:LK=VAL(IN$)
180 IFLK>255THENLK=255
190 PRINT:PRINT"HITS--------->";:INPUTHI$:IFLEN(HI$)>4THENHI$=RIGHT$(HI$,4)
200 PRINT:PRINT"COND--------->";:INPUTCO$:IFLEN(CO$)>4THENCO$=RIGHT$(CO$,4)
210 PRINT:PRINT"SPPT--------->";:INPUTSP$:IFLEN(SP$)>4THENSP$=RIGHT$(SP$,4)
220 PRINT:PRINT"MSPP--------->";:INPUTMS$:IFLEN(MS$)>4THENMS$=RIGHT$(MS$,4)
230 PRINT:PRINT"EXPERIENCE--->";:INPUTEX$:IFLEN(EX$)>10THENEX$=RIGHT$(EX$,10)
240 PRINT:PRINT"GOLDPIECES--->";:INPUTGL$:IFLEN(GL$)>10THENGL$=RIGHT$(GL$,10)
250 PRINT:PRINT"LEVEL-------->";:INPUTLE$:IFLEN(LE$)>3THENLE$=RIGHT$(LE$,3)
260 PRINT"[147]RACE (+,- FOR CHOOSE, RETURN TO GO ON):"
270 RA=PEEK(4698):DIMRA$(6)
280 FORI=0TO6:READRA$(I):NEXT
290 DATA"HUMAN","ELF","DWARF","HOBBIT","HALF-ELF","HALF-ORC","GNOME"
300 ZE=1:SP=0:GOSUB980:PRINT"        [157][157][157][157][157][157][157][157]"RA$(RA)
310 GETA$:IFA$=""THEN310
320 IFA$="+"THENRA=RA+1+7*(RA=6):GOTO300
330 IFA$="-"THENRA=RA-1-7*(RA=0):GOTO300
340 IFA$<>CHR$(13)THEN310
350 PRINT"[147]CLASS (+,- FOR CHOOSE, RETURN TO GO ON)"
360 CL=PEEK(4699):DIMCL$(4)
370 FORI=0TO4:READCL$(I):NEXT
380 DATA"WARRIOR","CONJUROR","MAGICIAN","ROGUE","PALADIN"
390 GOSUB980:PRINT"        [157][157][157][157][157][157][157][157]"CL$(CL)
400 GETA$:IFA$=""THEN400
410 IFA$="+"THENCL=CL+1+5*(CL=4):GOTO390
420 IFA$="-"THENCL=CL-1-5*(CL=0):GOTO390
430 IFA$<>CHR$(13)THEN400
440 PRINT"[147]CONJUROR SPELL LEVEL:"
450 GETCN$:IFCN$<"0"ORCN$>"6"THEN450
460 PRINT"[147]MAGICIAN SPELL LEVEL:"
470 GETMA$:IFMA$<"0"ORMA$>"6"THEN470
480 PRINT"[147]WIZARD   SPELL LEVEL:"
490 GETWI$:IFWI$<"0"ORWI$>"6"THEN490
500 DIMEQ$(63):FORI=0TO63:READEQ$(I):NEXT
510 DATA"--","TORCH","DAGGER","AXE","MACE","STAFF","SHORTSWORD"
520 DATA"LEATHER GLOVES"
530 DATA"LEATHER ARMOUR","HELM","IRON GLOVES","IRON HELM","IRON ARMOUR"
540 DATA"IRON SHIELD","IRON SCALE","IRON PLATE","IRON SWORD","IRON DAGGER"
550 DATA"IRON AXE","IRON MACE","BRONZE GLOVES","BRONZE HELM","BRONZE ARMOUR"
560 DATA"BRONZE SHIELD","BRONZE SCALE","BRONZE PLATE","BRONZE SWORD"
570 DATA"BRONZE DAGGER","BRONZE AXE","BRONZE MACE","SILVER GLOVES"
580 DATA"SILVER HELM"
590 DATA"SILVER ARMOUR","SILVER SHIELD","SILVER SCALE","SILVER PLATE"
600 DATA"SILVER SWORD","SILVER DAGGER","SILVER AXE","SILVER MACE","GOLD GLOVES"
610 DATA"GOLD HELM","GOLD ARMOUR","GOLD SHIELD","GOLD SCALE","GOLD PLATE"
620 DATA"GOLD SWORD","GOLD DAGGER","GOLD AXE","GOLD MACE","SHIELDRING"
630 DATA"SWORD OF KRII","MAGEHELM","HAMMER OF OX","MALU'S AXE","MAGESHIELD"
640 DATA"LANCE OF UFEM","MAGEGLOVES","SMALL KEY","RED KEY","GREEN KEY"
650 DATA"BLUE KEY"
660 DATA"YELLOW KEY","RAINBOW STAR"
670 PRINT"[147]EQUIPMENT (+/-:CHOOSE, RETURN:GO ON)":DIMEQ(7)
680 FORI=0TO7
690 EQ(I)=PEEK(4728+I)
700 ZE=I+1:SP=0:GOSUB980:POKE780,I+1:SYS59903:PRINTEQ$(EQ(I))
710 GETA$:IFA$=""THEN710
720 IFA$="+"THENEQ(I)=EQ(I)+1+64*(EQ(I)=63):GOTO700
730 IFA$="-"THENEQ(I)=EQ(I)-1-64*(EQ(I)=0):GOTO700
740 IFA$=CHR$(13)THEN760
750 GOTO710
760 NEXT
770 POKE4703,SR:POKE4704,IQ:POKE4705,DX:POKE4706,CN:POKE4707,LK:POKE4698,RA
780 POKE4699,CL
790 A$=HI$:A=4:GOSUB960:FORI=0TO3:POKE4682+I,VAL(MID$(A$,I+1,1))+176:NEXT
800 A$=CO$:A=4:GOSUB960:FORI=0TO3:POKE4686+I,VAL(MID$(A$,I+1,1))+176:NEXT
810 A$=SP$:A=4:GOSUB960:FORI=0TO3:POKE4690+I,VAL(MID$(A$,I+1,1))+176:NEXT
820 A$=MS$:A=4:GOSUB960:FORI=0TO3:POKE4694+I,VAL(MID$(A$,I+1,1))+176:NEXT
830 A$=LE$:A=3:GOSUB960:FORI=0TO2:POKE4700+I,VAL(MID$(A$,I+1,1))+176:NEXT
840 A$=EX$:A=10:GOSUB960:FORI=0TO9:POKE4708+I,VAL(MID$(A$,I+1,1))+176:NEXT
850 A$=GL$:A=10:GOSUB960:FORI=0TO9:POKE4718+I,VAL(MID$(A$,I+1,1))+176:NEXT
860 POKE4745,VAL(CN$):POKE4746,VAL(MA$):POKE4747,VAL(WI$)
870 FORI=0TO7:POKE4728+I,EQ(I):NEXT
880 FORI=1TO10-LEN(NB$):NB$=NB$+" ":NEXT
890 OPEN1,8,15,"S:"+NB$:CLOSE1
900 SYS(57812)"_"+NB$,8
910 POKE174,160:POKE175,18:POKE193,64:POKE194,18:SYS62957
920 PRINT"[147]NOCH EIN CHARAKTER ???(J/N)"
930 GETA$:IFA$=""THEN930
940 IFA$="N"THENSYS64738
950 GOTO30
960 IFLEN(A$)=ATHENRETURN
970 A$=RIGHT$("0000000000"+MID$(A$,1),A):RETURN
980 POKE211,SP:POKE214,ZE:SYS58640:RETURN