1 PRINT"[147]LOADING ADDITIONAL FILES --"
5 IFA=0THENA=1:LOAD"MENU.ML",8,1
6 IFB=0THENB=1:LOAD"MENU.BSAVE",8,1
10 PRINT"[147]"
15 DIMA$(10):DIMB$(10):S$="        "
20 MA=49181:CA=49403:FA=49397
30 FORX=1TO10
40 MA=MA+17:FA=FA+17:CA=CA+1
50 PRINT"[147]NAME OF PROGRAM #";X;"ON MENU"
55 N$=""
60 INPUTN$
70 AL=LEN(N$):IFAL<1 GOTO 50
71 IF AL>16 THEN PRINT"MAXIMUN OF 16 CHARACTERS!":FORY=1TO2000:NEXT:GOTO50
75 AL=LEN(N$):MB=MA:T=INT((16-AL)/2):AL=AL+T:A$(X)=LEFT$(S$,T)+N$
80 FORY=1TOAL
90 POKEMB+Y-1,ASC(MID$(A$(X),Y,1)):NEXTY
100 PRINT"FILENAME OF THIS PROGRAM TO LOAD"
105 PRINT"PRESS RETURN IF SAME AS ON MENU"
110 INPUTB$(X)
115 AL=LEN(B$(X)):IF AL<1 THEN B$(X)=N$
120 AL=LEN(B$(X)):FB=FA
130 POKECA,AL
140 FORZ=1TOAL
150 POKEFB+Z-1,ASC(MID$(B$(X),Z,1)):NEXTZ
160 NEXTX
170 PRINT"[147]"TAB(2)"MENU NAME"TAB(19)"FILENAME"
180 PRINT:FORX=1TO10:PRINTXTAB(3)A$(X)TAB(19)B$(X):NEXTX:PRINT:PRINT
190 PRINT"IS THIS CORRECT?"
200 GETC$:IFC$<>"Y"ANDC$<>"N"THEN200
210 IFC$="Y"THEN230
220 IFC$="N"THENRUN
230 PRINT"[147]PLACE DISK IN DRIVE TO RECIEVE MENU.ML"
240 PRINT:PRINT"PRESS [158]RETURN WHEN READY"
250 GETC$:IFC$<>CHR$(13)THEN250
260 OPEN15,8,15:PRINT#15,"S0:MENU.ML":CLOSE15
270 SYS828