10 REM PUZZLEWORD==============C64
20 REM (P) COMMODORE DISC
30 REM ===========================
40 REM (C) PETER BERGEN       V3.5
50 REM (V) A.MITTELMEYER      V2.0
60 REM
70 REM BASIC V2.0
80 REM C64
90 REM ===========================
91 IFPEEK(49154)=174THEN100
92 SYS57812"SYSMC",8,0:POKE780,0
93 POKE781,254:POKE782,191:SYS65493
100 AT=49152:EF=49337:GOSUB 1590
110 DATA"AUTOBAHN","SCHEITEL","TABLETTE","HAARNETZ","FREIBIER"
120 DATA"TAGEBUCH","WILDBRET","JOYSTICK","COMPUTER","PUTZFRAU"
130 DATA"TRENNUNG","DREIZEHN","FOXTROTT","NARZISSE","GASTHAUS"
140 DATA"FARBFOTO","SCHATTEN","OBSTWEIN","BADETUCH","HOCHZEIT"
150 DATA"PARANUSS","WERKZEUG","ABENDROT","LIEBELEI","RECORDER"
160 DATA"KUHSTALL","SENFTUBE","MASCHINE","POSTBOTE","STEHPULT"
170 DATA"HOLZKOPF","CLUBRAUM","WITZBOLD","HIMBEERE","FLUGZEUG"
180 A=RND(-TI):DIMS%(5):DIMW$(3):DIMX%(3,8):DIMY%(8):HS=1000
190 V=15:H=19:K=1643:RU=1:FORA=1TO4:S%(A)=0:NEXT
200 POKE53281,0:PRINTCHR$(147);
210 GOSUB1250:GOSUB1090:GOSUB1280:GOSUB770:SP=1:GOSUB890
220 POKE56322,224:REM STEUERUNG
230 JO=PEEK(56320):IFJO=119THENGOSUB340:GOSUB290
240 IFJO=123THENGOSUB360:GOSUB290
250 IFJO=126THENGOSUB380:GOSUB290
260 IFJO=125THENGOSUB400:GOSUB290
270 IFJO=111THENGOSUB1530:GOSUB430:GOSUB1540
280 GOTO230
290 S%(SP)=S%(SP)+1:GOSUB320:IFS%(SP)>999THENGOTO1420
300 RETURN
310 REM PUNKTANZEIGE
320 SYSAT,6,SP*2+13:PRINTYE$RIGHT$(" "+STR$(S%(SP)),3);:RETURN
330 REM KURSORVERSCHIEBUNG
340 IFH=27THENS%(SP)=S%(SP)-1:RETURN
350 GOSUB1070:H=H+1:GOSUB1060:K=K+1:GOSUB630:GOSUB1070:H=H+1:K=K+1:GOSUB1060:RETURN
360 IFH=11THENS%(SP)=S%(SP)-1:RETURN
370 GOSUB1070:H=H-1:GOSUB1060:K=K-1:GOSUB630:GOSUB1070:H=H-1:K=K-1:GOSUB1060:RETURN
380 IFV=7THENS%(SP)=S%(SP)-1:RETURN
390 GOSUB1070:V=V-1:GOSUB1060:K=K-40:GOSUB700:GOSUB1070:V=V-1:K=K-40:GOSUB1060:RETURN
400 IFV=23THENS%(SP)=S%(SP)-1:RETURN
410 GOSUB1070:V=V+1:GOSUB1060:K=K+40:GOSUB700:GOSUB1070:V=V+1:K=K+40:GOSUB1060:RETURN
420 REM AUSWERTUNG
430 B=1354
440 FORA=1TO8:B=B+2:Y%(A)=PEEK(B)+64:NEXT:GOSUB560
450 IFW>0THENGOSUB550:GOSUB520:RETURN
460 B=B+64:IFB<1930THENGOTO440
470 B=1276
480 FORA=1TO8:B=B+80:Y%(A)=PEEK(B)+64:NEXT:GOSUB560
490 IFW>0THENGOSUB550:GOSUB520:RETURN
500 B=B-638:IFB<1294THENGOTO480
510 RETURN
520 GOSUB880:GOSUB870
530 SP=SP+1:IFSP>SBTHENSP=1:RU=RU+1:IFRU>5THENGOTO1420
540 GOSUB890:GOSUB880:RETURN
550 GOSUB1010:GOSUB920:GOSUB990:RETURN
560 W=0:FORD=1TO3:WZ=0:FORA=1TO8
570 IFY%(A)=X%(D,A)THENWZ=WZ+1
580 NEXT:IFWZ>7THENW=D
590 NEXT:RETURN
600 REM NEUER BUCHSTABE
610 GOSUB1050:GOSUB840:GOSUB1040:RETURN
620 REM RAND VERTIKAL
630 IFV=7THENB=K+40:D=PEEK(K+40):GOSUB610:RETURN
640 IFV=23THENB=K-40:D=PEEK(K-40):GOSUB610:RETURN
650 REM BUCHSTABENTAUSCH VERTIKAL
660 W1=PEEK(K-40):W2=PEEK(K+40)
670 B=K-40:D=W1:GOSUB1050:B=K+40:D=W2:GOSUB1050:B=K-40:GOSUB1040:B=K+40:D=W1:GOSUB1040
680 RETURN
690 REM RAND HORIZONTAL
700 IFH=11THENB=K+1:D=PEEK(K+1):GOSUB610:RETURN
710 IFH=27THENB=K-1:D=PEEK(K-1):GOSUB610:RETURN
720 REM BUCHSTABENTAUSCH HORIZONTAL
730 W1=PEEK(K-1):W2=PEEK(K+1)
740 B=K-1:D=W1:GOSUB1050:B=K+1:D=W2:GOSUB1050:B=K-1:GOSUB1040:B=K+1:D=W1:GOSUB1040
750 RETURN
760 REM SPIELFELD
770 GOSUB830:POKE646,6:B=1354
780 FORA=1TO8:B=B+2:GOSUB840:GOSUB1050:GOSUB1040:NEXT:B=B+64
790 IFB<1930THENGOTO780
800 FORA=10TO22:SYSAT,1,A:PRINTYE$RN$LEFT$(BL$,9);:SYSAT,29,A:PRINTLEFT$(BL$,10)RF$;:NEXT
810 GOSUB860:GOSUB880:SYSAT,30,15:PRINTRN$"AUSWAHL:";
820 FORW=1TO3:GOSUB920:GOSUB990:NEXT:GOSUB1060:RETURN
830 POKE646,2:FORA=7TO23:SYSAT,11,A:PRINT"*****************";:NEXT:RETURN
840 LETD=INT(RND(1)*26)+1:RETURN
850 REM ANZEIGEN
860 GOSUB900:FORSP=1TO4:GOSUB320:NEXT
870 FORA=1TO4:SYSAT,2,A*2+13:PRINTYE$RN$;:PRINT;A;C1$".:":NEXT:RETURN
880 SYSAT,30,12:PRINTYE$+RN$+"RUNDE:";:SYSAT,36,12:PRINTYE$RF$;
881 PRINTRIGHT$(STR$(RU),2):RETURN
890 SYSAT,2,SP*2+13:PRINTYE$;:PRINT;SP;C1$".":RETURN
900 SYSAT,2,12:PRINTYE$;:PRINT;RN$"HS:":SYSAT,6,12:PRINTYE$;
901 PRINTRIGHT$(" "+STR$(HS),3):RETURN
910 REM WORTWAHL
920 RESTORE:Z=INT(RND(1)*35)+1:FORA=1TOZ:READR$:NEXT:GOTO980
930 FORA=1TO8:V$=MID$(W$(W),A,1):X%(W,A)=ASC(V$):NEXT:RETURN
940 REM WORT-UEBERPRUEFUNG
950 WX=0:FORA=1TO3:IFA=WTHENGOTO970
960 IFW$(A)=W$(W)THENWX=1
970 NEXT:IFWX=1THEN920
971 GOTO930
980 IFR$=W$(W)THEN920
981 W$(W)=R$:GOTO950
990 FORL=1TO6:GOSUB1020:NEXT:RETURN
1000 REM WORT-DARSTELLUNG
1010 FORL=6TO1STEP-1:GOSUB1020:NEXT:RETURN
1020 POKE646,15:SYSAT,30,W*2+15:PRINTRN$;:PRINT;W$(W);RF$:FORP=1TO50:NEXT:RETURN
1030 REM BUCHSTABEN-DARSTELLUNG
1040 FORL=14TO110STEP16:POKEB+54272,15:POKEB,D:NEXT:RETURN
1050 FORL=126TO14STEP-16:POKEB+54272,12:POKEB,D:NEXT:RETURN
1060 POKE646,7:SYSAT,H,V:PRINT"*";:RETURN
1070 POKE646,2:SYSAT,H,V:PRINT"*";:RETURN
1080 REM UEBERSCHRIFT
1090 SYSAT,0,1:PRINTRF$" "Z1$ZR$RN$" "RF$" "RN$" "RF$" "RN$" ";
1100 PRINTRF$Z1$Z1$" "RN$" "RF$Z1$Z1$" "RN$" "RF$" "RN$B3$RF$" "Z1$Z1$RN$" "RF$" ";
1110 PRINTRN$B2$RF$" "RN$" "RF$ZT$Z1$ZR$RN$" "RF$" "Z1$ZR$RN$" "RF$" "Z1$ZR$
1120 SYSAT,0,2:PRINTRF$" "RN$" "RF$" "RN$" ";
1130 PRINTRF$" "RN$" "RF$" "RN$B2$RF$ZT$RN$ZT$B2$RF$ZT$;
1140 PRINTRN$ZT$" "RF$" "RN$B3$RF$" "RN$B3$RF$" "RN$B2$RF$" ";
1150 PRINTRN$" "RF$" "RN$" "RF$" "RN$" "RF$" "RN$" "RF$" "RN$" "RF$" "RN$" "RF$" "
1160 SYSAT,0,3:PRINTRF$" "Z1$RN$ZT$" "RF$" "RN$" ";
1170 PRINTRF$+" "+RN$+" "+ZB$+RF$+ZB$+RN$+B2$+ZB$+RF$+ZB$+RN$+" ";
1180 PRINT" "RF$" "RN$B3$RF$" "Z1$RN$B2$RF$" "Z0$RN$Z0$RF$" "RN$" "RF$" ";
1190 PRINTRN$" "RF$" "RN$" "RF$" "ZQ$RN$Z0$" "RF$" "RN$" "RF$" "
1200 SYSAT,0,4:PRINTRF$" "RN$B3$RF$ZQ$RN$;
1210 PRINTZ1$RF$ZB$RN$" "RF$" "RN$Z1$Z1$" "RF$" ";
1220 PRINTRN$Z1$Z1$" "RF$" "RN$Z1$Z1$" "RF$" "RN$Z1$Z1$" "ZR$RF$ZB$ZQ$RN$ZT$" "RF$ZQ$;
1230 PRINTRN$Z1$RF$ZB$RN$" "RF$" "RN$" "RF$" "RN$" "RF$" "RN$Z1$RF$
1240 RETURN
1250 POKE646,6:FORA=0TO2:SYSAT,0,A:PRINTRN$BL$;:NEXT
1260 RETURN
1270 REM ANLEITUNG
1280 SYSAT,1,8:PRINTWH$"VERSUCHEN SIE DURCH VERSCHIEBEN DES"
1290 PRINT"GELBEN STERNCHENS (JOYSTICK PORT 2)"
1300 PRINT"MIT SO WENIG ZUEGEN WIE MOEGLICH EINES"
1310 PRINT"DER 3 AUSWAHLWOERTER ZU BILDEN."
1320 PRINT"STEHT DAS STERNCHEN ZWISCHEN 2 BUCHSTA-"
1330 PRINT"BEN, WERDEN DIESE VERTAUSCHT; STEHT ES"
1340 PRINT"AM SPIELFELDRAND, ENTSTEHT NEBEN DEM"
1350 PRINT"STERNCHEN EIN NEUER BUCHSTABE."
1360 PRINT"WURDE EIN WORT GEBILDET, ERFOLGT DURCH"
1370 PRINT">FIRE< EIN AUSTAUSCH IN DER WORTAUSWAHL,"
1380 PRINT"SOWIE GGF. DER SPIELERWECHSEL."
1390 PRINT"DAS SPIEL ENDET NACH 5 RUNDEN, ODER WENN"
1400 PRINT"MEHR ALS 999 ZUEGE BENOETIGT WURDEN."
1410 GOSUB1510:POKE198,0:PRINTC4$"WIEVIEL SPIELER";
1412 INPUTSB:PRINTCHR$(147);:GOSUB1250:GOTO1090
1420 GOSUB1520:FORA=1TOSB
1430 IFS%(A)<HSTHENHS=S%(A)
1440 NEXT:GOSUB900
1450 B=17:GOSUB830:FORA=8TO22:SYSAT,B,A:PRINTLG$"ENDE";:IFB=17THENB=18:GOTO1460
1451 B=17
1460 NEXT:POKE646,2:SYSAT,17,16:PRINT"****"C4$C4$LEFT$(QL$,4)"****";
1470 SYSAT,12,17:PRINTLG$">FIRE<=NEUSTART";
1480 IFPEEK(65320)=111THENGOTO190
1490 GOTO1480
1500 REM SOUNDS
1510 RETURN
1520 RETURN
1530 RETURN
1540 RETURN
1590 REM NACHSPANN ===============
1600 REM * FARBCODES/STEUERCODES *
1610 WH$=CHR$(005):C4$=CHR$(017)
1620 RN$=CHR$(018):RF$=CHR$(146)
1630 LG$=CHR$(153):C1$=CHR$(157)
1640 YE$=CHR$(158)
1650 REM *** ZEICHENSATZ/GRAPHIK *
1660 Z0$=CHR$(161):Z1$=CHR$(162)
1670 ZB$=CHR$(172):ZQ$=CHR$(187)
1680 ZR$=CHR$(188):ZT$=CHR$(190)
1690 REM ********* ZEICHENFOLGEN *
1700 B2$=" "+" ":B3$=B2$+" "
1710 FOR Q=1 TO 40
1720 QL$=QL$+C1$:BL$=BL$+" "
1730 NEXT Q
1740 RETURN
1750 REM =========================