Content Linking Component

The Content Linking component manages a list of URLs so that you can treat the pages in your Web site like the pages in a book. You can use the functionality of the Content Linking component to automatically generate and update tables of contents, and navigational links to previous and following Web pages. This is ideal for applications such as online newspapers and forum message listings.

The Content Linking component references a Content Linking List file that contains the list of the linked Web pages. This list is stored on the Web server.

File Names

Nextlink.dll	The Content Linking component.
Content Linking List	A text file that contains a list of Web pages in the order in which they should be displayed. This file must be available on a Web server virtual path.

Syntax

Set NextLink = Server.CreateObject("MSWC.Nextlink")

Parameters

NextLink

Specifies the name of the object created by the call to Server.CreateObject.

Registry Entries

None.

Methods

GetListCount	Counts the number of items linked in the Content Linking List file.
GetNextURL	Gets the URL of the next page listed in the Content Linking List file.
GetPreviousDescription	Gets the description line of the previous page listed in the Content Linking List file.
GetListIndex	Returns the index of the current page in the Content Linking List file.
GetNthDescription	Gets the description of the Nth page listed in the Content Linking List file.
GetPreviousURL	Gets the URL of the previous pages listed in the Content Linking List file.
GetNextDescription	Gets the description of the next page listed in the Content Linking List file.
GetNthURL	Gets the URL of the Nth page listed in the Content Linking List file.

Example

The following example builds a table of contents.

<ol>
<%  Set NextLink = Server.CreateObject ("MSWC.NextLink") %>  
<%  count = NextLink.GetListCount ("/data/nextlink.txt") %> 
<%  I = 1 %> 

<ul>
<%  Do While (I <= count)  %>  
<li><a href=" <%= NextLink.GetNthURL ("/data/nextlink.txt", I)  %>  "> 
<%= NextLink.GetNthDescription ("/data/nextlink.txt", I) %>  </a> 
<%  I = (I + 1)  %>  
<%  Loop  %>  

</ul>
</ol>
 

The following script adds the next- and previous-page buttons to an HTML file.

<%  Set NextLink = Server.CreateObject ("MSWC.NextLink") %>  
<%  If (NextLink.GetListIndex ("/data/nextlink.txt") > 1) Then %> 

<a href="  <%= NextLink.GetPreviousURL ("/data/nextlink.txt")  %>  ">

Previous Page</a> 
<%  End If  %>  
<a href="  <%= NextLink.GetNextURL ("/data/nextlink.txt")  %>  ">Next Page</a>