1000 A=200:GOTO20:REM Z=F(X,Y) ,BC3-C
1010 DIMZ(441):CN=0
1015 IFSV<35 THENDIMCC(1):REM COMPATIBILITEIT
1020 CC(0)=0:CC(1)=6:GOSUB100:GOSUB1500
1030 GOSUB100:GOSUB1670
1040 GOSUB600:T=0
1050 REM -- PLAATS TEKST --
1060 SR$=Z$:HO=.4:VE=.95:GOSUB650
1070 REM -- TEKEN IN X-RICHTING --
1080 FORPY=0 TO20:Y=PY/3.18-FF
1090 FORPX=0 TO20:X=PX/3.18-FF
1100 GOSUB1390:GOSUB1480
1110 IFPX=0 THEN GOSUB620:GOTO1130
1120 GOSUB630
1130 NEXTPX:NEXTPY
1140 REM -- TEKEN IN Y-RICHTING --
1150 FORPX=0 TO20:X=PX/3.18-FF
1160 FORPY=0 TO20:Y=PY/3.18-FF
1170 Z=Z(PX+21*PY)
1180 GOSUB1450:IFPY=0 THEN GOSUB620:GOTO1200
1190 GOSUB630
1200 NEXTPY:NEXTPX
1210 IFFF=0 THEN1240
1220 PX=10:PY=10:Z=Z(220):GOSUB1450
1230 GOSUB620:VE=.1:GOSUB630:GOTO1260
1240 PX=0:PY=0:Z=Z(0):GOSUB1450
1250 GOSUB620:VE=.1:GOSUB630
1260 GOSUB210:GOSUB100
1270 HO=4:VE=10:GOSUB110
1280 PRINT"[206]OG EEN FUNKTIE ([202]/[206]) ? ";
1290 GOSUB210:IFIN=74 THEN1030
1300 IFIN=78 THEN950
1310 GOTO1290
1320 REM -- FORMULES --
1330 ONFU GOTO1340,1350,1360,1370
1340 Z$="Z=SIN(X) * SIN(Y)":RETURN
1350 Z$="Z=COS(X) * SIN(2Y)":RETURN
1360 Z$="Z=SIN(X) + SIN(Y)":RETURN
1370 Z$="Z=SIN(2X) + COS(Y)":RETURN
1380 REM -- BEREKEN Z --
1390 ONFU GOTO1400,1410,1420,1430
1400 Z=SIN(X)*SIN(Y):GOTO1450
1410 Z=COS(X)*SIN(2*Y):GOTO1450
1420 Z=SIN(X)+SIN(Y):GOTO1450
1430 Z=SIN(2*X)+COS(Y)
1440 REM -- BEREKEN COORDINATEN --
1450 HO=.23+PX/27-PY/100
1460 VE=.85-PX/80-PY/40-Z/20:RETURN
1470 REM -- BEWAAR Z IN Z() --
1480 Z(T)=Z:T=T+1:RETURN
1490 REM -- INLEIDING --
1500 HO=9:VE=1:GOSUB110
1510 SR$="[218] = F([216],[217])":GOSUB150
1520 PRINT:PRINT
1530 PRINT"[196]IT PROGRAMMA MAAKT DE RUIMTELIJKE"
1540 PRINT"AFBEELDING VAN HET VLAK [218]. [196]E [216]-AS"
1550 PRINT"WIJST NAAR RECHTS , DE  [217]-AS WIJST"
1560 PRINT"NAAR ACHTER  EN DE [218]-AS WIJST NAAR"
1570 PRINT"BOVEN.":PRINT
1580 PRINT"[197]R ZIJN TWEE OPTIES:":PRINT
1590 PRINT"[200]ET EERSTE KWADRANT WORDT GETEKEND"
1600 PRINT"VOOR HET DOMEIN VAN 0 TOT 2 PI [210][193][196]"
1610 PRINT"= 0 TOT 360 GRADEN IN [216] EN [217].":PRINT
1620 PRINT"[197]R WORDEN VIER KWADRANTEN GETEKEND"
1630 PRINT"MET DE OORSPRONG IN HET MIDDEN, EN"
1640 PRINT"180 GRADEN IN ALLE RICHTINGEN.":PRINT
1650 PRINT"[201]EDER HOKJE IS 18 BIJ 18 GRADEN.":PRINT
1660 PRINT"    [212]IK OP EEN TOETS ";:GOSUB210:RETURN
1670 PRINT
1680 PRINT"[194]ESCHIKBAAR ZIJN DE FUNKTIES:":PRINT
1690 PRINT"1.  Z = SIN(X) * SIN(Y)":PRINT
1700 PRINT"2.  Z = COS(X) * SIN(2Y)":PRINT
1710 PRINT"3.  Z = SIN(X) + SIN(Y)":PRINT
1720 PRINT"4.  Z = SIN(2X) + COS(Y)":PRINT
1730 PRINT"    KIES EEN FUNKTIE : ";
1740 GOSUB210:IF(IN$<"1")OR(IN$>"4") THEN1740
1750 PRINTIN$:PRINT:FU=VAL(IN$):GOSUB1330
1760 PRINT"[193].  VIER KWADRANTEN":PRINT
1770 PRINT"[194].  ALLEEN EERSTE KWADRANT":PRINT
1780 PRINT"    KIES [193] OF [194]: ";
1790 GOSUB210:IF(IN<65)OR(IN>66) THEN1790
1800 FF=3.14:IFIN=66 THENFF=0
1810 PRINTZ$:PRINT
1820 PRINT"    [212]IK OP EEN TOETS ";
1830 GOSUB210:RETURN
1840 REM---------------------------------
32000 REM  CH.W.BREDERODE
32010 REM  VON BONNINGHAUSENLAAN 33
32020 REM  2161 ES  LISSE
32030 REM
32040 REM TROS-RADIO DD 911127
32050 REM DS-KULTUR
32060 REM -SPEZIAL 911211