Version 1.0 Class
Attribute VB_Name = "Application"
Attribute VB_Creatable = True
Attribute VB_Exposed = True
Attribute VB_Description = "Create Directory Dialog Box"
Option Explicit
Private mnuitCreateDirectory As Object

' Initialize the add-in.
Public Sub ConnectAddIn(Application As Object)
    ' Create a new MenuLine object.
    Set mnuitCreateDirectory = Application. _
        AddInMenu.MenuItems.Add("Create Directory")
    ' Associate the MenuLine AfterClick event
    ' with this object.
    mnuitCreateDirectory.ConnectEvents Me
    ' Create a new instance of an object
    ' to receive file control events.
    Dim objFileControl As New clsFileControl
    ' Connect the VB FileControlEvents to the object.
    Application.FileControl.ConnectEvents objFileControl
End Sub

' The AfterClick event procedure for the
' Create Directory menu item.
Public Sub afterclick()
    ' Display the Create Directory form.
    frmCreateDirectory.Show vbModal
End Sub

' De-initialize the add-in.
Public Sub DisconnectAddIn(Mode As Integer)
    ' Determine whether or not VB is quitting.
    Select Case Mode
        ' VB is quitting, so unload form.
        Case 0
            Unload frmCreateDirectory
        ' User has deselected add-in in the Add-In Manager
        ' remove the add-in's menu item, then unload form.
        Case 1
            mnuitCreateDirectory.Parent.Remove mnuitCreateDirectory
            Unload frmCreateDirectory
        End Select
End Sub

