10 GOSUB 5000
18 REM ----------  START  ----------
19 REM
20 PRINT "DIESES PROGRAMM ZEIGT,"
30 PRINT "WIE SPRITES FUNKTIONIEREN."
40 PRINT "UND ES ZEIGT DABEI AUCH JEWEILS"
50 PRINT "DIE AUFGERUFENEN PROGRAMMZEILEN."
55 PRINT" VC = 53248"
60 PRINT:PRINT
70 PRINT "FERTIG?"
80 GET A$:IF A$="" THEN 80
90 PRINT C$D$D$D$D$D$
95 REM
96 REM ------ LESEN/AUSFUEHREN -----
97 REM
100 FOR N=1 TO 17
110 READ X$,Y$
120 PRINTB$X$
130 PRINTY$
140 PRINT:PRINT G$" CONT"
145 PRINTB$L$:PRINT"TIPPE RETURN-";
150 PRINT"TASTE ZUR FORTSETZUNG."
160 PRINTL$G$U$U$U$U$U$U$U$U$U$U$
166 REM
167 REM NAECHSTE ZEILE HOLT EINE RETURN-
168 REM TASTE IN DEN EINGABEPUFFER
169 REM
170 POKE 198,1 : POKE 631,13
180 STOP
190 PRINTD$D$D$D$ : NEXT N
195 PRINTB$"ENDE DES BEISPIELS." : END
197 REM
198 REM ------- DATEN/BEFEHLE --------
199 REM
200 DATA"POKE VC+21,1"
210 DATA"<SPRITE 0 EINSCHALTEN>"
220 DATA"POKE VC,24 : POKE VC+1,50"
230 DATA"<BEWEGEN NACH X=24 UND Y=50>"
240 DATA"POKE VC+39,7"
250 DATA"<SPRITEFARBE GELB WAEHLEN>"
260 DATA"POKE 2040,255"
270 DATA"<SPRITE-ZEIGER SETZEN>"
280 DATA"POKE VC+29,1"
290 DATA"<HORIZONTAL ERWEITERN>"
300 DATA"POKE VC+23,1"
310 DATA"<VERTIKAL ERWEITERN>"
320 DATA"FOR C=24 TO 255:POKE VC,C:NEXT"
330 DATA"<SPRITE BEWEGEN>"
340 DATA"POKE VC+16,1 : POKE VC,40"
350 DATA"<BEWEGEN JENSEITS X=255>"
360 DATA"FOR C=50TO208:POKEVC+1,C:NEXT"
370 DATA"<SPRITE VERTIKAL BEWEGEN>"
380 DATA"POKE VC+16,0 : POKE VC,150"
390 DATA"<ZURUECK , LINKS VON X=255>"
400 DATA"POKE VC+27,1"
410 DATA"<HINTER DEN VIDEO-TEXT>"
420 DATA"POKE VC+37,2"
430 DATA"ROT WAEHLEN ALS ZUSATZFARBE #1>"
440 DATA"POKE VC+38,6"
450 DATA"<BLAU WAEHLEN ALS ZUSATZFARBE #2>"
460 DATA"POKE VC+28,1"
470 DATA"<SCHALTEN AUF MEHRFARBIG>"
480 DATA"POKE VC+29,0"
490 DATA"<SCHRUMPFEN HORIZONTAL>"
500 DATA"POKE VC+23,0"
510 DATA"<SCHRUMPFEN VERTIKAL>"
520 DATA"POKE VC+21,0"
530 DATA"<SPRITE AUSSCHALTEN>"
4997 REM
4998 REM -----  SPRITE AUFSTELLEN -----
4999 REM
5000 VA=1024
5010 VC=53248
5040 L$="==================================="
5050 C$=CHR$(147)
5060 B$=CHR$(5)
5070 G$=CHR$(155)
5080 U$=CHR$(145)
5090 D$=CHR$(17)
5100 POKE 53280,12: POKE 53281,15
5110 PRINT B$C$;
5150 FOR N=16320 TO 16331
5160 POKE N,255 : POKE N+111,255
5170 NEXT N
5180 FOR N=16332 TO 16368 STEP3
5190 POKE N,245:POKE N+1,66:POKE N+2,175
5195 NEXT N
5200 RETURN