1 A=A+1:IFA=1THENPOKE53265,11:LOAD"DO.PIC",8,1
2 IFA=2THENLOAD"BIT.C.L",8,1
3 IFA=3THENSYS1430:LOAD"DO.CHAR",8,1
4 FORW=1TO3000:NEXT:SYS1024:POKE53265,11
5 POKE53280,11:POKE56576,148:POKE53272,2:POKE53270,200:POKE648,192
6 PRINT"[147]":POKE52487,255:POKE53281,0:GOSUB443
7 GOSUB58:PRINT"[147]"X$(1);"[194][159]          DOSH INDEXES MENU           [193]";X$(2);
8 PRINT"[153][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209]"
9 FORBD=1TO11:PRINT"[209]                            [209]":NEXT
10 PRINT"[209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209]"
11 PRINTTB$"[146][158]@[154]SHADOW GRAPHICS 1992"
12 PRINT"[159] 1.  FILE FROM DISK"
13 PRINT"[159] 2.  INDEX UPDATE"
14 PRINT"[159] 3.  SCRATCH OLD FILE"
15 PRINT,"[176][175][175][175][175][175][175][175][175][175][175][175][175][175][174]":PRINT,"^[153]SELECT NUMBER_"
16 PRINT,"[173][172][172][172][172][172][172][172][172][172][172][172][172][172][189]":POKE53265,27:POKE53280,5
17 GETO$:IFO$=""THEN17
18 O=VAL(O$):IFO=1THENME$="[156] FILE FROM DISK [146]":GOTO22
19 IFO=2THENME$="[154]  INDEX UPDATE  [146]":GOTO22
20 IFO=3THENME$="[150]  SCRATCH FILE  [146]":GOTO22
21 IFO$<>""THEN17
22 PRINT"[147][155]"X$(1);"[194] [153] F1=FILE :[158] F3=MENU :";ME$;"[155] [193]";X$(2)
23 FORX=1TO15:PRINTTAB(0)"[155]"LC$TAB(20)LC$"[146][145]"
24 PRINTTAB(0)LK$TAB(20)LK$"[146][145]":FORW=1TO20:NEXT
25 PRINT"[158]"MID$(STR$(X),2)"[153]"TAB(3)G$(X)TAB(19)"[158]"X+15"[153]"G$(X+15):NEXTX
26 PRINTTB$"[145][155][176][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][174]":PRINTTB$"^               _"
27 PRINTTB$"[173][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][189]":PRINTTB$"[154] SELECT OPTION [146]";
28 GETA$:IFA$=""THENGOSUB439
29 IFA$>""THEN31
30 PRINTTB$"[159] SELECT OPTION [146]";:GOSUB439:GOTO26
31 IFA$<CHR$(133)ORA$>CHR$(134)THEN26
32 IFA$=CHR$(134)THENPRINTTB$,,"[150]EXIT TO MENU":GOTO7
33 IFA$=CHR$(133)THENGOSUB442:PRINTTB$:INPUT"[145][159]   FILE NUMBER   [146]";A
34 IFA<1ORA>30THEN33
35 IFG$(A)=SI$ANDO=1THENPRINTTB$,,"[150]EMPTY FILE":GOSUB434:GOTO22
36 IFG$(A)=SI$ANDO=3THENPRINTTB$,,"[150]EMPTY FILE":GOSUB434:GOTO22
37 IFO=3ANDG$(A)<>=SI$THENPRINTTB$,,"[150]O.K":GOSUB434:GOTO39
38 IFO=2ANDG$(A)<>SI$THENPRINTTB$,,"[150]FILE EXISTS":GOSUB434:GOTO22
39 IFO=1THENNR=0:GOTO59
40 IFO=2THENBZ=0:NR=0:IU=1:GOTO85
41 IFO=3THEN43
42 IFO<1ORO>3THEN27
43 GOSUB439:PRINTTB$" SCRATCHING FILE [146]      ";:OPEN2,8,15
44 PRINT#2,"S:";G$(A):CLOSE2:G$(A)=SI$:GOSUB432:GOTO51
45 PRINTTA$"[150]INDEX FILE UPDATE NUMBER";A
46 PRINTTA$" MAX 16 CHARACTERS [146][159]"
47 PRINTTA$"[176][178][178][178][178][178][178][178][178][178][178][178][178][178][178][174]"
48 INPUT"";G$(A)
49 L=LEN(G$(A)):IFL>16THENPRINT"[145]                       ":GOTO47
50 IFG$(A)=SI$THEN47
51 PRINTTB$"[145][150][176][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][174]     "
52 PRINTTB$"^[155] WRITING INDEX [150]_     ":PRINTTB$"[173][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][189]     ":IU=0
53 FORJ=1TO30:IFG$(J)=""THENG$(J)=SI$
54 NEXT
55 OPEN2,8,2,"@0:"+E$(3)+",S,W":FORJ=1TO30:PRINT#2,G$(J):NEXT:CLOSE2
56 IFO=3THEN7
57 IFO=2THEN85
58 OPEN2,8,2,E$(3)+",S,R":FORJ=1TO30:INPUT#2,G$(J):NEXT:CLOSE2:RETURN
59 OPEN2,8,2,G$(A)+",S,R"
60 INPUT#2,BZ:INPUT#2,N:INPUT#2,BA:INPUT#2,NR
61 IFNR=0THEN63
62 FORI=1TONR:INPUT#2,CK$(I):INPUT#2,DT$(I):INPUT#2,A$(I):INPUT#2,BA$(I):NEXT
63 INPUT#2,SN:INPUT#2,SE:INPUT#2,TL$:INPUT#2,LE$:CLOSE2:GOTO85
64 OPEN2,8,2,"@0:"+G$(A)+",S,W"
65 PRINT#2,BZ;R$;:PRINT#2,N;R$;:PRINT#2,BA;R$;:PRINT#2,NR;R$;:IFNR=0THEN68
66 FORI=1TONR:PRINT#2,CK$(I)R$;:PRINT#2,DT$(I)R$;:PRINT#2,A$(I)R$;
67 PRINT#2,BA$(I)R$;:NEXT
68 PRINT#2,SN;R$;:PRINT#2,SE;R$:PRINT#2,TL$;R$;:PRINT#2,LE$;R$;
69 CLOSE2:GOTO85
70 PRINT""
71 PRINT"[155]"X$(1);"[194][150] SET UP NEW BALANCE                   [146][155][193]";:PRINTX$(2)
72 PRINT" FILE NAME :-";G$(A)
73 PRINT" ENTER START BALANCE AMOUNT \";:GOSUB392:LE$=CHR$(160)
74 BZ=VAL(B$):TL$=B$:PRINT
75 IFB$=""THEN84
76 IFBZ=0THENA$="[145]":GOTO81
77 PRINT" CREDIT OR DEBIT (C/D)? ";
78 GETA$:IFA$="C"THEN81
79 IFA$<>"D"THEN78
80 BZ=-BZ
81 PRINTA$:PRINT"[155] IS THIS OK? ";
82 GETA$:IFA$="Y"THENBA=BZ:GOSUB440:GOTO64
83 IFA$<>"N"THEN82
84 GOSUB440:GOTO70
85 PRINT"[147][155]"X$(1);"[194][153]          DOSH OPTIONS MENU           [155][193]";X$(2)"[146]";
86 A$="ENTER":IFZQ=1THENA$="INSERT"
87 PRINT"[153] 1 [146] [158]"A$" PAY INS":PRINT"[153] 2 [146] [158]"A$" PAY OUTS"
88 IFNR<1ORZQ=1THENPRINT"[155] * [146] CHECK STATEMENT":GOTO90
89 IFNR>0THENPRINT"[153] 3 [146] [158]CHECK STATEMENT"
90 IFNR<1ORZQ=1THENPRINT"[155] * [146] EDIT PAY INS/OUTS & BALANCE":GOTO92
91 IFNR>0THENPRINT"[153] 4 [146] [158]EDIT PAY INS/OUTS & BALANCE"
92 IFBZ=0ORZQ=1THENPRINT"[155] * [146] RETURN TO INDEX MENU":GOTO94
93 IFBZ<>0THENPRINT"[153] 5 [146] [158]RETURN TO INDEX MENU"
94 IFIU=1THEN45
95 IFBZ=0THEN70
96 GETA$
97 K=VAL(A$):IFK<1ORK>5THEN96
98 IFK=1THEN104
99 IFK=2THEN131
100 IFK=3ANDNR>0ANDZQ=0THEN187
101 IFK=4ANDNR>0ANDZQ=0THEN247
102 IFK=5ANDBZ<>0ANDZQ=0THEN7
103 GOTO96
104 IFZQ=1THEN158
105 NR=NR+1
106 PRINT""
107 PRINT"[155]"X$(1);"[194][159]   ENTER PAYMENT  [155]:[158]  ENTER \0 TO END  [146][155][193]";:PRINTX$(2)
108 IFNR>=100THENPRINT"[158]STATEMENT IS FULL":GOSUB433:GOSUB440:GOTO64
109 PRINTTA$" AMOUNT PAID IN: \";:GOSUB392
110 IF(B$=""ORB$="0")ANDC$=""THENNR=NR-1:GOTO64
111 A$(NR)="+"+B$:BA=BA+VAL(A$(NR))
112 GOSUB420:BA$(NR)=BA$
113 GOSUB440:PRINTTA$"[155]INPUT TRANSACTION DESCRIPTION[158]"
114 PRINT,"(8 CHARS MAX)"
115 PRINTTB$"  ";:GOSUB378
116 CK$(NR)=B$:P(NR)=0
117 GOSUB440:PRINTTA$"[155]DATE (DD[158]/[155]MM[158]/[155]YY): ";:GOSUB356
118 IFDE=1THENDE=0:GOTO117
119 GOSUB440:PRINTTB$"[145][145][159]FILE ENTRY READS:-"
120 PRINTTB$"[153]"DT$(NR)" "CK$(NR)"\"RIGHT$(A$(NR),8)" "BA$(NR)
121 GETA$:IFA$=""THENPRINT"[158] IS THIS CORRECT? [146]":GOSUB438
122 IFA$="N"THENGOSUB440:GOTO106
123 IFA$="Y"THEN126
124 PRINT"[158] IS THIS CORRECT? ":GOSUB438:IFA$=""THEN121
125 IFA$<>"N"ORA$<>"Y"THEN121
126 GETA$:IFA$=""THENPRINT" MORE PAYINS Y/N? [146]":GOSUB438
127 IFA$="N"THENGOSUB440:PRINT"[158]SAVING NEW DETAILS":GOTO64
128 IFA$="Y"THENGOSUB440:GOTO105
129 PRINT" MORE PAYINS Y/N? ":GOSUB438:IFA$=""THEN126
130 IFA$<>"N"ORA$<>"Y"THEN126
131 IFZQ=1THEN173
132 NR=NR+1
133 PRINT""
134 PRINT"[155]"X$(1);"[194][150]   ENTER PAY OUT  [155]:[158]  ENTER \0 TO END  [146][155][193]";:PRINTX$(2)
135 IFNR>=100THENPRINT"[158]STATEMENT IS FULL":GOSUB433:GOSUB440:GOTO64
136 PRINTTA$"[150] AMOUNT PAID OUT \";:GOSUB392
137 IF(B$=""ORB$="0")ANDC$=""THENNR=NR-1:GOTO64
138 A$(NR)="-"+B$:BA=BA+VAL(A$(NR))
139 GOSUB420:BA$(NR)=BA$
140 GOSUB440:PRINTTA$"[155]INPUT CHEQUE NUMBER OR DESCRIPTION[158]"
141 PRINT,"(8 CHARS MAX)"
142 PRINTTB$"  ";:GOSUB378
143 CK$(NR)=B$:P(NR)=0
144 GOSUB440:PRINTTA$"[155]DATE (DD[158]/[155]MM[158]/[155]YY): ";:GOSUB356
145 IFDE=1THENDE=0:GOTO144
146 GOSUB440:PRINTTB$"[145][145][159]FILE ENTRY READS:-"
147 PRINTTB$"[150]"DT$(NR)" "CK$(NR)"\"RIGHT$(A$(NR),8)" "BA$(NR)
148 GETA$:IFA$=""THENPRINT"[158] IS THIS CORRECT? [146]":GOSUB438
149 IFA$="N"THENGOSUB440:GOTO133
150 IFA$="Y"THEN153
151 PRINT"[158] IS THIS CORRECT? ":GOSUB438:IFA$=""THEN148
152 IFA$<>"N"ORA$<>"Y"THEN148
153 GETA$:IFA$=""THENPRINT"MORE PAYOUTS Y/N ?[146]":GOSUB438
154 IFA$="N"THENGOSUB440:PRINT"[158]SAVING NEW DETAILS":GOTO64
155 IFA$="Y"THENGOSUB440:GOTO132
156 PRINT"MORE PAYOUTS Y/N? ":GOSUB438:IFA$=""THEN153
157 IFA$<>"N"ORA$<>"Y"THEN153
158 PRINTTA$"[155]DATE (DD[158]/[155]MM[158]/[155]YY): ";:GOSUB356
159 IFDE=1THENDE=0:GOTO158
160 GOSUB440:PRINTTB$"[145][145][145][145][155]INPUT TRANSACTION DESCRIPTION[158]"
161 PRINT,"(8 CHARS MAX)"
162 PRINTTB$"[145][145]  ";:GOSUB378
163 CK$(I)=B$:P(I)=0
164 PRINTTA$"[153] AMOUNT PAID IN: \";:GOSUB392
165 IF(B$=""ORB$="0")ANDC$=""THEN164
166 A$(I)="+"+B$:GOSUB233
167 PRINTTA$"FILE ENTRY READS:-            "
168 PRINTTA$""DT$(I)" "CK$(I)"\"RIGHT$(A$(I),8)" "BA$(I)
169 GETA$:IFA$=""THENPRINTTA$"[158] IS THIS CORRECT? (Y/N)":GOSUB438
170 IFA$="N"THENGOSUB440:GOTO158
171 IFA$="Y"THENZQ=0:SE=0:GOSUB440:GOTO64
172 IFA$<>"N"ORA$<>"Y"THEN169
173 PRINTTA$"[155]DATE (DD[158]/[155]MM[158]/[155]XY): ";:GOSUB356:DT$(I)=DT$(P-1)
174 IFDE=1THENDE=0:GOTO173
175 PRINTTA$"[155]INPUT CHEQUE NUMBER OR DESCRIPTION[158]"
176 PRINTTA$"[158]  ";:GOSUB378
177 CK$(I)=B$:P(I)=0:GOSUB440
178 PRINTTA$"[150] AMOUNT PAID OUT \";:GOSUB392
179 IF(B$=""ORB$="0")ANDC$=""THEN178
180 A$(I)="-"+B$:GOSUB233
181 GOSUB440:PRINTTA$"FILE ENTRY READS:-"
182 PRINTTA$""DT$(I(" "CK$(I)"\"RIGHT$(A$(I(,8)" "BA$(I)
183 GETA$:IFA$=""THENPRINTTA$"[158] IS THIS CORRECT? [146]":GOSUB438
184 IFA$="N"THENGOSUB440:GOTO173
185 IFA$="Y"THENZQ=0:SE=0:GOSUB440:GOTO64
186 IFA$<>"N"ORA$<>"Y"THEN183
187 PN=INT((NR-1)/10)+1
188 PRINT"[147][155]";X$(1);"[194]                                      [193]";
189 PRINT"[194]                                      [193]";X$(2)"[146]";
190 PRINT"[158]                                      [146]"
191 PRINTTA$"[145][153][176][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][178][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][174]"
192 PRINTTA$"^                 _                  _"
193 PRINT"[173][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][177][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][189]":PRINT"",,"[158]";G$(A)
194 PRINT"[158] CHECK  STATEMENT [146]"
195 PRINT"[150]                                      [146]"
196 PRINT"","[157][150] : ORIGINAL BALANCE \";TL$
197 PRINT"[155]  DATE    TRANS   PAYMENT  BALANCE  "
198 PRINTTA$,,"[155] P=PRINTER:[152]Q=QUIT [146]"
199 J=INT((NR-1)/10)*10+1
200 PRINT"[150] PAGE ";PN
201 PRINT"[158]"
202 FORPK=1TO10:PRINT"                                       ":NEXT
203 P=J:PRINT"[158]";:GOSUB204:GOTO210
204 PRINT"[158]"
205 FORI=1TOP-J+1:PRINT:NEXT
206 IFLEFT$(A$(P),1)="+"THENPRINTDT$(P),CK$(P)"[153]"RIGHT$(A$(P),8)"[146]  "BA$(P)
207 IFLEFT$(A$(P),1)="-"THENPRINTDT$(P),CK$(P)"[150]"RIGHT$(A$(P),8)"[146]  "BA$(P)
208 RETURN
209 GOSUB204
210 IFP<J+9THENPRINT"[158]";:GOSUB204
211 IFP=NRTHEN215
212 IFP<J+9THENP=P+1:GOTO209
213 IFP=J+9ANDP=NRTHENGOSUB204
214 IFP=J+9ANDP<NRTHENGOSUB204
215 IFJ>1ANDJ+9<NRTHENPRINTTA$"[158]+/- PAGE ON/BACK [146]";:GOTO218
216 IFJ<>1THENPRINTTA$"[150] - PAGE BACKWARD [146]";:GOTO218
217 IFJ+9<NRTHENPRINTTA$"[153] + PAGE  FORWARD [146]";
218 NL=NR-SE:GETA$:IFA$=""THEN218
219 IFA$="+"ANDJ+9<NRTHENJ=J+10:PN=PN+1:GOTO200
220 IFA$="-"ANDJ>1THENJ=J-10:PN=PN-1:GOTO200
221 IFA$="Q"THEN85
222 IFA$="P"ANDNR>SEANDNL>1THENPRINTTB$"[155]THERE ARE"NL"TRANSACTIONS TO PRINT"
223 IFA$="P"ANDNR>SEANDNL>1THENPRINTTB$"PRINT THEM (Y/N)?":GOTO229
224 IFA$="P"ANDNR>SEANDNL=1THENPRINTTB$"[155]THERE IS"NL"TRANSACTION TO PRINT"
225 IFA$="P"ANDNR>SEANDNL=1THENPRINTTB$"PRINT IT (Y/N)?":GOTO229
226 IFA$="P"ANDNR<=SETHENPRINTTB$"[155]NO TRANSACTIONS LEFT TO PRINT"
227 IFA$="P"ANDNR<=SETHENGOSUB434:GOSUB440
228 GOTO218
229 GETA$:IFA$=""THEN229
230 IFA$="N"THENGOSUB440:GOTO218
231 IFA$="Y"THENGOSUB440:GOTO237
232 IFA$<>"Y"ORA$<>"N"THEN22
233 BA=BZ:FORWO=ITONR:BA$(WO)="":NEXT:EN=NR:NR=1
234 BA=BA+VAL(A$(NR)):GOSUB420:BA$(NR)=BA$:PRINTTA$"[158] WORKING "
235 IFNR<ENTHENNR=NR+1:PRINTTA$"[158] WORKING [146]":GOTO234
236 IFNR=ENTHENGOSUB440:RETURN
237 NS=SN:IFNS=1THENLE$=TL$
238 OPEN4,4:PRINT#4
239 PRINT#4,"STATEMENT NUMBER:";NS;"FOR ";G$(A)
240 PRINT#4,"[192][192][192][192][192][192][192][192][192][192][192][192] PREVIOUS BALANCE: \"LE$
241 PRINT#4:PRINT#4," DATE     TRANS      PAYMENT    BALANCE [146]"
242 FORW=SE+1TONR:IFW=NR+1THEN63999
243 IFLEFT$(A$(W),1)="+"THENPRINT#4,DT$(W)"  "CK$(W)A$(W)"  "BA$(W):NEXT
244 IFLEFT$(A$(W),1)="-"THENPRINT#4,DT$(W)"  "CK$(W)A$(W)"  "BA$(W):NEXT
245 PRINT#4:PRINT#4,"[192][192][192][192][192][192][192][192][192][192][192][192] LATEST BALANCE: \"BA$(NR)
246 SN=NS+1:SE=NR:LE$=BA$(NR):CLOSE4:GOTO64
247 PN=INT((NR-1)/10)+1
248 PRINT"[147][153]"X$(1);"[194][155]                                      [146][153][193]";
249 PRINT"[194]                                      [193]";X$(2)"[146]";
250 PRINTTA$"[145][158][176][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][178][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][174]"
251 PRINT"^                 _                  _"
252 PRINT"[171][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][219][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][179]"
253 PRINT"^                 _                  _"
254 PRINT"[173][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][177][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][189]":PRINT"",,"[155]";G$(A)
255 PRINT"[155] EDIT  STATEMENT [146]"
256 PRINT"[152]                                      [146]"
257 PRINT"","[157][152] : ORIGINAL BALANCE \";TL$
258 PRINTTA$,,"[155] SELECT Q TO QUIT [146]"
259 PRINT" CRS U/D = SELECT[146][153]_ AND PRESS RETURN [146]"
260 PRINT" DELETE / EDIT IS ON HIGHLIGHTED LINE":PRINT,,"[157][163][163]"
261 PRINT"INSERT IS MADE ABOVE HIGHLIGHTED LINE":PRINT,,"[157][157][157][157][163][163][163][163][163]"
262 PRINT"[150]  DATE    TRANS   PAYMENT  BALANCE  "
263 J=INT((NR-1)/10)*10+1
264 PRINT"[152] PAGE ";PN
265 PRINT:FORPK=1TO10:PRINT"                                       ":NEXT
266 PRINT"[153]"
267 FORI=JTOJ+9
268 IFLEFT$(A$(I),1)="+"THENPRINT"[153]"DT$(I),CK$(I)RIGHT$(A$(I),8)"+ "BA$(I)
269 IFLEFT$(A$(I),1)="-"THENPRINT"[153]"DT$(I),CK$(I)RIGHT$(A$(I),8)"- "BA$(I)
270 NEXT
271 IFJ>1ANDJ+9<NRTHENPRINTTA$"[158]+/- PAGE ON/BACK [146]";:GOTO274
272 IFJ<>1THENPRINTTA$"[150] - PAGE BACKWARD [146]";
273 IFJ+9<NRTHENPRINTTA$"[153] + PAGE  FORWARD [146]";
274 P=J:PRINT"";:GOSUB294:GOTO276
275 GOSUB294
276 GETA$:IFA$=""THEN276
277 IFA$=""ANDP=NR THEN276
278 IFA$=""ANDP<J+9THENPRINT"[153]";:GOSUB294:P=P+1:PRINT"";:GOTO275
279 IFA$="[145]"ANDP>JTHENPRINT"[153]";:GOSUB294:P=P-1:PRINT"";:GOTO275
280 IFA$="+"ANDJ+9<NRTHENJ=J+10:PN=PN+1:GOTO264
281 IFA$="-"ANDJ>1THENJ=J-10:PN=PN-1:GOTO264
282 IFA$="Q"ANDUD=0THEN85
283 IFA$="Q"ANDUD=1THENUD=0:PRINTTA$,,"[158]SAVING NEW DETAILS":GOTO64
284 IFA$=CHR$(13)THENUD=1:GOTO298
285 GOTO276
286 PRINTTB$"[145][145][145][153] 1 [146] [159]DATE:        "DT$(P)
287 PRINT"[153] 2 [146] [159]DESCRIPTION: "CK$(P)
288 PRINT"[153] 3 [146] [159]AMOUNT:      \"RIGHT$(A$(P),8)
289 A$=LEFT$(A$(P),1)
290 IFA$="-"THENCDT$="DEBIT"
291 IFA$="+"THENCDT$="CREDIT"
292 PRINT"[153] 4 [146] [159]CREDIT/DEBIT: "CDT$
293 RETURN
294 PRINT"":FORI=1TOP-J+1:PRINT:NEXT
295 IFLEFT$(A$(P),1)="+"THENPRINTDT$(P),CK$(P)RIGHT$(A$(P),8)"+ "BA$(P)
296 IFLEFT$(A$(P),1)="-"THENPRINTDT$(P),CK$(P)RIGHT$(A$(P),8)"- "BA$(P)
297 RETURN
298 B$="[155]":IFNR=100THENB$="[144]"
299 PRINTTA$""B$" I=INSERT AN ITEM[146][153]_[155] D=DELETE AN ITEM "
300 PRINT"[155] E=EDIT AN ITEM  [146][153]_[155] Q=QUIT           "
301 GETA$:IFA$="Q"THEN85
302 IFA$="I"ANDB$="[155]"THEN351
303 IFA$="D"THEN346
304 IFA$<>"E"THEN301
305 PRINTTA$"[145][153][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192]"
306 PRINTTA$"                                      "
307 PRINTTA$"                                      ":GOSUB440:GOSUB286
308 PRINT"  SELECT 1[146],2[146],3[146],4[146] OR Q=QUIT"
309 GETA$:IFA$="Q"THEN85
310 K=VAL(A$):IFK<1ORK>4THEN309
311 ONKGOTO312,320,326,336
312 GOSUB440:DC=NR:NR=P:T$=DT$(P)
313 PRINTTA$"[159] DATE TO CHANGE IS :-[146] "DT$(P)
314 PRINTTA$"[158]ENTER NEW DATE:[155]";:GOSUB356
315 IFDE=1THENDE=0:GOSUB440:GOTO313
316 PRINT:PRINT"[158]OK (Y/N)?":NR=DC
317 GETA$:IFA$="N"THENDT$(P)=T$:GOSUB440:GOTO247
318 IFA$<>"Y"THEN317
319 GOSUB440:GOTO247
320 GOSUB440:PRINTTB$"[145][145][145][159] DETAIL IS [146]:- "CK$(P)
321 PRINT"[158]ENTER NEW DESC:[155] ";:GOSUB377
322 PRINT:PRINT"[158]OK (Y/N)?"
323 GETA$:IFA$="N"THENGOSUB440:GOTO247
324 IFA$<>"Y"THEN323
325 GOSUB440:CK$(P)=B$:GOTO247
326 GOSUB440:PRINTTB$"[145][145][145][159] AMOUNT TO CHANGE [146]:- \"RIGHT$(A$(P),8)
327 PRINT"[158]NEW AMOUNT:[155]\";:GOSUB392
328 PRINT:PRINT"[158]OK (Y/N)?"
329 GETA$:IFA$="N"THENGOSUB440:GOTO247
330 IFA$<>"Y"THEN329
331 A$(P)=LEFT$(A$(P),1)+B$
332 BA=BZ:FORWO=JTONR:BA$(WO)="":NEXT:EN=NR:NR=1
333 BA=BA+VAL(A$(NR)):GOSUB420:BA$(NR)=BA$:PRINTTA$,,"[158] WORKING          "
334 IFNR<ENTHENNR=NR+1:PRINTTA$,,"[158]          WORKING [146]":GOTO333
335 IFNR=ENTHEN247
336 GOSUB440:PRINTTB$"[145][145][145][159] ITEM IS A "CD$
337 PRINT"[158]CREDIT/DEBIT:ENTER C OR D [155]";
338 GETA$:IFA$="C"THENB$="+":GOTO341
339 IFA$<>"D"THEN338
340 B$="-"
341 PRINTA$
342 PRINT"[158]OK (Y/N)?"
343 GETA$:IFA$="N"THENGOSUB440:GOTO247
344 IFA$<>"Y"THEN343
345 A$(P)=B$+RIGHT$(A$(P),8):GOTO332
346 PRINTTA$,," ARE YOU SPRE Y/N [146]":GETA$:IFA$="N"THEN247
347 IFA$<>"Y"THEN346
348 FORI=P+1TONR
349 CK$(I-1)=CK$(I):DT$(I-1)=DT$(I):A$(I-1)=A$(I):BA$(I-1)=BA$(I):NEXT
350 CK$(NR)="":A$(NR)="":DT$(NR)="":BA$(NR)="":NR=NR-1:GOTO332
351 NR=NR+1:FORI=NRTOPSTEP-1
352 IFI=PTHEN354
353 CK$(I)=CK$(I-1):DT$(I)=DT$(I-1):A$(I)=A$(I-1):BA$(I)=BA$(I-1):NEXT
354 IFI=PTHENZQ=1
355 GOTO85
356 DT$(ND)=""
357 GETA$:IFA$=""THEN357
358 IFA$=CHR$(13)ANDLEN(DT$(ND))=8ANDZQ=0THENDT$(NR)=DT$(ND):RETURN
359 IFA$=CHR$(13)ANDLEN(DT$(ND))=8ANDZQ=1THENDT$(I)=DP$(ND):RETURN
360 IFA$=CHR$(20)ANDLEN(DT$(ND))>0THENDE=1:RETURN
361 IFLEN(DT$(ND))=8THEN357
362 IFA$="0"THEN364
363 IFVAL(A$)<1THEN357
364 IFLEN(DT$(ND))=0ANDVAL(A$)>3THEN357
365 IFDT$(ND)="3"ANDVAL(A$)>1THEN357
366 IFDT$(ND)="0"ANDVAL(A$)=0THEN357
367 IFLEN(DT$(ND))=3ANDVAL(A$)>1THEN357
368 IFMID$(DT$(ND),4,1)="1"ANDLEN(DT$(ND))=4ANDVAL(A$)>2THEN357
369 IFMID$(DT$(ND),4,1)="0"ANDLEN(DT$(ND))=4ANDVAL(A$)=0THEN357
370 IFLEN(DT$(ND))=6ANDVAL(A$)<8THEN357
371 IFLEN(DT$(ND))=1THENA$=A$+"/"
372 IFLEN(DT$(ND))=4THENA$=A$+"/"
373 DT$(ND)=DT$(ND)+A$:PRINTA$;:GOTO357
374 L=1:IFLEN(DT$(ND))=3THENL=2
375 IFLEN(DT$(ND))=6THENL=2
376 DT$(ND)=LEFT$(DT$(ND),LEN(DT$(ND))-L)
377 PRINT"[157] [157]";:IFL=2THENPRINT"[157] [157]";:GOTO357
378 B$="":L=0:S=1
379 GETA$:IFA$=""THEN379
380 IFA$=CHR$(13)THEN390
381 IFA$=CHR$(20)ANDL>0THEN389
382 IFL=8THEN379
383 IFA$=","ORA$=":"THEN379
384 IFA$=" "ANDS=1THEN379
385 IFA$=" "ORA$="!"THEN387
386 IFA$<"#"ORA$>"_"THEN379
387 S=0:IFA$=" "THENS=1
388 B$=B$+A$:L=L+1:PRINTA$;:GOTO379
389 S=0:PRINT"[157] [157]";:L=L-1:B$=LEFT$(B$,L):GOTO379
390 IFLEN(B$)<9THENB$=B$+" ":GOTO390
391 RETURN
392 B$="":C$="":L=0
393 GETA$:IFA$=""THEN393
394 IFA$=CHR$(13)ANDL=0THENB$="0.00":GOTO417
395 IFA$=CHR$(13)THENB$=B$+".00":GOTO417
396 IFA$=CHR$(20)ANDL>0THEN404
397 IFA$="."ANDL=0THENA$="0.":L=1:GOTO405
398 IFA$="."THEN405
399 IFL=5THEN393
400 IFB$="0"THEN393
401 IFA$="0"THEN403
402 IFVAL(A$)=0THEN393
403 PRINTA$;:B$=B$+A$:L=L+1:GOTO393
404 L=L-1:PRINT"[157] [157]";:B$=LEFT$(B$,L):GOTO393
405 L=L+1:B$=B$+A$:L1=0:C$="":PRINTA$;
406 GETA$:IFA$=""THEN406
407 IFVAL(B$)=0ANDA$=CHR$(13)ANDC$=""THEN418
408 IFA$=CHR$(13)ANDL1=2THENB$=B$+C$:GOTO417
409 IFA$=CHR$(20)ANDL1>0THEN416
410 IFA$=CHR$(20)THEN404
411 IFL1=2THEN406
412 IFA$="0"THEN414
413 IFVAL(A$)=0THEN406
414 PRINTA$;:C$=C$+A$:L1=L1+1:GOTO406
415 IFL1=2THENB$=B$+C$:GOTO419
416 L1=L1-1:PRINT"[157] [157]";:C$=LEFT$(C$,L1):GOTO406
417 IFLEN(B$)<8THENB$=" "+B$:GOTO417
418 IFVAL(B$)=0THENB$=""
419 RETURN
420 BA=BA*100+.5:BA=INT(BA)/100
421 B$=STR$(ABS(BA*100)):B$=RIGHT$(B$,LEN(B$)-1)
422 IFLEN(B$)<3THENBA$="0":GOTO424
423 BA$=LEFT$(B$,LEN(B$)-2)
424 BA$=BA$+"."
425 IFLEN(B$)=1THENBA$=BA$+"0"+B$:GOTO427
426 BA$=BA$+RIGHT$(B$,2)
427 IFLEN(BA$)<8THENBA$=CHR$(160)+BA$:GOTO427
428 IFB$="0"THENB$="  ":GOTO431
429 B$="[153] C"
430 IFBA<>ABS(BA)THENB$="[150] D"
431 BA$=BA$+B$:RETURN
432 FORW=1TO2000:NEXT
433 FORW=1TO1000:NEXT
434 FORW=1TO500:NEXT
435 FORW=1TO400:NEXT
436 FORW=1TO300:NEXT
437 FORW=1TO200:NEXT
438 FORW=1TO100:NEXT
439 FORW=1TO100:NEXT:RETURN
440 PRINTTA$"                                       ":FORWP=1TO5
441 PRINT"                                       ":FORW=1TO50:NEXT:NEXT:RETURN
442 PRINTTB$"                                       ":RETURN
443 X$(1)="[213]>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>[201]":E$(3)="INDEX":N=100:SN=1
444 X$(2)="[202]<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<[203]":R$=CHR$(13)
445 DIMCK$(N+1),DT$(N+1),A$(N+1),P(N+1),G$(30),J(30),A(30),BA$(N+1)
446 TB$="":TA$=""
447 LC$="[175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175]":LK$="                   "
448 SI$="[172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172]":RETURN