//
//
//  EGTMPLT.TXT
//  English-German Sample Templates for Power Translator 6.x
//
//


// *********************************************************************
// NOUN NOUN ==> NOUN
//
// Example: tin can ==> Blechdose
//
// SOURCE.1 = tin; SOURCE.2 = can; TARGET.1 = Blechdose
// *********************************************************************

// RULESET1
// Procedure = Top Traverse; Stage = Disambiguation; Key = SOURCE.2

<HasAttr Noun:"SOURCE.1" && Word == "SOURCE.1">
<HasAttr Noun:"SOURCE.2">
    ==> <1 SetAttr Noun:"SOURCE.1">
        <2 SetAttr Noun:"SOURCE.2">;


// RULESET2
// Procedure = Depth Traverse; Stage = Frame; Key = SOURCE.2

<IsAttr Noun:"SOURCE.1" && Word == "SOURCE.1">
<IsAttr Noun:"SOURCE.2">
    ==> <1 Delete>
        <2 Target.ChangeWord "TARGET.1">;


// *********************************************************************
// ADJECTIVE NOUN ==> NOUN
//
// Example: Economic Commission ==>  Wirtschaftskommission
//
// SOURCE.1 = economic; SOURCE.2 = commission;
// TARGET.1 =  Wirtschaftskommission
// *********************************************************************

// RULESET1
// Procedure = Top Traverse; Stage = Disambiguation; Key = SOURCE.2

<HasAttr Adjective:"SOURCE.1">
<HasAttr Noun:"SOURCE.2">
    ==> <1 SetAttr Adjective:"SOURCE.1">
        <2 SetAttr Noun:"SOURCE.2">;


// RULESET2
// Procedure = Depth Traverse; Stage = Frame; Key = SOURCE.2

<NodeType NounBar>
    /
    <NodeType AdjectivePhrase && Primary.IsAttr Adjective:"SOURCE.1">
    <NodeType NounBar>
        /
        <NodeType NounTheta> / <IsAttr Noun:"SOURCE.2"> \
        \
    \
    ==> <1>
            /
            <1.1 Primary.Target.Hidden = True>
            <1.2>
                /
                <1.2.1> / <1.2.1.1 Target.ChangeWord "TARGET.1"> \
                \
            \;


// ***********************************************************************
//
//  VERB FRAMES
//
// ***********************************************************************


// *********************************************************************
// VERB + PARTICLE + DIRECT OBJECT ==> VERB + DIRECT OBJECT
//
// Example: make s.th. up ==> etw. erfinden
//
// SOURCE.1 = make; SOURCE.2 = up; TARGET.1 =erfinden
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Particle("SOURCE.2") Obj(SX_Direct)       // invent
    ==> "TARGET.1";


// *********************************************************************
// VERB + DIRECT OBJECT ==> VERB + DIRECT OBJECT
//
// Example: achieve an end ==> ein Ziel erreichen
//
// SOURCE.1 = achieve; SOURCE.2 = end;
// TARGET.1 = erreichen; TARGET.2 = Ziel
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Obj(SX_Direct,Primary.IsAttr Noun:"SOURCE.2")
    ==> "TARGET.1" Make(SX_Direct,SX_Direct,Primary.Target.ChangeWord "TARGET.2");


// *********************************************************************
// VERB + DIRECT OBJECT ==> VERB + PREPOSITIONAL OBJECT
//
// Example: access s.th. ==> auf etw. (+Acc) zugreifen
//
// SOURCE.1 = access; TARGET.1 = zugreifen; TARGET.2 = auf
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Obj(SX_Direct)
    ==> "TARGET.1" Make(SX_Direct, "TARGET.2", Primary.Target.Case = CASE_Accusative);


// *********************************************************************
// VERB  + PARTICLE ==> VERB
//
// Example: make up ==> sich versöhnen
//
// SOURCE.1 = make; SOURCE.2 = up; TARGET.1 = sich versöhnen
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Particle("SOURCE.2")
    ==> "TARGET.1";


// *********************************************************************
// VERB  + PREPOSITIONAL OBJECT ==> VERB + PREPOSITIONAL OBJECT
//
// Example: look for ==> suchen nach
//
// SOURCE.1 = look; SOURCE.2 = for; TARGET.1 = suchen; TARGET.2 = nach
// *********************************************************************

// RULESET1
// Procedure = Verb Frame; Stage = Frame; Key = SOURCE.1

"SOURCE.1" Obj("SOURCE.2")
    ==> "TARGET.1" Make("TARGET.1", "TARGET.2");