//
//
//  EITMPLT.TXT
//  English-Italian Sample Templates for Power Translator 6.x
//
//


// *********************************************************************
// NOUN NOUN = NOUN
//
// Example: apartment building = palazzo
//
// SOURCE.1 = apartment; SOURCE.2 = building; TARGET.1 = palazzo
// *********************************************************************

// RULESET1
// Procedure = Top Traverse; Stage = Disambiguation; Key = SOURCE.2

<HasAttr Noun:"SOURCE.1" && Word == "SOURCE.1">
<HasAttr Noun:"SOURCE.2">
    ==> <1 SetAttr Noun>
        <2 SetAttr Noun>;


// RULESET2
// Procedure = Depth Traverse; Stage = Frame; Key = SOURCE.2

<IsAttr Noun:"SOURCE.1" && Word == "SOURCE.1">
<IsAttr Noun:"SOURCE.2">
    ==> <1 Delete>
        <2 Target.ChangeWord "TARGET.1">;


// *********************************************************************
// NOUN NOUN = NOUN DE NOUN
//
// Example: birth certificate==> certificato di nascita
//
// SOURCE.1 = birth; SOURCE.2 = certificate; TARGET.1 = certificato; TARGET.2 = nascita;
// *********************************************************************

// RULESET1
// Procedure = Top Traverse; Stage = Disambiguation; Key = SOURCE.2

<HasAttr Noun:"SOURCE.1">
<HasAttr Noun:"SOURCE.2">
    ==> <1 SetAttr Noun>
        <2 SetAttr Noun>;


// RULESET2
// Procedure = Depth Traverse; Stage = Frame; Key = SOURCE.2

<IsAttr Noun: "SOURCE.1">
<IsAttr Noun: "SOURCE.2">
    ==> <2 Target.ChangeWord "TARGET.1">
        AddTargetWord("di", Preposition)
        <1 Target.ChangeWord "TARGET.2">;


// *********************************************************************
// NOUN NOUN ==> NOUN ADJ
//
// Example: sea breeze ==> brezza marina
//
// SOURCE.1 = sea; SOURCE.2 = breeze; TARGET.1 = brisa; TARGET.2 = marino;
//
// Notice that the adjective has to go in the uninflected form
// *********************************************************************

// RULESET1
// Procedure = Top Traverse; Stage = Disambiguation; Key = SOURCE.2

<HasAttr Noun:"SOURCE.1">
<HasAttr Noun:"SOURCE.2">
    ==> <1 SetAttr Noun>
        <2 SetAttr Noun>;


// RULESET2
// Procedure = Depth Traverse; Stage = Frame; Key(s) =SOURCE.2, TARGET.1

<IsAttr Noun: "SOURCE.1">
<IsAttr Noun: "SOURCE.2">
    ==> <1 Delete>
        <2 Target.ChangeWord "TARGET.1">
        AddTargetWord("TARGET.2", Adjective);

<Target.IsAttr Noun: "TARGET.1">
<Target.IsAttr Adjective: "TARGET.2">
    ==> <1> <2 Target.AgreeWith = Node(1)> ;


// *********************************************************************
//
//  VERB FRAMES
//
// *********************************************************************


// *********************************************************************
// VERB  + PARTICLE ==> VERB
//
// Example: pick up ==> raccogliere
//
// SOURCE.1 = pick; SOURCE.2 = up; TARGET.1 = raccogliere
//
// "pick" Particle ("up")
//     ==> "raccogliere";
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Particle("SOURCE.2")
    ==> "TARGET.1";


// *********************************************************************
// VERB  + ADVERB ==> VERB
//
// Example: come back ==> ritornare
//
// SOURCE.1 = come; SOURCE.2 = back; TARGET.1 = ritornare
//
// "come" Adv ("back")
//     ==> "ritornare" Delete ("back");
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Adv("SOURCE.2")
    ==> "TARGET.1" Delete ("SOURCE.2");


// *********************************************************************
// VERB + DIRECT OBJECT ==> VERB
//
// Example: have fun ==> divertirsi
//
// SOURCE.1 = have; SOURCE.2 = fun; TARGET.1 = divertirsi
//
// "have" Obj (SX_Direct, Primary.Word=="fun")
//     ==> "divertirsi" Make (SX_Direct,SX_Direct,Primary.Target.Hidden=True);
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Obj(SX_Direct,Primary.Word=="SOURCE.2")
    ==> "TARGET.1" Make (SX_Direct,SX_Direct,Primary.Target.Hidden=True);


// *********************************************************************
// VERB  + PREPOSITIONAL OBJECT ==> VERB + DIRECT OBJECT
//
// Example: look for ==> cercare
//
// SOURCE.1 = look; SOURCE.2 = for; TARGET.1 = cercare;
//
// "look" Obj ("for")
//     ==> "cercare" Make ("for",SX_Direct);
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Obj("SOURCE.2")
    ==> "TARGET.1" Make("SOURCE.2",SX_Direct);


// *********************************************************************
// VERB  + PREPOSITIONAL OBJECT ==> VERB + PREPOSITIONAL OBJECT
//
// Example: depend on ==> dipendere da
//
// SOURCE.1 = depend; SOURCE.2 = on; TARGET.1 = dipendere TARGET.2 = da;
//
// "depend" Obj ("on")
//     ==> "dipendere" Make ("on","da");
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Obj("SOURCE.2")
    ==> "TARGET.1" Make("SOURCE.2","TARGET.2");


// *********************************************************************
// VERB  + PREDICATE ADJECTIVE ==> VERB
//
// Example: become angry ==> arrabbiarsi
//
// SOURCE.1 = become; SOURCE.2 = angry; TARGET.1 = arrabbiarsi
//
// "become" Obj (SX_PredicateAdjective, Primary.IsAttr Adjective:"angry")
//     ==> "arrabbiarsi" Delete (SX_PredicateAdjective);
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Obj(SX_PredicateAdjective, Primary.IsAttr Adjective:"SOURCE.2")
    ==> "TARGET.1" Delete (SX_PredicateAdjective);