10 POKE53280,1:POKE53281,1:PRINT""
100 POKE144,49
110 POKE 59468,12
120 PRINT"[147]         DOG STAR ADVENTURE[146]"
130 GOSUB6580
140 PRINT"   ADAPTED FOR THE PET CIRCA 1980"
145 REM ORIGINAL VERSION BY LANCE MIKLUS
147 REM FROM APPLESEED - JANUARY 1980
150 REM ADAPTED FOR PET BY DAVID MALMBERG
170 REM DISK VERSION BY JAY $ AND ERIC  R. NELSON-1980
180 GOSUB3900
190 DIMA(10)
200 PRINT"[147]"
210 PRINT"DO YOU WISH INSTRUCTIONS? "
220 GETA$:IFA$=""THEN220
230 IFLEFT$(A$,1)="Y"THENGOSUB5910:GOTO250
240 IFA$<>"N"THEN220
250 IFER<>0THENER=0:PRINT"[147]":GOTO290
260 PRINT"[147]"
270 LC=2:SL=40:GF=50:TB=1
280 GOTO2970
290 IFDG=-1THENDJ=-1
300 IFTC<25ORINT(RND(1)*GF)<>1THEN420
310 IFTC=300THENGF=20
320 IFLC<3ORLC=9ORLC=26ORLC=36ORLC=37THEN420
330 IFLC>26ANDLC<31THEN420
340 PRINT"HOLY SMOKES!!  AN ARMED STORMTROOPER"
350 PRINT"JUST WALKED IN."
360 GOTO7120
370 GOSUB3390:IFVB<>12ORNO<>15THEN1650
380 X=13:GOSUB3840:IFY<>-1THEN1650
390 IFBL=0THENPRINT"[147]I'M OUT OF AMMUNITION!":GOTO1660
400 PRINT"ZZZAP!!!  NO MORE STORMTROOPER!"
410 BL=BL-1:IFBL=0THENPRINT"I'M OUT OF AMMUNITION!"
420 IFMD<>TCTHEN450
430 X=22:GOSUB3840:IFY<>-1THEN450
440 PRINT"YOUR BIG MAC IS COLD."
450 GOSUB3390:TC=TC+1
460 IFVB=0ANDNO=0THEN480
470 GOTO500
480 PRINT"I DON'T UNDERSTAND.":GOTO290
490 PRINT"NOTHING HAPPENED.":GOTO290
500 IFVB>1ORNO>7THEN700
510 IFNO=0THENVB=0:GOTO460
520 IFDS(LC,NO-1)=0THENPRINT"I CAN'T GO THAT WAY.":GOTO290
530 IFDR=1ANDDS(LC,NO-1)>2ANDDS(LC,NO-1)<6THEN550
540 GOTO580
550 PRINT"[147]I CAN'T GO THAT WAY.  THE FLIGHT DECK"
560 PRINT"DOORS NEED TO BE CLOSED....AGH!!!..."
570 PRINT"..NO AIR!!!":FORI=1TO4000:NEXTI:PRINT"[147]":GOTO3170
580 IFNO=3ANDLC=31ANDDJ<>-1THENPRINTM0$:GOTO290
590 IFNO=1ANDLC=34ANDDJ<>-1THENPRINTO8$:GOTO290
600 IFLC=35ANDDS(LC,NO-1)=36ANDOB(21,1)<>0THEN620
610 GOTO630
620 PRINT"THE ROBOT WON'T LET ME.":GOTO290
630 IFLC=17ANDOB(13,1)=17THEN1650
640 IFLC=9ANDOB(5,1)=9THEN1650
650 IFLC=9ORLC=17THENHE$(LC)=""
660 LC=DS(LC,NO-1)
670 IFLC=34THENHE$(LC)=""
680 IFLC=26THEN3310
690 GOTO2970
700 IFVB=3THEN2970
710 IFVB<>2THEN950
720 IFNO=38THENPRINT"I'D RATHER NOT IF YOU DON'T MIND.":GOTO290
730 IFNO=35ANDEN=-1THENPRINT"GOOD GUESS, BUT SHE LOOKS A LITTLE BURNT.":GOTO290
740 IFLEN(NO$(NO))=0THENPRINT"TAKE WHAT?":GOTO290
750 IFNO=0THENPRINT"I DON'T KNOW WHAT A ";NO$(0);" IS.":GOTO290
760 IFCR>5THENPRINT"I CAN'T CARRY ANY MORE...TOO HEAVY!":GOTO290
770 KK=0:I=0
780 I=I+1
790 IFOB(I,0)=(NO)THENKK=I
800 IFI<LOTHEN780
810 IFKK=0THEN480
820 I=KK
830 IFOB(I,1)=-1THENPRINT"I'M ALREADY CARRYING IT.":GOTO290
840 IFOB(I,1)<>LCTHENPRINT"I DON'T SEE IT.":GOTO290
850 IFNO<>37THEN880
860 X=13:GOSUB3840:IFY<>-1THENPRINT"I DON'T HAVE A BLASTER TO PUT IT IN.":GOTO290
870 BL=10:OB(I,1)=0:PRINT"MY BLASTER'S RELOADED.":GOTO290
880 IFNO=15ORNO=25ORNO=34THENPRINT"HE LOOKS P-R-E-T-T-Y MEAN TO ME.":GOTO290
890 CR=CR+1:OB(I,1)=-1:PRINT"OK."
900 IFNO=14ANDCM<>1THENPRINT"A VOICE SAYS...SESAME![146]":CM=1
910 IFNO=22ANDMD=0THENMD=TC+50
920 IFNO=12THENHE$(2)=""
930 IFNO=13THENHE$(7)=""
940 GOTO290
950 IFVB<>4THEN1000
960 PRINT"I'M CARRYING..."
970 K=0:FORI=1TOLO:IFOB(I,1)=-1THENPRINTOB$(I):K=1:IFI=3THENPRINT""BL"[146]SHOTS"
980 NEXTI:IFK=0THENPRINT"NOTHING"
990 PRINT:GOTO290
1000 IFVB<>5THEN1020
1010 GOSUB3780:GOTO290
1020 IFVB<>6THEN1150
1030 IFLEN(NO$(NO))=0THENPRINT"PLEASE BE MORE SPECIFIC.":GOTO290
1040 IFNO=0THEN750
1050 IFLC=2THENPRINT"THERE'S NO ROOM HERE.":GOTO290
1060 IC=0:FORI=1TOLO:IFOB(I,1)=LCTHENIC=IC+1
1070 NEXTI:IFIC>12THENPRINT"THERE'S NOT ENOUGH ROOM...DUMP SOMETHING.":GOTO290
1080 I=0
1090 I=I+1
1100 IFOB(I,0)=(NO)THEN1130
1110 IFI<LOTHEN1090
1120 GOTO480
1130 IFOB(I,1)<>-1THENPRINT"I'M NOT CARRYING IT.":GOTO290
1140 CR=CR-1:OB(I,1)=LC:PRINT"OK.":GOTO290
1150 IFVB<>7THEN1180
1160 IFHE$(LC)=""THENPRINT"HOW AM I SUPPOSED TO KNOW WHAT TO DO?":GOTO290
1170 PRINT:PRINTHE$(LC):GOTO290
1180 IFVB<>8THEN1350
1190 PRINT"[147]"
1200 INPUT"T[146]APE OR D[146]ISK  D[157][157][157]";Q$:IFQ$<>"T"ANDQ$<>"D"THENPRINT"[145]";:GOTO1200
1210 IFQ$="T"THEN1230
1220 INPUT"DRIVE 1 OR  0[157][157][157]";Q$:IFQ$<>"1"ANDQ$<>"0"THENPRINT"[145][145]";:GOTO1220
1230 POKE144,46:INPUT"TITLE  *[157][157][157]";TL$:IFTL$="*"THENPRINT"[145]";:GOTO1230
1240 IFQ$="T"THENOPEN1,1,1,TL$:GOTO1270
1250 DN$=CHR$(34)+Q$+":"
1260 OPEN1,8,1,DN$+TL$+",S,W"
1270 PRINT"[147] ****** DATA TRANSFER IN PROCESS ****** "
1280 A(1)=TB:A(2)=TC:A(3)=CM:A(4)=DR:A(5)=BL
1290 A(6)=MD:A(7)=GF:A(8)=DJ:A(9)=CR:A(10)=LC
1300 FORI=0TO10:PRINT#1,A(I);CHR$(13);::PRINT""A(I):NEXTI
1310 FORI=0TOLO:FORP=0TO2:PRINT#1,OB(I,P);CHR$(13);:PRINT""OB(I,P):NEXTP,I
1320 CLOSE1:PRINT:PRINT"[147]GAME SAVED.[146]"
1330 PRINT"TITLE WAS:"TL$
1340 PRINT"MAY THE FORCE BE WITH YOU.":GOSUB3780:GOTO8060
1350 IFVB<>9THEN1510
1360 PRINT"[147]"
1370 INPUT"T[146]APE OR D[146]ISK  D[157][157][157]";Q$:IFQ$<>"T"ANDQ$<>"D"THENPRINT"[145]";:GOTO1370
1380 IFQ$="T"THEN1400
1390 INPUT"DRIVE 1 OR  0[157][157][157]";Q$:IFQ$<>"1"ANDQ$<>"0"THENPRINT"[145][145]";:GOTO1390
1400 DN$=CHR$(34)+Q$+":"
1410 POKE144,46:INPUT"TITLE  *[157][157][157]";TL$:IFTL$="*"THENPRINT"[145]";:GOTO1410
1420 IFQ$="T"THENOPEN1,1,0,TL$:GOTO1440
1430 OPEN1,8,0,DN$+TL$+",S,R"
1440 PRINT"[147] ****** DATA TRANSFER IN PROCESS ****** "
1450 FORI=0TO10:INPUT#1,A(I):PRINT""A(I):NEXTI
1460 FORI=0TOLO:FORP=0TO2:INPUT#1,OB(I,P):PRINT""OB(I,P):NEXTP,I
1470 CLOSE1
1480 TB=A(1):TC=A(2):CM=A(3):DR=A(4):BL=A(5)
1490 MD=A(6):GF=A(7):DJ=A(8):CR=A(9):LC=A(10)
1500 POKE144,49:GOTO2970
1510 IFVB<>10THEN1540
1520 INPUT"DO YOU WANT TO SAVE GAME Y[157][157][157]";K$:IFLEFT$(K$,1)="Y"THEN1190
1530 PRINT:PRINT"[147]MAY THE FORCE BE WITH YOU.":GOSUB3780:GOTO8060
1540 IFVB<>11THEN1750
1550 IFLEN(NO$(NO))=0THENPRINT"PUSH WHAT?":PRINT:GOTO290
1560 IFNO<>10THEN480
1570 IFLC<>2ANDLC<>11THENPRINT"WHAT BUTTON?":GOTO290
1580 IFLC=11ANDTBTHENTB=0:PRINTN2$:GOTO290
1590 IFLC=11ANDNOTTBTHENTB=1:PRINTN3$:GOTO290
1600 X=12:GOSUB3840:IFY<>1THEN490
1610 X=24:GOSUB3840:IFY<>1THEN490
1620 IFTB=1THENPRINTN3$:GOTO490
1630 IFDR=0THENPRINTN4$:GOTO290
1640 GOTO3140
1650 PRINT"[147]HELP!!!"
1660 PRINT"VADER'S SOLDIERS ARE EVERYWHERE."
1670 PRINT"I'VE BEEN CAPTURED."
1680 PRINT"I'M A PRISONER...WOE IS ME..."
1690 FORDU=1TOLO
1700 IF OB(DU,1)<>-1THEN1720
1710 OB(DU,1)=LC
1720 NEXTDU
1730 CR=0:OB(22,1)=34:OB(19,1)=26:LC=2
1740 GOTO6810
1750 IFVB<>12THEN1930
1760 IFNO=38THENNO=35:NO$(35)="REMAINS"
1770 IFNO=36ANDDG<>-1THEN7990
1780 IFLEN(NO$(NO))=0THENPRINTN7$:GOTO290
1790 X=13:GOSUB3840:IFY<>-1THENPRINT"BUT I DON'T HAVE A BLASTER.":GOTO290
1800 IFBL=0THENPRINT"BUT I DON'T HAVE ANY AMMUNITION.":GOTO290
1810 X=NO:GOSUB3840:IFY=-1THENPRINT"I CAN'T...I'M HOLDING IT.":GOTO290
1820 IFNO=34THENPRINT"ZZZAP!":BL=BL-1:GOTO290
1830 IFY<>LCTHENPRINT"I DON'T SEE IT.":GOTO290
1840 I=0
1850 I=I+1
1860 IFOB(I,0)=(NO)THEN1890
1870 IFI<LOTHEN1850
1880 GOTO480
1890 IFNO=12THEN7070
1900 OB(I,1)=0:PRINT"ZZZAP!!!  THE ";NO$(NO);" VAPORIZED!"
1910 BL=BL-1:IFBL=0THENPRINT"I'M OUT OF AMMUNITION."
1920 GOTO290
1930 IFVB<>13THEN2020
1940 IFLEN(NO$(NO))=0THENPRINT"SAY WHAT?":GOTO290
1950 X=14:GOSUB3840
1960 IFY<>-1ORNO<>19THENPRINT"OK... ";NO$(NO):PRINT:GOTO290
1970 IFDR=1THEN490
1980 DR=1:PRINT"[147]A VOICE COMES OVER THE P.A...":PRINT"   OPENING FLIGHT DECK DOORS"
1990 IFLC>2ANDLC<6THENPRINT"...YIPS!!!THERE'S NO AIR!!!...CROAK..."
2000 IFLC>2ANDLC<6THENFORI=1TO4000:NEXTI:PRINT"[147]":GOTO3170
2010 GOTO290
2020 IFVB<>14THEN2200
2030 IFNO<>20ANDNO<>16ANDNO<>11ANDNO<>33THEN490
2040 IFNO=20THEN2130
2050 IFNO<>16THEN2090
2060 IFOB(6,1)=-1THENGOSUB7210:GOTO290
2070 IFOB(6,1)=LCTHENPRINT"TRY...TAKE MAP":GOTO290
2080 PRINT"IT'S NOT HERE.":GOTO290
2090 X=NO:GOSUB3840:IFY<>LCANDY<>-1THEN2080
2100 IFNO=11THENPRINT"IT SAYS NEEDS TURBO[146]"
2110 IFNO=33THENPRINT"IT SAYS OUT OF ORDER[146]"
2120 GOTO290
2130 IFLC<>13THENPRINT"I DON'T SEE ANY.":GOTO290
2140 PRINT"IT SAYS ON THE WALL..."
2150 PRINT"YOUR MOTHER'S GOT A BIG NOSE"
2160 PRINT"KILROY WAS HERE"
2170 PRINT"FOR A GOOD TIME CALL 6557"
2180 PRINT"SAY SECURITY"
2190 GOTO290
2200 IFVB<>15THEN2320
2210 IFLEN(NO$(NO))=0THENPRINT"EAT WHAT?":GOTO290
2220 IFNO=0THENPRINT"WHAT'S A ";NO$(NO);"?":GOTO290
2230 IFNO<>22THENPRINT"DON'T BE RIDICULOUS!":GOTO290
2240 X=22:GOSUB3840:IFY<>-1THENPRINT"I'M NOT HOLDING IT.":GOTO290
2250 I=0
2260 I=I+1
2270 IFOB(I,0)=22THEN2300
2280 IFI<LOTHEN2260
2290 PRINT"I DON'T KNOW WHERE IT IS.":GOTO290
2300 OB(I,1)=0:PRINT"CHOMP...CHOMP...HUMMM, GOOD!"
2310 GOTO290
2320 IFVB<>16ORLC<>16THEN2380
2330 IFLEN(NO$(NO))=0THENPRINT"COPY WHAT?":GOTO290
2340 IFNO<>23THEN2380
2350 X=23:GOSUB3840:IFY<>-1THENPRINT:PRINTM1$:GOTO290
2360 OB(11,1)=0:OB(14,1)=16:CR=CR-1:PRINT:PRINTM2$
2370 GOTO290
2380 IFVB<>18ANDVB<>24THEN2510
2390 IFNO=19ANDVB=18THEN1970
2400 IFLEN(NO$(NO))<>0THEN2430
2410 IFNO=0ANDVB=24THENPRINTN6$:GOTO290
2420 IFNO=0ANDVB=18THENPRINTN5$:GOTO290
2430 IFNO<>36THEN480
2440 IFLC<>34ANDLC<>31THENPRINTO0$:GOTO290
2450 IFDJ=-1ANDVB=24THENPRINTO2$:GOTO290
2460 IFDJ=-1ANDVB=18THENPRINTO1$:GOTO290
2470 IFDJ<>-1ANDVB=18THENPRINT"I CAN'T OPEN A LOCKED DOOR!":GOTO290
2480 IFLC=34ANDDJ<>-1THENPRINTO3$:GOTO290
2490 X=17:GOSUB3840:IFY<>-1THENPRINTM3$:GOTO290
2500 HE$(31)="":DJ=-1:PRINT:PRINTM4$:GOTO290
2510 IFVB<>22ANDVB<>23THEN2610
2520 IFLEN(NO$(NO))<>0THEN2550
2530 IFNO=0ANDVB=22THENPRINTN8$:GOTO290
2540 IFNO=0ANDVB=23THENPRINTN9$:GOTO290
2550 IFNO<>36THEN480
2560 IFLC<>31ANDLC<>34THENPRINTO0$:GOTO290
2570 IFVB=23ANDDJ=-1THENPRINTO4$:GOTO290
2580 IFVB=23ANDDJ<>-1THENPRINTO6$:GOTO290
2590 IFVB=22ANDDJ<>-1THENPRINTO7$:GOTO290
2600 DJ=1:PRINTO5$:GOTO290
2610 IFVB<>19ORNO=0THEN2810
2620 IFLEN(NO$(NO))=0THENPRINT"WHAT OR WHOM?":GOTO270
2630 IFNO<>34THENPRINT"THAT'S STUPID!":GOTO290
2640 IFLC<>35THENPRINT:PRINTM5$:GOTO290
2650 X=22:GOSUB3840:IFY<>-1THENPRINT:PRINTM6$:GOTO290
2660 IFNO=35THENPRINTM7$:GOTO290
2670 IFNO<>34THENPRINTNO$(0);M8$:GOTO290
2680 IFTC>MDTHENPRINTM9$:GOTO290
2690 I=0
2700 I=I+1
2710 IFOB(I,0)=34THENK=I:GOTO2740
2720 IFI<LOTHEN2700
2730 GOTO480
2740 I=0
2750 I=I+1
2760 IFOB(I,0)=22THEN2790
2770 IFI<LOTHEN2750
2780 GOTO480
2790 PRINTN0$:HE$(35)=""
2800 OB(K,1)=0:OB(I,1)=0:GOTO290
2810 IFVB<>17THEN2830
2820 IFVB<>20THEN2940
2830 IFVB<>20THEN2940
2840 IFLEN(NO$(NO))=0THENPRINT"HIT WHAT?":GOTO290
2850 IFNO=10THENPRINT"JUST PUSH IT.":GOTO290
2860 IFNO=0THEN480
2870 X=NO:GOSUB3840:IFY=-1THENPRINT"THAT'S IMPOSSIBLE...I'M CARRYING IT.":GOTO290
2880 IFY=LCTHEN2910
2890 IFNO<11ORNO=19ORNO=20ORNO=30THEN480
2900 PRINT"I CAN'T HIT IT IF I CAN'T SEE IT!":GOTO290
2910 IFNO=15ORNO=25ORNO=31THENPRINT"I'D RATHER NOT...HE MIGHT HIT BACK!":GOTO290
2920 IFNO=35THENPRINT"THAT'S NOT NICE!!!":GOTO290
2930 GOTO490
2940 IFVB<>21THEN2960
2950 PRINT"I'M NOT STRONG ENOUGH TO KILL ANYTHING!":GOTO290
2960 GOTO480
2970 PRINT"[147]"DS$(LC):A$=""
2980 IFLC=35THENGF=10
2990 IFLC=7THEN3060
3000 K=0:FORI=1TOLO:IFOB(I,1)<>LCTHEN3040
3010 IFK=0THENK=1:PRINT:PRINT"AROUND ME I SEE --- ":A$=OB$(I):GOTO3040
3020 IFLEN(A$)+5+LEN(OB$(I))>40THENPRINTA$:A$=OB$(I):GOTO3040
3030 A$=A$+"    "+OB$(I)
3040 NEXTI
3050 IFA$<>""THENPRINTA$
3060 PRINT:PRINT"OBVIOUS DIRECTIONS ARE ";:K=0
3070 FORI=0TO5:IFDS(LC,I)=0THEN3110
3080 IFK<>0THENPRINT",";
3090 PRINTNO$(I+1);:K=K+1
3100 IFK=3THENPRINT""
3110 NEXTI
3120 IFK=0THENPRINT"UNKNOWN";
3130 PRINT".":GOTO290
3140 J=0:FORI=1TOLO:IFOB(I,1)=1THENJ=J+OB(I,2)
3150 NEXTI:PRINT"[147]"
3160 IFJ<>0THEN3200
3170 PRINT"WE HAVE FAILED IN OUR MISSION.  THE"
3180 PRINT"FORCES OF PRINCESS LEIA WILL BE"
3190 PRINT"CONQUERED.":GOTO3290
3200 IFJ<>SCTHEN3260
3210 PRINT"WE ARE HEROES.  THE FORCES OF PRINCESS"
3220 PRINT"LEIA WILL CONQUER THE EVIL IMPERIAL"
3230 PRINT"SOLDIERS, AND FREEDOM WILL PREVAIL"
3240 PRINT"THROUGHOUT THE GALAXY!":J=J+10
3250 PRINT"MAY THE FORCE BE WITH YOU!":GOSUB3800:GOTO8060
3260 PRINT"WE HAVE HELPED THE FORCES OF PRINCESS"
3270 PRINT"LEIA DEFEND THE GALAXY.  LONG LIVE THE"
3280 PRINT"FORCES OF FREEDOM!"
3290 PRINT"MAY THE FORCE BE WITH YOU!"
3300 PRINT:PRINT:PRINT:GOSUB 3780:GOTO8060
3310 PRINT"[147]A VOICE CALLS OUT...WHO GOES THERE?[146]"
3320 GOSUB3390
3330 IFVB<>13ORNO<>30THEN1650
3340 PRINTN1$
3350 GOSUB3390
3360 X=31:GOSUB3840:IFY<>-1THEN1650
3370 IFVB<>17ORNO<>31THEN1650
3380 GOTO2970
3390 PRINT"WHAT SHOULD I DO? ";
3400 CM$=""
3410 GETCDM$:PRINT" [157]";:IFCDM$=""THENPRINT"[166][157]";:GOTO3410
3420 IFCDM$=CHR$(13)THENPRINT" [157]":GOTO3490
3430 IFCDM$=CHR$(20)ANDLEN(CM$)<>0THENCM$=LEFT$(CM$,LEN(CM$)-1):PRINTCDM$;:GOTO3410
3440 IFCDM$=CHR$(20)ANDLEN(CM$)=0THEN3410
3450 IFCDM$=CHR$(3)THEN3410
3460 PRINTCDM$;
3470 CM$=CM$+CDM$:GOTO3410
3480 PRINT" ":GOTO3410
3490 IFLEFT$(CM$,4)=F$ORRIGHT$(CM$,6)=FU$THEN7050
3500 IF ER<>0 THEN 6880
3510 IFCQ=1ANDLEFT$(CM$,3)="YES"THENCM$="READ MAP":CQ=2
3520 IFLEFT$(CM$,3)="YES"THENPRINT"HUH?":GOTO3390
3530 IFCQ=1ANDLEFT$(CM$,3)<>"YES"THENCQ=0
3540 IFLEFT$(CM$,2)="NO"THENPRINT"HUH?":GOTO3390
3550 PRINT:IFCM$="N"THENCM$="NORTH"
3560 IFCM$="E"THENCM$="EAST"
3570 IFCM$="S"THENCM$="SOUTH"
3580 IFCM$="W"THENCM$="WEST"
3590 IFCM$="U"THENCM$="UP"
3600 IFCM$="D"THENCM$="DOWN"
3610 VB$(0)="":NO$(0)="":VB=0:NO=0:IFLEN(CM$)=0THENRETURN
3620 FORZL=1TOLEN(CM$)
3630 IFMID$(CM$,ZL,1)<>" "THENVB$(0)=VB$(0)+MID$(CM$,ZL,1):GOTO3650
3640 ZL=LEN(CM$)
3650 NEXTZL
3660 FORZL=1TOLV
3670 ZZ=4:YY=LEN(VB$(ZL)):IFYY<ZZTHENZZ=YY
3680 IFVB$(ZL)<>""ANDLEFT$(VB$(0),ZZ)=LEFT$(VB$(ZL),ZZ)THENVB=ZL:ZL=LV
3690 NEXTZL
3700 IFVB=0THENNO$(0)=VB$(0):GOTO3730
3710 IFLEN(VB$(0))+1>LEN(CM$)THENNO=0:RETURN
3720 NO$(0)=RIGHT$(CM$,LEN(CM$)-1-LEN(VB$(0)))
3730 NO=0:FORZL=1TOLN
3740 ZZ=4:YY=LEN(NO$(ZL)):IFYY<ZZTHENZZ=YY
3750 IFNO$(ZL)<>""THENIFLEFT$(NO$(0),ZZ)=LEFT$(NO$(ZL),ZZ)THENNO=ZL:ZL=LN
3760 NEXTZL
3770 RETURN
3780 J=0:FORI=1TOLO:IFOB(I,1)=1THENJ=J+OB(I,2)
3790 NEXTI
3800 PRINT"OUT OF A MAXIMUM OF";225;"POINTS"
3810 PRINT"YOU HAVE ";J;"POINTS."
3820 IFJ=0THENPRINT"YOU ARE NOT DOING SPECTACULARLY WELL!"
3830 RETURN
3840 ZL=-1
3850 ZL=ZL+1
3860 IFOB(ZL,0)=XTHENY=OB(ZL,1):RETURN
3870 IFZL<LOTHEN3850
3880 Y=-99:RETURN
3890 INPUTA$:RETURN
3900 SC=215:BT=0
3910 LV=24:DIMVB$(LV)
3920 FORI=1TOLV:READVB$(I):NEXTI
3930 DATAGO,TAKE,LOOK,INVENTORY,SCORE,DROP,HELP,SAVE,LOAD,QUIT,PUSH,SHOOT
3940 DATASAY,READ,EAT,COPY,SHOW,OPEN,FEED,HIT,KILL,CLOSE,LOCK,UNLOCK
3950 LN=38:DIMNO$(LN)
3960 FORI=1TOLN:READNO$(I):NEXTI
3970 DATANORTH,EAST,SOUTH,WEST,UP,DOWN,"","",""
3980 DATABUTTON,TAG,FUEL,BLASTER,COMMUNICATOR
3990 DATASTORMTROOPER,MAP,KEYS,NECKLACE,SESAME,GRAFFITI,CAPE,BIG MAC,TAPE,TURBO
4000 DATASCIENTIST,PLANS,SCHEMATIC,DEVICE,GUN,SECURITY,I.D.,CRYSTAL,SIGN
4010 DATAROBOT,PRINCESS,DOOR,AMMUNITION,REMAINS
4020 CL=37:DIMDS$(CL),DS(CL,5),HE$(CL)
4030 FORI=1TOCL
4040 FORZL=0TO5:READDS(I,ZL):NEXTZL
4050 NEXTI
4060 DS$(1)="I'M IN THE PASSENGER AND STORAGE AREA "
4070 DS$(1)=DS$(1)+"OF THE MILLENNIUM FALCON.  THERE'S AN"
4080 DS$(1)=DS$(1)+" EXIT HERE TO LEAVE THE SHIP."
4090 DATA2,0,0,0,0,3
4100 DS$(2)="I'M IN THE COCKPIT OF THE FALCON.  A    "
4110 DS$(2)=DS$(2)+"LARGE RED BUTTON IS LABELED PUSH[146] TO     "
4120 DS$(2)=DS$(2)+"BLAST OFF."
4130 DATA0,0,1,0,0,0
4140 DS$(3)="I'M STANDING NEXT TO THE MILLENNIUM     "
4150 DS$(3)=DS$(3)+"FALCON WHICH IS LOCATED ON A HUGH DECK."
4160 DATA18,0,4,0,1,0
4170 DS$(4)="I'M OUT ON THE FLIGHT DECK OF DARTH     "
4180 DS$(4)=DS$(4)+"VADER'S BATTLECRUISER."
4190 DATA3,5,4,4,0,0
4200 DS$(5)=DS$(4)
4210 DATA4,6,5,4,0,0
4220 DS$(6)="I'M IN A HALLWAY.  THERE ARE DOORS ON   "
4230 DS$(6)=DS$(6)+"ALL SIDES.  THE DOOR TO THE NORTH SAYS: "
4240 DS$(6)=DS$(6)+"CLOSED FOR THE DAY[146]"
4250 DATA7,0,8,5,0,0
4260 DS$(7)="I'M IN THE SUPPLY DEPOT.  AROUND ME I   "
4270 DS$(7)=DS$(7)+"SEE ALL KINDS OF THINGS."
4280 DATA0,0,6,0,0,0
4290 DS$(8)="I'M AT THE END OF ONE OF THE HALLWAYS.  "
4300 DS$(8)=DS$(8)+"I CAN HEAR VOICES NEARBY.  THEY SOUND   "
4310 DS$(8)=DS$(8)+"LIKE STORMTROOPERS."
4320 DATA6,10,0,9,0,12
4330 DS$(9)="I'M IN THE STRATEGIC PLANNING ROOM."
4340 DATA11,8,0,0,0,0
4350 DS$(10)="I'M IN THE DECONTAMINATION ROOM."
4360 DATA0,14,0,8,0,0
4370 DS$(11)="THIS AREA IS THE TRACTOR BEAM CONTROL   "
4380 DS$(11)=DS$(11)+"ROOM. THERE IS A SIGN ON THE BULKHEAD:  "
4390 DS$(11)=DS$(11)+"      ONLY AUTHORIZED PERSONNEL [146]        "
4400 DS$(11)=DS$(11)+"          MAY PUSH BUTTONS!     [146]      "
4410 DATA0,0,9,0,0,0
4420 DS$(12)="I'M IN ANOTHER HALLWAY.  TO THE EAST IS "
4430 DS$(12)=DS$(12)+"A RESTROOM."
4440 DATA15,13,0,0,8,0
4450 DS$(13)="THIS IS WHAT IS COMMONLY CALLED (ON     "
4460 DS$(13)=DS$(13)+"EARTH), THE BATHROOM. THERE'S GRAFFITI "
4470 DS$(13)=DS$(13)+"ON THE WALLS AND PIPES GOING UP THROUGH "
4480 DS$(13)=DS$(13)+"THE CEILING."
4490 DATA15,0,0,12,27,0
4500 DS$(14)="THIS SEEMS TO BE AN INTERROGATION ROOM."
4510 DATA0,0,0,10,0,0
4520 DS$(15)="I'M IN THE OFFICERS LOUNGE."
4530 DATA0,0,13,12,0,0
4540 DS$(16)="THIS IS THE COMPUTER CENTER.  THE CRT   "
4550 DS$(16)=DS$(16)+"SAYS: READY FOR DATA COPY[146]"
4560 DATA17,0,18,0,0,0
4570 DS$(17)="I'M IN A TESTING LABORATORY."
4580 DATA0,0,16,0,0,0
4590 DS$(18)="I'M IN A HALLWAY.  A LARGE ARROW POINTS "
4600 DS$(18)=DS$(18)+"EAST AND SAYS: TO THE VAULT[146]"
4610 DATA16,25,3,19,0,0
4620 DS$(19)="THIS IS THE ENTRANCE TO THE DEVELOPMENT "
4630 DS$(19)=DS$(19)+"LAB SECTION."
4640 DATA20,18,21,20,22,0
4650 DS$(20)="I'M IN A LONG CORRIDOR.  THERE ARE LABS "
4660 DS$(20)=DS$(20)+"ALL AROUND ME."
4670 DATA19,23,21,20,22,24
4680 DS$(21)="I'M IN A RESEARCH LAB."
4690 DATA20,0,0,0,0,0
4700 DS$(22)="I'M LOST!!!"
4710 DATA22,22,22,22,22,20
4720 DS$(23)=DS$(21)
4730 DATA0,0,0,0,20,0
4740 DS$(24)=DS$(21)
4750 DATA0,0,0,20,0,0
4760 DS$(25)="I'M NEAR THE ENTRANCE TO THE VAULT.  A  "
4770 DS$(25)=DS$(25)+"SIGN SAYS: AUTHORIZED PERSONNEL ONLY[146]"
4780 DATA0,26,0,18,0,0
4790 DS$(26)="I'M IN THE VAULT."
4800 DATA0,0,0,25,0,0
4810 DS$(27)="I'M IN A PIPE TUNNEL THAT LEADS IN ALL  "
4820 DS$(27)=DS$(27)+"DIRECTIONS."
4830 DATA28,27,27,27,27,13
4840 DS$(28)=DS$(27)
4850 DATA29,29,29,29,30,29
4860 DS$(29)="I'M LOST IN A MAZE OF PIPES."
4870 DATA28,29,29,29,29,27
4880 DS$(30)="I'M IN A MAZE OF PIPES.  BELOW ME I     "
4890 DS$(30)=DS$(30)+"THINK I SEE THE JAIL. IT'S A LONG DROP. IF I GO DOWN,"
4900 DS$(30)=DS$(30)+" I MAY NOT BE ABLE TO GET  BACK UP."
4910 DATA29,29,28,29,29,31
4920 DS$(31)="I'M IN THE JAIL. FAR ABOVE IS A         VENTILATION SHAFT."
4930 DATA32,33,34,35,0,0
4940 DS$(32)="I'M IN A JAIL CELL."
4950 DATA0,0,31,0,0,0
4960 DS$(33)=DS$(32)
4970 DATA0,0,0,31,0,0
4980 DS$(34)=DS$(32)
4990 DATA31,0,0,0,0,0
5000 DS$(35)="I'M AT THE SECURITY DESK.  TO THE NORTH "
5010 DS$(35)=DS$(35)+"IS AN ELEVATOR."
5020 DATA36,31,0,0,0,0
5030 DS$(36)="I'M IN THE ELEVATOR."
5040 DATA0,0,35,0,37,0
5050 DS$(37)=DS$(36)
5060 DATA0,0,14,0,0,36
5070 LO=23:DIMOB$(LO),OB(LO,2)
5080 FORI=1TOLO:READOB$(I):NEXTI
5090 DATA"A TAG WHICH SAYS: NEEDS TURBO","ANTI-MATTER FUEL","BLASTER"
5100 DATACOMMUNICATOR,A VERY SURPRISED STORMTROOPER,A MAP OF THE SHIP
5110 DATASOME KEYS,A SHINESTONE NECKLACE,PRINCESS LEIA'S CAPE,A BIG MAC
5120 DATAA CASSETTE TAPE,A TURBOENCABULATOR,AN EVIL LOOKING SCIENTIST
5130 DATASECRET ATTACK PLANS,DEATH RAY SCHEMATIC,CLOAKING DEVICE
5140 DATA MICRO LASER GUN,I.D. CARD,MALIDUM CRYSTALS (THE TREASURY)
5150 DATA"A SIGN WHICH SAYS: OUT OF ORDER",AN ATTACK ROBOT,PRINCESS LEIA
5160 DATAAMMUNITION
5170 FORI=1TOLO:FORZL=0TO2:READOB(I,ZL):NEXTZL,I
5180 DATA11,5,0
5190 DATA12,5,5
5200 DATA13,7,0
5210 DATA14,9,0
5220 DATA15,9,0
5230 DATA16,29,20
5240 DATA17,9,0
5250 DATA18,10,20
5260 DATA21,14,5
5270 DATA22,15,0
5280 DATA23,7,0
5290 DATA24,17,5
5300 DATA25,17,0
5310 DATA26,0,20
5320 DATA27,9,20
5330 DATA28,17,20
5340 DATA29,24,20
5350 DATA31,17,0
5360 DATA32,26,30
5370 DATA33,3,0
5380 DATA34,35,0
5390 DATA35,34,50
5400 DATA37,7,0
5410 HE$(1)="[145]WE'RE SUPPOSE TO LEAVE THE STUFF HERE."
5420 HE$(2)="[145]I WONDER IF WE HAVE ENOUGH FUEL?"
5430 HE$(7)="[145]HOW ABOUT A BLASTER?"
5440 HE$(9)="[145]TRY TO SHOOT THE STORMTROOPER."
5450 HE$(13)="[145]READ THE GRAFFITI."
5460 HE$(17)="[145]TRY SHOOTING THE SCIENTIST."
5470 HE$(22)="[145]I'M AS CONFUSED AS YOU ARE!":HE$(29)=HE$(22)
5480 HE$(31)="[145]IT MIGHT HELP IF WE HAD SOME KEYS TO    "
5490 HE$(31)=HE$(31)+"OPEN ANY LOCKED DOORS."
5500 HE$(35)="[145]DID YOU BRING ANYTHING TO EAT?"
5510 M0$="[145]CAN'T GO IN THERE.  THE DOOR IS LOCKED. "
5520 M1$="[145]I'M NOT CARRYING ANY BLANK TAPE."
5530 M2$="[145]THE PET RECORDED ON THE TAPE, THEN IT   "
5540 M2$=M2$+"PRINTED: ATTACK PLANS--VERY SECRET[146]"
5550 M3$="[145]I CAN'T.  I'M NOT CARRYING ANY KEYS."
5560 M4$="[145]OK...THE DOOR TO THE JAIL IS UNLOCKED."
5570 M5$="[145]THERE'S NO ROBOT HERE!"
5580 M6$="[145]BUT I DON'T HAVE ANY BIG MACS."
5590 M7$="[145]THE PRINCESS THANKS YOU FOR A DELICIOUS"
5600 M7$=M7$+"MEAL."
5610 M8$="[145]DOESN'T EAT HAMBURGER."
5620 M9$="[145]NOTHING HAPPENED.  THE BIG MAC IS COLD."
5630 N0$="THE ATTACK ROBOT EATS THE BIG MAC AND   "
5640 N0$=N0$+"DISAPPEARS."
5650 N1$="I'M AT THE IDENTIFICATION TERMINAL.  ON "
5660 N1$=N1$+"THE SCREEN IT SAYS: GIVE AUTHORIZATION[146]"
5670 N2$="THE TRACTOR BEAM IS OFF."
5680 N3$="THE TRACTOR BEAM IS ON."
5690 N4$="YOU FORGOT TO OPEN THE FLIGHT DECK      "
5700 N4$=N4$+"DOORS."
5710 N5$="OPEN WHAT?"
5720 N6$="UNLOCK WHAT?"
5730 N7$="SHOOT WHAT?"
5740 N8$="CLOSE WHAT?":N9$="LOCK WHAT?"
5750 O0$="I SEE NO DOOR HERE."
5760 O1$="IT'S ALREADY OPEN!"
5770 O2$="IT'S ALREADY UNLOCKED!"
5780 O3$="I CAN'T..."+CHR$(10)+CHR$(13)+"IT UNLOCKS FROM THE OTHER SIDE."
5790 O4$="A DOOR HAS TO BE CLOSE TO BE LOCKED."
5800 O5$="OK... THE DOOR IS NOW CLOSED AND LOCKED."
5810 O6$="IT'S ALREADY LOCKED!"
5820 O7$="IT'S ALREADY CLOSED!"
5830 O8$="I CAN'T GO THAT WAY..."+CHR$(10)+CHR$(13)+"YOU LOCKED THE DOOR."
5840 S$=CHR$(83)+CHR$(72)+CHR$(73)+CHR$(84)
5850 E$=CHR$(69)+CHR$(65)+CHR$(84):D$=CHR$(68)+CHR$(73)+CHR$(69)
5860 F$=CHR$(70)+CHR$(85)+CHR$(67)+CHR$(75):FU$=F$+CHR$(69)+CHR$(68)
5870 T$=CHR$(84)+CHR$(85)+CHR$(82)+CHR$(75)+CHR$(69)+CHR$(89)
5880 RETURN
5890 IFTI<8THEN5890
5900 RETURN
5910 PRINT"[147]YOU ARE THE ONLY HOPE OF SAVING"
5920 PRINT"PRINCESS LEIA AND THE FREEDOM FIGHTING"
5930 PRINT"FORCE."
5940 PRINT"HER SHIP HAS BEEN CAPTURED BY DARTH"
5950 PRINT"VADER AND SHE IS BEING HELD PRISONER ON"
5960 PRINT"HIS BATTLECRUISER.  ON BOARD HER SHIP"
5970 PRINT"WAS THE ENTIRE TREASURY OF THE FREEDOM"
5980 PRINT"FIGHTING FORCES.  THE PRINCESS WAS ALSO"
5990 PRINT"WEARING A NECKLACE OF SHINESTONES, WITH"
6000 PRINT"ONE STONE ENCODED WITH THE SECRET"
6010 PRINT"STRENGTH AND LOCATION OF THE FREEDOM"
6020 PRINT"FORCES."
6030 PRINT"DARTH VARDER MUST NOT DISCOVER THE"
6040 PRINT"SECRET OR ELSE HE WILL LAUNCH AN ATTACK"
6050 PRINT"AND PEACE WILL BE LOST TO THE GALAXY"
6060 PRINT"FOR EONS TO COME."
6070 PRINT"PRESS RETURN[146] TO CONTINUE."
6080 GETA$:IFA$=""THEN6080
6090 PRINT"[147]DISGUISED AS A TRADING SHIP, YOU HAVE"
6100 PRINT"JUST LANDED ON DARTH VADER'S SHIP. YOU"
6110 PRINT"MUST RESCUE THE PRINCESS, HER NECKLACE,"
6120 PRINT"AND THE TREASURY.  IF YOU FAIL TO GET"
6130 PRINT"THE PRINCESS, IN THE INTEREST OF PEACE"
6140 PRINT"YOU MUST AT LEAST DO EVERYTHING YOU CAN"
6150 PRINT"TO FOIL VADER'S PLANS."
6160 PRINT"YOU MUST EXERCISE EXTREME CAUTION."
6170 PRINT"STORMTROOPERS ARE EVERYWHERE ON THE "
6180 PRINT"SHIP.  ONLY A SINGLE RESCUER, MOVING"
6190 PRINT"STEALTHILY, HAS A CHANCE.  THE ODDS"
6200 PRINT"AGAINST YOU ARE OVERWHELMING--BUT FOR"
6210 PRINT"THE SAKE OF THE GALAXY, YOU MUST TRY!"
6220 PRINT"MAY THE FORCE BE WITH YOU."
6230 PRINT"PRESS RETURN[146] TO CONTINUE."
6240 GETA$:IFA$=""THEN6240
6250 PRINT"[147]DURING THIS ADVENTURE THE PET WILL BE"
6260 PRINT"YOUR ALTER EGO.  YOU TAKE ACTIONS BY"
6270 PRINT"GIVING THE PET A SERIES OF ORDINARY"
6280 PRINT"ENGLISH COMMANDS OF ONE OR TWO WORDS."
6290 PRINT"EXAMPLES ARE: GO NORTH[146], TAKE SIGN[146], DROP[146]"
6300 PRINT"NECKLACE[146], EAT BIG MAC[146], ETC.  INVENTORY[146]"
6310 PRINT"WILL CALL UP A LIST OF THE ITEMS YOU"
6320 PRINT"ARE CARRYING.  HELP[146] MAY RESULT IN A"
6330 PRINT"HELPFUL HINT.  LOOK[146] MAY REVEAL VERY"
6340 PRINT"SIGNFICANT DETAILS THAT WILL HELP YOU"
6350 PRINT"TO WIN.  OTHER WORDS IN THE PET'S "
6360 PRINT"LEXICON ARE SCORE[146], AND QUIT[146]."
6370 PRINT"THE PET WILL ACCEPT VARIOUS FORMS FOR"
6380 PRINT"SOME COMMANDS.  FOR EXAMPLE:N[146], NORTH[146],"
6390 PRINT"AND GO NORTH[146] ARE EQUIVALENT.  THE PET"
6400 PRINT"LOOKS AT ONLY THE FIRST FOUR LETTERS OF"
6410 PRINT"EACH WORD, SO INVE[146] WILL GET THE SAME"
6420 PRINT"RESULT AS INVENTORY[146]."
6430 PRINT"PRESS RETURN[146] TO CONTINUE."
6440 GETA$:IFLEFT$(A$,1)=""THEN6440
6450 PRINT"[147]SAVE[146] WILL CAUSE THE CURRENT GAME"
6460 PRINT"STATUS TO BE SAVED ON TAPE OR DISK."
6470 PRINT"LOAD[146] ENABLE YOU TO RESUME A PREVIOUSLY"
6480 PRINT"SAVED GAME."
6490 PRINT"REMEMBER, EVERYTHING YOU ENCOUNTER IN"
6500 PRINT"YOUR DOG STAR ADVENTURE HAS A PURPOSE."
6510 PRINT"THERE ARE CLUES EVERYWHERE, BUT IT WILL"
6520 PRINT"TAKE IMAGINATION, PERSEVERANCE AND LUCK"
6530 PRINT"TO RESCUE THE PRINCESS AND SAVE THE"
6540 PRINT"GALAXY."
6550 PRINT"PRESS RETURN[146] TO BEGIN."
6560 GETA$:IFLEFT$(A$,1)=""THEN6560
6570 RETURN
6580 PRINT"              [198][192][195][195][192][198][210]"
6590 PRINT"             [206] [200][199]    [205]"
6600 PRINT"             [165] [212][165]    [167]"
6610 PRINT"            [206] [200][200]      [165]"
6620 PRINT"           [206][163][196][177][177][195][197][195][164]  [212]"
6630 PRINT"          [200] < )([164] > [205] [212]"
6640 PRINT"          [199] [192][195]  [164][192][192][189] [165][221]"
6650 PRINT"         [217]  [196][206]HT[205][195][206]  [194][160][205]"
6660 PRINT"         [165] [213][206][178]T[178] [206][206]  [167]  [165]"
6670 PRINT"         [205] [202][203][163][163][163][202][203]    [197][205][199]"
6680 PRINT"          [197][195][192][174]    [206][195][174] [176][195][189]"
6690 PRINT"           [164][206]    [173][196][163]   [196][192]"
6700 PRINT"         [192][196]   =         [196][192][198][164]
6710 [153]"       (null)TAB(    (null) CHR$ (null) (null)        TAB((null)
6720 PRINT"      [206]     [221][221] [199] [221] [167]          [205]
6730 [153]"     (null)     FN (null) CHR$ RIGHT$ THEN           (null)
6740 PRINT"    [167]     [221]  [221]   [221] [221]            [165]
6750 [153]"    (null)     /  (null)     (null)            CHR$
6760 PRINT"    [165]      [163][196][192][198][198][192][189]              [167]
6770 [153]"   THEN       (null)TAB(TAB(TAB(TAB(TAB(TAB((null)             THEN
6780 PRINT"   [199]      [167][167][176][178][174][160][213][201][165][165]             [165]
6790 [153]"   CHR$      THENTHENOR=^ MID$(null)FNFN             CHR$
6800 RETURN
6810 FORI=1TO4000:NEXTI
6820 PRINT"[147]YOU ARE LOCKED IN A MAXIMUM SECURITY"
6830 PRINT"CELL.  YOU WILL SOON BE TORTURED"
6840 PRINT"MERCILESSLY FOR ANY INFORMATION YOU MAY HAVE."
6850 PRINT"THERE SEEM TO BE ONLY TWO ALTERNATIVES."
6860 PRINT"ESCAPE OR DIE..."
6870 RE=RE+1:ER=RND(0)/(RE):GOTO3390
6880 IFCM$<>"LOOK"ANDCM$<>"DIE"ANDCM$<>"ESCAPE"THEN6920
6890 IFCM$="LOOK"THEN6820
6900 IFCM$="DIE"THEN 6930
6910 IFCM$="ESCAPE"THEN6960
6920 PRINT"I SAID THERE WERE ONLY TWO ALTERNATIVES!":GOTO3390
6930 PRINT"[147]IT WILL BE QUICK AND PAINLESS.":FORI=1TO2000:NEXTI
6940 PRINT"GOD REST YOUR SOUL.":FORI=1TO3000:NEXTI
6950 SYS64721
6960 PRINT"[147]I'LL DO MY BEST...":FORI=1TO2000:NEXTI
6970 IF ER>.1THEN7000
6980 PRINT"I'M SORRY, I'M JUST TO WEAK."
6990 GOTO3170
7000 PRINT"[147]WE MADE IT!!!"
7010 PRINT"THE POWER OF THE FORCE HAS TRANSPORTED"
7020 PRINT"US BACK TO THE COCKPIT OF THE MILLENNIUMFALCON."
7030 PRINT"BE CAREFULL.  WE WERE LUCKY THIS TIME.":FORI=1TO5000:NEXTI
7040 GOTO250
7050 PRINT"[147]"E$" "S$" AND "D$"... "T$"!":FORI=1TO1000:NEXT I
7060 PRINT"[147]":GOTO3390
7070 PRINT"[147]CONGRADULATIONS!"
7080 PRINT"YOU HAVE JUST BLASTED 40 KILOGRAMS OF   HIGH GRADE ANTI-MATTER FUEL."
7090 PRINT"YOU AND THE SURROUNDING AREA ARE NOW    SPACE DUST."
7100 FORI=1TO4000:NEXTI
7110 PRINT"[147]":GOTO3160
7120 FORI=1TO1000:NEXTI
7130 PRINT"HE FIRES!!....."
7140 FORI=1TO1000:NEXTI
7150 IFRND(1)<.075THEN7180
7160 PRINT"HE MISSES!!!"
7170 GOTO370
7180 PRINT"YOU'VE BEEN STUNNED!!!!"
7190 FORI=1TO3000:NEXTI
7200 GOTO1650
7210 IFCQ=2THEN7240
7220 PRINT"WHAT AM I... A CARTOGRAPHER?"
7230 CQ=1:GOTO290
7240 PRINT"[147]"
7250 PRINT"CRUISER PLANS: NORTH SECTION[146]"
7260 PRINT" [166][166][166][166][166][166][166]                  "
7270 PRINT" [166]  E  [166]        [176][192][192][192][192][192][192][192][174] "
7280 PRINT" [166]N_[219][192]S[166]        [221] VAULT [221] "
7290 PRINT" [166]  W  [166]        [173][192][192][178][178][192][192][192][189] "
7300 PRINT" [166][166][166][166][166][166][166]           [221][221]     PAGE 1"
7310 PRINT"                   [221][171][209][146]         OF FOUR[145]"
7320 PRINT"         [176][192][192][192][192][192][192][174]  [221][221]     "
7330 PRINT"         [221]      [173][192][192][189][173][192][192][192][192][192][192][192][192]
7340 [153]"         (null) COMP.ORTANTAN^ORTANTANTANTANTANTANTANTANTANTAN
7350 PRINT"         [221]      [221]  [221][221]
7360 [153]" ORTANTANTANTANTANTAN^(null) CENT.(null)  (null)/TANTANTANTANTANTANTANTANTANTANTANTANTAN^
7370 PRINT" [221]      [173][189]      [221]  [221]              [221]
7380 [153]" (null) TEST.ORTANTANTANTANTANTANTANEXP  (null) RESEARCH     (null)
7390 PRINT" [221]      [221]   [176][192][192][192][192][192][192][189]              [221]
7400 [153]" (null) LAB  (null)   (null)         LABS        (null)
7410 PRINT" [173][192][192][192][192][192][192][189]   [221]                     [221]
7420 [153]"            (null)  DETAIL RESTRICTEDWAIT  (null)
7430 PRINT"            [173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189]
7440 [141]7930
7450 [153]" SPC(SPC(SPC(SPC(SPC(SPC(SPC(
7460 PRINT" [166]  E  [166]
7470 [153]" SPC(N_(null)TANSSPC(  CRUISER PLANS: MID SECTION"
7480 [153]" SPC(  W  SPC("
7490 [153]" SPC(SPC(SPC(SPC(SPC(SPC(SPC(  PAGE 2 OF FOUR"
7500 [153]"
7510 PRINT"             SAME SCALE"
7520 PRINT"                 [176][192][192][192][192][192][174]"
7530 PRINT"                 [221]SUPP.[173][192][192][192][192][192][192][192] "
7540 PRINT"                 [173][192][192][192][192][174][176][192][192][192][192][192][192][192] "
7550 PRINT"    [176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189][173][146][192][192][192][192][192][192][192][192][192][174] "
7560 PRINT" [192][192][192][189][146] SHIP                    [221]"
7570 PRINT"  [192][192][174][146]STORAGE                     [221]"
7580 PRINT"    [173][192][192][192][192][174]                       [221]"
7590 PRINT"         [221]                       [221]"
7600 PRINT"         [221]                       [221]"
7610 PRINT"         [221]      FLIGHT DECK      [221]"
7620 PRINT"         [221]                       [221]"
7630 PRINT"         [221]                       [221]"
7640 PRINT"         [221]                       [221]"
7650 PRINT"         [221]                       [221]"
7660 PRINT"         [173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][146][192][192][192][192][192][192][189]"
7670 GOSUB7930
7680 PRINT""
7690 PRINT" [166][166][166][166][166][166][166] "
7700 PRINT" [166]  S  [166]  CRUISER PLANS: SOUTH SECTION"
7710 PRINT" [166]E_[219][192]W[166] "
7720 PRINT" [166]  N  [166]    PAGE 3 OF FOUR         "
7730 PRINT" [166][166][166][166][166][166][166]      SAME SCALE"
7740 PRINT
7750 PRINT"                       [176][192][192][192][192][192][192][192][192][192][174]"
7760 PRINT" [176][192][192][192][192][192][192][178][192][192][192][192][192][192][192][192][174][176][192][192][192][174][221]STRATI.  [221]"
7770 PRINT" [221]INTER.[221] DECON. [173][189]   [173][189]         [221]"
7780 PRINT" [209]      [177]        [176][192][174] [176][192][174]PLANNING [221]"
7790 PRINT" [221]ROOM  [178] ROOM   [221] [221] [221] [171][192][192][179][171][192][192][192][192][192][179]"
7800 PRINT" [173][192][192][192][192][192][192][177][192][192][192][192][192][192][192][192][189] [221] [221] [221]         [221]"
7810 PRINT"                   [221] [221] [221] T.B.C.  [221]"
7820 PRINT"                   [221] [221] [173][192][192][192][192][192][192][192][192][192][189]"
7830 PRINT"                   [221]   "
7840 GOSUB7930
7850 PRINT"CRUISER PLANS: LOWER LEVELS"
7860 PRINT"PAGE 4 OF 4:SAME SCALE"                                   
7870 PRINT"[204][206][205][164][164][206][163][163][205][206][205][206][205][164][206][205][206][163][205][206][205][206][163][163][163][205][164][164][164][206][205][206][205][164][164][206][205][206][205][186]"
7880 PRINT"THE REST SEEMS TO BE MISSING."
7890 FORF=1024TO1063:POKEF,100:NEXTF
7900 FORF=1103TO1263STEP40:POKEF,103:NEXTF
7910 FORF=1064TO1224STEP40:POKEF,101:NEXTF
7920 PRINT"":RETURN
7930 FORF=1024TO1063:POKEF,100:NEXTF
7940 FORF=1984TO2023:POKEF,99:NEXTF
7950 FORF=1064TO1944STEP40:POKEF,101:NEXTF
7960 FORF=1103TO1983STEP40:POKEF,103:NEXTF
7970 GETQ$:IFQ$=""THEN7970
7980 PRINT"[147]":RETURN
7990 IFDG=-1THENPRINTO0$:GOTO290
8000 DG=-1
8010 O2$=O0$:O3$=O0$:O4$=O0$:O5$=O0$:O56$=O0$:O7$=O0$
8020 PRINT"ZZZAP!!! THE DOOR BLASTED!"
8030 IFDJ=-1ORLC<>31THEN290
8040 OB$(22)="SOMEONE'S CHARRED REMAINS"
8050 EN=-1:DJ=-1:GOTO290
8060 POKE144,46:PRINT"THANKS FOR PLAYING.":CLR:END