0 REM--- (C) ANSSI HAKKARAINEN 1986 ---
1 REM          VEIKKAUSRIVIT
2 REM
3 POKE251,0:GOSUB1000
4 CC=RND(-TI)
8 DIME(3,13),PE(13),Q(14)
10 POKE53280,6:POKE53281,6
11 PRINT"[147]   ****  [214]EIKKAUSRIVIEN ARVONTA  ****"
12 PRINT:PRINT"      ([195]) [193]NSSI [200]AKKARAINEN 1986"
15 GOTO230
18 REM -- RIVIEN ARVONTA --
20 CLR:INPUT"[205]ONTAKO SARAKETTA (MAX 500)";SA$:IFVAL(SA$)>500ORVAL(SA$)<1THEN20
25 SA=VAL(SA$):DIMPR$(SA),L$(SA),O(SA),E(3,13),PE(13),Q(14)
30 PRINT"[211]E MAKSAA"SA/2"MARKKAA":M=.99
40 FORI=1TO13
50 PRINT"[203][207][200][196][197]"I
60 INPUT"[217]KKOSELLE %  ";Y$
70 INPUT"[210]ISTILLE %   ";R$
80 INPUT"[203]AKKOSELLE % ";K$
90 Y=VAL(Y$):R=VAL(R$):K=VAL(K$)
95 IFY+R+K<>100THENGOSUB360:GOTO50
100 E(1,I)=Y:E(2,I)=R:E(3,I)=K
110 PRINT"":NEXT
111 PRINT"[207]DOTA HETKI...."
120 FORI=1TOSA
125 FORT=1TO13
130 Z=RND(0)+M
131 Y=E(1,T)/100:R=E(2,T)/100
140 IFZ<Y+1ANDY>0THENPE(T)=1:GOTO170
150 IFZ<Y+R+1ANDR>0THENPE(T)=2:GOTO170
160 PE(T)=3
170 PE$=STR$(PE(T)):PR$(I)=PR$(I)+PE$:NEXT
171 IFI>1THENGOSUB400
172 NEXT
175 FORT=1TOSA
180 FORI=1TO26
190 IFMID$(PR$(T),I,1)="1"THENA$=A$+"1"
192 IFMID$(PR$(T),I,1)="2"THENA$=A$+"X"
194 IFMID$(PR$(T),I,1)="3"THENA$=A$+"2"
200 NEXT
210 L$(T)=A$:A$=""
220 NEXT
222 GOSUB300
225 PRINT"[147]"
230 PRINT:PRINT:PRINT"1 [210]IVIEN ARVONTA"
235 PRINT"2 [204]ATAA RIVIT"
240 PRINT"3 [212]ALLETA RIVIT"
250 PRINT"4 [212]ARKASTA RIVIT"
255 PRINT"5 [212]ULOSTA RIVIT"
260 PRINT"6 [204]OPETUS"
261 GETG$:IFG$=""THEN261
265 G=VAL(G$):P=0
270 ONGGOTO20,505,450,600,750,285
280 GOTO261
285 END
300 REM -- AANIMERKKI --
305 FORI=54272TO54296:POKEI,0:NEXT
310 POKE54296,15:POKE54277,44:POKE54278,44:POKE54276,33
320 POKE54273,25:POKE54272,177:FORI=1TO100:NEXT
321 POKE54273,45:POKE54272,198:FORI=1TO200:NEXT
322 POKE54273,30:POKE54272,141:FORI=1TO200:NEXT
340 FORI=54272TO54296:POKEI,0:NEXT
350 RETURN
360 FORPY=54272TO54296:POKEPY,0:NEXT
365 POKE54296,15:POKE54277,44:POKE54278,166:POKE54276,33
370 POKE54273,5:POKE54272,5:FORPY=1TO100:NEXT
380 FORPY=54272TO54296:POKEPY,0:NEXT
390 RETURN
400 FORJ=1TOI-1:IFPR$(J)=PR$(I)THENI=I-1
405 NEXT
410 RETURN
420 REM -- TIEDOSTON TALLETUS --
450 INPUT"[212]ALLETETTAVAN TIEDOSTON NIMI";FI$
460 OPEN1,8,1,FI$+".VK"
465 PRINT#1,SA$
470 FORI=1TOSA
480 PRINT#1,L$(I)
481 GETG$:IFG$="[136]"THENWAIT631,199
490 NEXT
495 GOSUB900:GOTO791
501 REM -- TIEDOSTON LATAUS --
505 CLR
510 INPUT"[204]ADATTAVAN TIEDOSTON NIMI";FI$
520 OPEN1,8,0,FI$+".VK"
530 INPUT#1,SA$
535 SA=VAL(SA$):IFSA=0THEN552
536 DIML$(SA),O(SA),Q(14)
540 FORI=1TOSA:INPUT#1,L$(I)
550 NEXT
552 GOSUB900:GOTO791
590 REM -- RIVIEN TARKASTUS --
600 PRINT"[147]         [210]IVIEN TARKASTUS"
605 IFPEEK(251)=1THENINPUT"[212]ULOSTUS MYOS PRINTTERILLE (K/E)  K[157][157][157]";CK$
606 IFCK$="K"THENP=1
610 INPUT"[211]YOTA OIKEA RIVI";OI$
620 IFLEN(OI$)<>13THEN610
621 PRINT"[207]DOTA HETKI...."
622 PRINT
630 FORT=1TOSA
631 IFLEN(L$(T))<>13THENQ(0)=Q(0)-1
635 FORI=1TO13
640 IFMID$(L$(T),I,1)=MID$(OI$,I,1)THENO=O+1
645 NEXT
650 O(T)=O
660 O=0:NEXT
670 FORI=1TOSA
675 FORT=0TO13
680 IFO(I)=TTHENQ(T)=Q(T)+1
690 NEXT:NEXT
695 IFP=1THENOPEN4,4
700 FORI=13TO0STEP-1
705 PRINTI
710 PRINT"[145]OIKEIN"Q(I)" KPL"
711 IFP=1THENPRINT#4,I" OIKEIN"Q(I)" KPL"
715 Q(I)=0
720 NEXT
722 IFP=1THENPRINT#4,CHR$(13)CHR$(13):CLOSE4
730 PRINT"   PAINA RETURN   "
740 GETG$:IFG$=CHR$(13)THEN10
741 GOTO740
742 REM -- RIVIEN TULOSTUS --
750 IFPEEK(251)=1THENINPUT"[212]ULOSTUS PRINTTERILLE (K/E)  K[157][157][157]";CX$
760 IFCX$="K"THEN800
770 FORI=1TOSA
780 PRINTL$(I)"       ";
781 GETG$:IFG$="[136]"THENGOSUB860
790 NEXT
791 PRINT:PRINT"   PAINA RETURN   "
792 GETG$:IFG$=CHR$(13)THEN10
795 GOTO792
800 OPEN4,4
810 FORI=1TOSA
820 PRINT#4,L$(I)"       ";
830 NEXT
840 CMD4
850 PRINT#4:CLOSE4:GOTO791
860 GETG$:IFG$="[136]"THENRETURN
865 GOTO860
895 REM -- LEVYVIRHEEN TUTKIMINEN --
900 CLOSE1:OPEN15,8,15:INPUT#15,E1$,E2$,E3$,E4$
905 IFE2$="OK"THENPRINT"OK.":GOTO920
910 PRINT""E1$","E2$","E3$;E4$
920 CLOSE15:RETURN
1000 POKE53280,6:POKE53281,6
1010 INPUT"[147][203]AYTETAANKO PRINTTERIA (K/E)  K[157][157][157]";KA$
1020 IFKA$="K"THENPOKE251,1
1030 RETURN