0 REM
1 REM   *****************
2 REM   *               *
3 REM   *  DEZ-HEX-BIN  *
4 REM   *               *
5 REM   *****************
6 REM
7 REM     DIETER JANSKY
8 REM       WUERZBURG
9 REM
10 POKE53280,0:POKE53281,0:POKE788,52
20 PRINT"[147][142][158]";:B$="                                      "
30 PRINTB$"   UMRECHNUNG -- DEZ -- HEX -- BIN    "B$"[155]"
40 PRINT"   INPUT DEZIMAL.................1"
42 PRINT"   INPUT HEXADEZIMAL.............2"
44 PRINT"   INPUT BINAER..................3"
45 PRINT"   ENDE  ........................4"
50 GETQ$:IFQ$<"1"ORQ$>"4"THEN50
55 IFQ$="4"THENPRINT"[147]":PRINT"":END
60 ONVAL(Q$)GOTO70,80,90
70 PRINT"[147]"B$"  DEZIMAL -- HEXADEZIMAL -- BINAER    "B$
72 CLR:PRINT:INPUT" ";D1:IFD1>16^4-1THEN72
73 IFD1=<0THENRUN
75 PRINTSPC(14)"[145]";:GOSUB400:PRINTSPC(11);:GOSUB300:
78 GOTO72
80 PRINT"[147]"B$"  HEXADEZIMAL -- DEZIMAL -- BINAER    "B$
82 CLR:PRINT:INPUT" ";H$:L=LEN(H$):IFL>4THEN82
83 IFH$<"0"THENRUN
84 PRINTSPC(17)"[145]";:GOSUB100:GOSUB300
88 GOTO82
90 PRINT"[147]"B$"   BINAER  -- DEZIMAL -- HEXADEZIMAL  "B$
92 CLR:PRINT:INPUT" ";B$:IFB$<"0"THENRUN
93 IFLEN(B$)<>8THEN92
94 PRINTSPC(14)"[145]";:GOSUB200:PRINTTAB(26);:GOSUB400
98 GOTO92
100 REM * HEX > DEZ *
120 D=0:FORQ=LTO1STEP-1:C$=MID$(H$,Q,1)
130 IFASC(C$)>47ANDASC(C$)<58THENR=ASC(C$)-48:GOTO180
140 R=ASC(C$)-55
180 D=D+R*16^(L-Q):NEXT:PRINTD,:D1=D:RETURN
200 REM * BIN > DEZ *
220 D=0:FORQ=8TO1STEP-1
230 D=D+VAL(MID$(B$,9-Q,1))*2^(Q-1)
260 NEXT:PRINTD;:D1=D:RETURN
270 REM
300 REM * DEZ > BIN *
310 D=D1:IFD>255THENRETURN
320 B$="":FORQ=8TO1STEP-1
330 IFD<2^(Q-1)THENB$=B$+"0":GOTO350
340 D=D-2^(Q-1):B$=B$+"1"
350 NEXT:PRINTB$;:RETURN
360 REM
400 REM * DEZ > HEX *
420 D=D1:H$="":FORQ=4TO1STEP-1
430 E=INT(D/16^(Q-1))
440 IFE>9THENH$=H$+CHR$(E+55):GOTO470
450 H$=H$+CHR$(E+48)
470 D=D-E*16^(Q-1):NEXT:PRINTH$;:RETURN