10 POKE51,52:POKE52,52:POKE55,52:POKE56,52:G=G+1:IFG=1THENLOAD"TN.CHR",8,1
20 POKE53280,0:POKE53281,0:GOSUB2550:GOSUB2450
30 PRINT"[147]";X$(1)"[199][153]     GALAXY ORE MINING CORPORATION    [200]";
40 PRINT"[199][153]    SUPERVISORS REPORT FOR            [200]";:PRINTX$(2);
50 PRINT"";X$(3):PRINTX$(4):PRINTX$(5):PRINTX$(4):PRINTX$(6):PRINTTP$;X$(7)
60 PRINTX$(8):PRINTX$(9):PRINTX$(8):PRINTX$(9):PRINTX$(8):PRINTX$(10):GOSUB2180
70 FG=1:IFTC=1ANDY=ETHENGOSUB2100
80 RS=INT(RND(1)*3)+1:IFRS=3THENGOSUB1740
90 IFCR<800ANDS>1000THENGOSUB1600
100 IFCR<1THEN1000
110 C=INT(RND(18)*9)+18:MP=C
120 X=0:POKEV,18:PRINTU$:POKEH,1:PRINT"[154]HOW MANY MINES WOULD YOU LIKE TO CLOSE"
130 PRINT"THIS MONTH AT"MP"CREDITS A MINESHAFT":INPUT"";X
140 X=INT(X)
150 IFPEEK(200)=3THEN120
160 IFX=0THENGOSUB1700:GOTO220
170 IFX<TMTHENGOSUB1700:GOTO210
180 GOSUB1700
190 POKEV,18:PRINTU$:POKEH,1:PRINT"[159]SUPERVISOR..YOU ONLY HAVE"TM"MINES"
200 PRINT"TRY CLOSING A FEW LESS":GOSUB2140:GOSUB1700:GOTO120
210 TM=TM-X:CR=CR+MP*X:GOSUB2280:GOSUB2400:GOTO340
220 C=INT(RND(18)*9)+18:MP=C
230 X=0:POKEV,18:PRINTU$:POKEH,1:PRINT"[154]HOW MANY NEW MINES WILL YOU OPEN THIS"
240 PRINT"MONTH AT"MP"CREDITS A MINESHAFT":INPUT"";X
250 X=INT(X)
260 IFPEEK(200)=3THEN230
270 IFX=0THENGOSUB1700:GOTO340
280 IFMP*X<=CRTHENGOSUB1700:GOTO330
290 GOSUB1700:IFCR<1THEN1000
300 POKEV,18:PRINTU$:POKEH,1:PRINT"[158]SUPERVISOR, THERE IS ONLY SUFFICIENT"
310 POKEV,19:PRINTU$:POKEH,1:PRINT"FUNDS TO PURCHASE";INT(CR/MP);"MINES"
320 GOSUB2140:GOSUB1700:GOTO230
330 TM=TM+X:CR=CR-MP*X:GOSUB2280:GOSUB2400
340 F=0:POKEV,18:PRINTU$:POKEH,3:PRINT"[152]HOW MANY CREDITS WILL YOU SPEND TO"
350 PRINT"FEED THE WORKFORCE THIS MONTH":INPUT"";F
360 F=INT(F)
370 IFF=0THENGOSUB1700:GOTO340
380 IFF<=CRTHENGOSUB1700:CR=CR-F:GOTO430
390 GOSUB1700:IFCR<1THEN1000
400 POKEV,18:PRINTU$:POKEH,1:PRINT"[158]SUCH GENEROSITY BUT YOU ONLY HAVE"CR
410 POKEV,19:PRINTU$:POKEH,1:PRINT"CREDITS AVAILABLE SUPERVISOR"
420 GOSUB2140:GOSUB1700:GOTO340
430 GOSUB2400
440 D=WF-INT(F/10):I=0:IFD>0THEN460
450 I=-D/2:D=0
460 MW=0:POKEV,18:PRINTU$:POKEH,3:PRINT"[159]HOW MANY MINES WILL BE WORKED THIS"
470 PRINT"MONTH SUPERVISOR ?":INPUT"";MW
480 MW=INT(MW)
490 IFMW=0THEN460
500 IFMW<=TMTHEN540
510 GOSUB1700
520 POKEV,18:PRINTU$:POKEH,1:PRINT"[159]IMAGINATIVE THINKING SIR BUT WE ONLY"
530 PRINT"HAVE"TM"MINESHAFTS":GOSUB2140:GOSUB1700:GOTO460
540 IFINT(MW/2)<=CRTHEN650
550 GOSUB1700
560 POKEV,17:PRINTU$:POKEH,2:PRINT"[152]CREDITS HAVE BEEN DEDUCTED TO BE ABLE"
570 CH=INT(RND(1)*3)+1:ONCHGOTO580,590,600
580 PRINT"TO PURCHASE SOME NEW MINE EQUIPMENT.":GOTO610
590 PRINT"TO IMPROVE THE MINE SAFETY EQUIPMENT.":GOTO610
600 PRINT"TO MAKE REPAIRS TO MINE EQUIPMENT."
610 SB=INT(CR/3):SB=INT(SB)
620 IFSB>1THENPRINT"ONLY[158]"SB"[152]MINES CAN BE WORKED":GOTO640
630 IFSB=1THENPRINT"ONLY[158] 1 [152]MINE CAN BE WORKED"
640 MW=SB:CR=CR-SB-10:GOSUB2400:GOSUB2140:GOSUB1700:GOTO700
650 IFMW<=10*WFTHEN700
660 GOSUB1700
670 POKEV,18:PRINTU$:POKEH,1:PRINT"[159]SUPERVISOR,ONE WORKER CAN ONLY OPERATE"
680 PRINT"TEN MINES. WE CAN OPERATE A MAXIMUM OF":MW=10*WF:PRINTMW"MINES"
690 GOSUB2430:GOSUB1700:GOTO460
700 C=INT(RND(1)*5)+1:M=MW*C:BN=INT(RND(1)*70)+1:IFBN>60THENGOSUB1390
710 IFBN>50ANDBN<60ANDS>2000THENGOSUB1470
720 Q=RND(1)*3+1
730 IFINT(Q/2)<>Q/2THEN750
740 K=INT(S/Q)
750 S=S-K+M:GOSUB2360:IFS>99000THENGOTO1280
760 I=INT(C*(20*TM+S)/WF/100+1):GOSUB2320:WF=WF+I
770 Q=INT(F/10):DP=INT(RND(1)*3)+1
780 IFWF<QTHEND=DP:GOTO850
790 D=WF-Q:GOSUB2380:CP=CP+D:IFD>.5*WFTHEN880
800 IFD>.35*WFTHEN830
810 IFD>.2*WFTHEN1360
820 IFLC=4THEN880
830 WF=Q
840 IFCR>400*WFTHEN1090
850 E=E+3:IFE=37THENYR=YR+1:E=1:LC=0
860 IFE<37THENGOSUB1700
870 GOSUB2340:GOSUB2250:MT=MT+1:GOTO70
880 PRINT"[147][150]"CP"PEOPLE HAVE DIED OF MALNUTRITION":K$="MONTH"
890 PRINT"AND OTHER RELATED DISEASES SINCE YOU":IFMT<>1THENK$=K$+"S"
900 PRINT"TOOK OVER HERE"MT;K$;" AGO."
910 IFSL>0THENPRINT""SL"WORKERS HAVE BEEN LOST TO SLAVERY."
920 FORW=1TO1000:NEXT:PRINT,,"[157][157][157][157][157]_  _  _":FORW=1TO1000:NEXT
930 PRINT"YOU HAVE BEEN ASSASINATED BY A MEMBER"
940 PRINT"OF THE WORKFORCE BECAUSE OF YOUR POOR"
950 PRINT"LEADERSHIP QUALITIES."
960 PRINT"TRY AGAIN WITH A FRESH SUPERVISOR (Y/N)":GOSUB2140
970 IFA$="N"THENSYS64738
980 IFA$="Y"THENGOSUB2440:GOTO30
990 IFA$<>"N"ORA$<>"Y"THEN880
1000 PRINT"[147][153]YOU ARE STONEY BROKE !!! YOU HAD"
1010 PRINT"THE MEANS TO FURTHER YOUR CAREER"
1020 PRINT"WITH THE COMPANY AND YOU BLEW IT."
1030 PRINT"IT MIGHT BE BEST IF YOU WERE ON"
1040 PRINT"THE NEXT SHIP OUT OF HERE."
1050 PRINT"TRY AGAIN WITH A FRESH SUPERVISOR (Y/N)":GOSUB2140
1060 IFA$="N"THENSYS64738
1070 IFA$="Y"THENGOSUB2440:GOTO30
1080 IFA$<>"N"ORA$<>"Y"THEN1000
1090 PRINT"[147][154]YOU HAVE DECIDED TO TAKE THE SOFT"
1100 PRINT"OPTION AND LEG IT OFF THE PLANET"
1110 PRINT"WITH THE COMPANY SAFE AMONGST YOUR"
1120 PRINT"LUGGAGE.":PRINT"THE SAFE CONTAINS A TOTAL OF"CR
1130 PRINT"CREDITS AND SOME GOLD AND SILVER"
1140 PRINT"WHICH YOU 'CREAMED' OFF FOR JUST"
1150 PRINT"SUCH AN OCCASION."
1160 PRINT"TRY AGAIN WITH A FRESH SUPERVISOR (Y/N)":GOSUB2140
1170 IFA$="N"THENSYS64738
1180 IFA$="Y"THENGOSUB2440:GOTO30
1190 IFA$<>"N"ORA$<>"Y"THEN1090
1200 PRINT"[147][155]I DON'T KNOW HOW YOU DID IT BUT YOU"
1210 PRINT"HAVE MANAGED TO CLOSE DOWN THE ENTIRE"
1220 PRINT"OPERATION ALL BY YOUR SELF."
1230 PRINT"MOVE OVER AND LET SOMEONE ELSE HAVE AGO."
1240 PRINT"[152]TRY AGAIN WITH A FRESH SUPERVISOR (Y/N)":GOSUB2140
1250 IFA$="N"THENSYS64738
1260 IFA$="Y"THENGOSUB2440:GOTO30
1270 IFA$<>"N"ORA$<>"Y"THEN1200
1280 PRINT"[147][159]THERE ISN'T ROOM TO STORE ANY MORE"
1290 PRINT"ORE. THE MARKETS HAVE STOPPED BUYING"
1300 PRINT"BECAUSE OF A GLUT."
1310 PRINT"GO ON VACATION UNTIL THINGS IMPROVE."
1320 PRINT"[152]TRY AGAIN WITH A FRESH SUPERVISOR (Y/N)":GOSUB2140
1330 IFA$="N"THENSYS64738
1340 IFA$="Y"THENGOSUB2440:GOTO30
1350 IFA$<>"N"ORA$<>"Y"THEN1280
1360 LC=LC+1:GOSUB1700
1370 POKEV,18:PRINTU$:POKEH,1:PRINT"[150]BE WARNED !! THE WORKERS ARE HUNGRY"
1380 PRINT"AND THERE IS TALK OF REBELLION.":GOSUB2430:GOSUB1700:GOTO830
1390 X=INT(RND(1)*4)+1:BC=MW*X+300:GOSUB1700
1400 IFX=1THENBN$="TIN":GOTO1440
1410 IFX=2THENBN$="COPPER":GOTO1440
1420 IFX=3THENBN$="SILVER":GOTO1440
1430 IFX=4THENBN$="GOLD"
1440 POKEV,18:PRINTU$:POKEH,1:PRINT"[158]BONUS! WE HAVE FOUND A VEIN OF "BN$
1450 O$="CREDIT":IFBB<>1THENO$=O$+"S"
1460 PRINT"THIS IS WORTH"BC;O$:CR=CR+BC:GOSUB2430:GOSUB2400:RETURN
1470 X=INT(RND(1)*3)+1:GOSUB1700
1480 IFX=1THENSH$="CARGO TUG"
1490 IFX=2THENSH$="FREIGHTER"
1500 IFX=3THENSH$="ORE CARRIER"
1510 X=X+2:POKEV,18:PRINTU$:POKEH,1:PRINT"[158]SUPERVISOR, A PASSING "SH$" HAS"
1520 PRINT"HAILED US AND ENQUIRES IF WE WISH TO"
1530 PRINT"SELL SOME STOCK. THE CAPTAIN HAS ROOM"
1540 OS=RND(1)*(1500-500)+500:OS=INT(OS):PRINT"FOR"OS"TONS AT"X"CREDITS A TON"
1550 PRINT"SHALL I SELL AT THAT PRICE ? Y/N ?"
1560 GOSUB2140:IFA$="N"THENGOSUB1700:RETURN
1570 IFA$="Y"THENCR=CR+OS*X:MS=MS+OS:S=S-OS:GOSUB2300:GOSUB2360:GOSUB2400
1580 IFA$="Y"THENGOSUB1700:RETURN
1590 IFA$<>"N"ORA$<>"Y"THENGOSUB1700:GOTO1470
1600 RN=INT(RND(100)*2000)+1:PD=INT(RND(1)*4)+1:OS=INT(RND(1)*600)+RN
1610 POKEV,18:PRINTU$:POKEH,1:PRINT"[158]I HAVE CALLED THE FEDERATION MARKETS"
1620 PRINT"WHO REQUIRE"OS"TONS OF ORE."
1630 O$="CREDIT":IFPD<>1THENO$=O$+"S"
1640 PRINT"THEY WILL PAY"PD;O$" A TON. SHALL I"
1650 PRINT"SELL AT THAT PRICE ? Y/N ?"
1660 GOSUB2140:IFA$="N"THENGOSUB1700:RETURN
1670 IFA$="Y"THENCR=CR+OS*PD:MS=MS+OS:S=S-OS:GOSUB2300:GOSUB2360:GOSUB2400
1680 IFA$="Y"THENGOSUB1700:RETURN
1690 IFA$<>"N"ORA$<>"Y"THENGOSUB1700:GOTO1610
1700 W=17:FORXW=1TO8
1710 POKEV,W:PRINTU$:POKEH,0:PRINT"                                       "
1720 W=W+1:IFW<25THENNEXT
1730 RETURN
1740 RG=INT(RND(1)*5)+1:ONRGGOTO1750,1900,1750,1900,1750
1750 IFTM<=1THEN1200
1760 X=INT(RND(1)*4)+1:GOSUB2080
1770 IFX=1THENAP$="HILL":GOTO1810
1780 IFX=2THENAP$="RIVER":GOTO1810
1790 IFX=3THENAP$="DESERT":GP=INT(RND(1)*WF/5)+2:WF=WF-GP:GOSUB2340:GOTO1810
1800 IFX=4THENAP$="PLAINS":GE=INT(RND(1)*100)+1:CR=CR-GE:GOSUB2400
1810 POKEV,18:PRINTU$:POKEH,2:PRINT"[150]WE HAVE BEEN ATTACKED BY ONE OF THE"
1820 PRINT""AP$" TRIBES."DN"WORKERS ARE DEAD."
1830 IFX=1ORX=2THENGOSUB2140:GOTO1890
1840 IFX=3THENPRINT""GP"OF OUR PEOPLE HAVE BEEN TAKEN AS"
1850 IFX=3THENPRINT"SLAVES":SL=SL+GP:GOSUB2140:GOTO1890
1860 IFX=4THENPRINT"[152]VITAL EQUIPMENT HAS BEEN TAKEN TO THE"
1870 IFX=4THENPRINT"VALUE OF"GE"CREDITS. YOUR ACCOUNT"
1880 IFX=4THENPRINT"HAS BEEN DEBITED FOR THIS AMOUNT.":GOSUB2140
1890 GOSUB1700:RETURN
1900 IFTM<=1THEN1200
1910 X=INT(RND(1)*4)+1:GOSUB2080
1920 IFX=1THENAP$=" SERIOUS FIRE":GOTO1960
1930 IFX=2THENAP$=" HEAVY FLOOD":GOTO1960
1940 IFX=3THENAP$="N EXPLOSION":GOTO1960
1950 IFX=4THENAP$=" BAD CAVE-IN"
1960 POKEV,18:PRINTU$:POKEH,2:PRINT"[150]THERE HAS BEEN A"AP$" AT A"
1970 PRINT"MINE IN SECTOR"SK"[157]-"SR
1980 PRINT""DN"WORKERS ARE DEAD OR INJURED."
1990 IFX=1ORX=2ANDCM=1ORCM=3THEN2030
2000 IFX=1ORX=2ANDCM=2ORCM=4THEN2060
2010 IFX=3ORX=4ANDCM=1ORCM=3THEN2030
2020 IFX=3ORX=4ANDCM=2ORCM=4THEN2060
2030 IFTC=1THEN2060
2040 IFTC=0THENPRINT"[159]MINE IS CLOSED FOR REPAIRS.":Y=INT(RND(1)*6)*6+1:TC=1
2050 IFTC=1THENTM=TM-1:GOSUB2140:GOTO2070
2060 PRINT"[159]MINE IS CLOSED PERMANENTLY.":TM=TM-1:GOSUB2140
2070 GOSUB2280:GOSUB1700:RETURN
2080 TP=WF:DN=INT(RND(1)*TP/4)+2:WF=WF-DN:D=DN:MD=INT(RND(1)*TM/4)+1:GOSUB2340
2090 SK=INT(RND(1)*50)+1:SR=INT(RND(1)*80)+1:CM=INT(RND(1)*4)+1:GOSUB2380:RETURN
2100 POKEV,18:PRINTU$:POKEH,4:PRINT"[159]DAMAGED MINE HAS BEEN REPAIRED AT"
2110 MR=INT(CR/6):MR=INT(MR)
2120 PRINT"A COST OF"MR"CREDITS":TC=0:TM=TM+1
2130 CR=CR-MR:GOSUB2400:GOSUB2280:GOSUB2140:GOSUB1700:RETURN
2140 RP=23:FORPL=0TO14STEP1:PE$=RIGHT$(PK$,PL+1)
2150 PRINT"[153]"TAB(PL)RIGHT$(V$,RP)" "PE$:NEXT
2160 GETA$:IFA$=""THEN2160
2170 IFA$<>""THENRETURN
2180 POKEV,6:PRINTU$:POKEH,2:PRINT"[159]^ WORKFORCE"
2190 POKEV,6:PRINTU$:POKEH,21:PRINT"[150]_ FATALATIES"
2200 POKEV,8:PRINTU$:POKEH,2:PRINT"[159]TOTAL MINES"
2210 POKEV,8:PRINTU$:POKEH,21:PRINT"[150]^ IMMIGRANTS"
2220 POKEV,11:PRINTU$:POKEH,10:PRINT"[158]MINERAL TONS IN SILOS"
2230 POKEV,13:PRINTU$:POKEH,10:PRINT"[158]MINERALS SHIPPED TO DATE"
2240 POKEV,15:PRINTU$:POKEH,10:PRINT"[152]CREDITS AVAILABLE"
2250 FORW=1TO7:POKEV,3:PRINTU$:POKEH,28:PRINT"[154]"MID$(DT$,E,3);YR
2260 POKEV,3:PRINTU$:POKEH,28:PRINT""MID$(DT$,E,3);YR;"[146]":NEXT
2270 POKEV,3:PRINTU$:POKEH,28:PRINT"[153]"MID$(DT$,E,3);YR
2280 POKEV,8:PRINTU$:POKEH,14:PRINT"      [159]"
2290 POKEV,8:PRINTU$:PRINTTAB(20-LEN(STR$(TM)))TM:IFFG=1THENRETURN
2300 POKEV,13:PRINTU$:PRINTTAB(2)"      [158]"
2310 POKEV,13:PRINTU$:PRINTTAB(8-LEN(STR$(MS)))MS:IFFG=1THENRETURN
2320 POKEV,8:PRINTU$:PRINTTAB(35)"   [150]"
2330 POKEV,8:PRINTU$:PRINTTAB(38-LEN(STR$(I)))I:IFFG=1THENRETURN
2340 POKEV,6:PRINTU$:PRINTTAB(15)"     [159]"
2350 POKEV,6:PRINTU$:PRINTTAB(20-LEN(STR$(WF)))WF:IFFG=1THENRETURN
2360 POKEV,11:PRINTU$:POKEH,2:PRINT"      [158]"
2370 POKEV,11:PRINTU$:PRINTTAB(8-LEN(STR$(S)))S:IFFG=1THENRETURN
2380 POKEV,6:PRINTU$:PRINTTAB(35)"   [150]"
2390 POKEV,6:PRINTU$:PRINTTAB(38-LEN(STR$(D)))D:IFFG=1THENRETURN
2400 POKEV,15:PRINTU$:POKEH,2:PRINT"      [152]"
2410 POKEV,15:PRINTU$:PRINTTAB(8-LEN(STR$(CR)))CR:IFFG=1THENRETURN
2420 RETURN
2430 FORW=1TO3000:NEXT:RETURN
2440 I=0:MS=0:S=0:D=0:CP=0:FG=0:TC=0:GOSUB2550:RETURN
2450 PRINT"[147]":POKE53272,31:A=1
2460 M$="[159] SHADOW  GRAPHICS":J=11:GOSUB2510
2470 M$="[129] PRESENTS":J=15:GOSUB2510
2480 M$=" MAURICE  MINER":J=12:GOSUB2510
2490 M$="[159]@ SHADOW GRAPHICS 1992":J=9:GOSUB2510
2500 GOSUB2430:RETURN
2510 FORT=1TO24STEP1
2520 MS$=LEFT$(M$,1+T)
2530 PRINT""TAB(J)LEFT$(V$,A+10);MS$
2540 FORW=1TO15:NEXTW,T:A=A+2:RETURN
2550 X$(1)="[213][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][201]":TP$="":WF=100
2560 DT$="JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDEC":E=1:PK$="PRESS A KEY"
2570 X$(2)="[202][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][203]":U$="[145][145]":H=211:V=214:D=0
2580 X$(3)=" [176][175][175][175][175][175][175][175][175][175][175][175][178][175][175][175][175][175][175][178][175][175][175][175][175][175][175][175][175][175][175][175][175][178][175][175][175][174]":TM=RND(1)*(1010-990)+990
2590 X$(4)=" [199]           [200]      [200]             [200]   [200]":TM=INT(TM):CR=1000:YR=2050
2600 X$(5)=" [171][175][175][175][175][175][175][175][175][175][175][175][219][175][175][175][175][175][175][219][175][175][175][175][175][175][175][175][175][175][175][175][175][219][175][175][175][179]"
2610 X$(6)=" [173][172][172][172][172][172][172][172][172][172][172][172][177][172][172][172][172][172][172][177][172][172][172][172][172][172][172][172][172][172][172][172][172][177][172][172][172][189]"
2620 X$(7)=" [176][175][175][175][175][175][175][178][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][174]"
2630 X$(8)=" [199]      [200]                             [200]"
2640 X$(9)=" [171][175][175][175][175][175][175][219][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][175][179]"
2650 X$(10)=" [173][172][172][172][172][172][172][177][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][172][189]"
2660 V$="":RETURN