Alle anzeigenHinweis Sie k÷nnen die folgenden Beispiele in berechneten Spalten verwenden. Die Beispiele, die keine Spaltenverweise enthalten, k÷nnen zur Angabe des Standardwerts einer Spalte verwendet werden.
▄berprⁿfen, ob eine Zahl gr÷▀er oder kleiner als eine andere Zahl ist
Verwenden Sie die WENN-Funktion fⁿr diese Aufgabe.
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 15000 | 9000 | =Spalte1>Spalte2 | Ist Spalte1 gr÷▀er als Spalte2? (WAHR) |
| 15000 | 9000 | =WENN(Spalte1<=Spalte2, "OK", "Nicht OK") | Ist Spalte1 kleiner als oder gleich Spalte2? (Nicht OK) |
Zurⁿckgeben eines logischen Werts nach dem Vergleich des Spalteninhalts
| Spalte1 | Spalte2 | Spalte3 | Formel | Beschreibung |
|---|---|---|---|---|
| 15 | 9 | 8 | =UND(Spalte1>Spalte2, Spalte1<Spalte3) | Ist 15 gr÷▀er als 9 und kleiner als 8? (FALSCH) |
| 15 | 9 | 8 | =ODER(Spalte1>Spalte2, Spalte1<Spalte3) | Ist 15 gr÷▀er als 9 oder kleiner als 8? (WAHR) |
| 15 | 9 | 8 | =NICHT(Spalte1+Spalte2=24) | Ist 15 plus 9 nicht gleich 24? (FALSCH) |
Verwenden Sie fⁿr ein Ergebnis, das aus einer weiteren Berechnung besteht, oder fⁿr einen beliebigen anderen Wert als WAHR oder FALSCH, die Funktionen WENN, UND und ODER.
| Spalte1 | Spalte2 | Spalte3 | Formel | Beschreibung |
|---|---|---|---|---|
| 15 | 9 | 8 | =WENN(Spalte1=15, "OK", "Nicht OK") | Wenn der Wert in Spalte1 gleich 15 ist, dann "OK" zurⁿckgeben. (OK) |
| 15 | 9 | 8 | =WENN(UND(Spalte1>Spalte2, Spalte1<Spalte3), "OK", "Nicht OK") | Wenn 15 gr÷▀er als 9 und kleiner als 8 ist, dann "OK" zurⁿckgeben. (Nicht OK) |
| 15 | 9 | 8 | =WENN(ODER(Spalte1>Spalte2, Spalte1<Spalte3), "OK", "Nicht OK") | Wenn 15 gr÷▀er als 9 oder kleiner als 8 ist, dann "OK" zurⁿckgeben. (OK) |
Anzeigen von Nullen als Leerzeichen oder Striche
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 10 | 10 | =Spalte1-Spalte2 | Zweite Zahl wird von der ersten subtrahiert (0) |
| 10 | 10 | =WENN(Spalte1-Spalte2,"",Spalte1-Spalte2) | Gibt 0 zurⁿck, wenn der Wert Null ist (leere Spalte) |
| 15 | 9 | =WENN(Spalte1-Spalte2,"-",Spalte1-Spalte2) | Gibt einen Strich zurⁿck, wenn der Wert Null ist (-) |
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 09.06.2007 | 3 | =Spalte1+Spalte2 | Fⁿgt 3áTage zum 09.06.07 hinzu (12.06.07) |
| 10.12.2008 | 54 | =Spalte1+Spalte2 | Fⁿgt 54áTage zum 10.12.2008 hinzu (02.02.2009) |
Verwenden Sie die Funktionen DATUM, JAHR, MONAT und TAG, um eine Anzahl von Monaten zu einem Datum hinzuzufⁿgen.
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 09.06.2007 | 3 | =DATUM(JAHR(Spalte1),MONAT(Spalte1)+Spalte2,TAG(Spalte1)) | Fⁿgt 3áMonate zum 09.06.07 hinzu (09.09.07) |
| 10.12.2008 | 25 | =DATUM(JAHR(Spalte1),MONAT(Spalte1)+Spalte2,TAG(Spalte1)) | Fⁿgt 25áMonate zum 10.12.2008 hinzu (10.01.2011) |
Verwenden Sie die Funktionen DATUM, JAHR, MONAT und TAG, um eine Anzahl von Jahren zu einem Datum hinzuzufⁿgen.
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 09.06.2007 | 3 | =DATUM(JAHR(Spalte1)+Spalte2,MONAT(Spalte1),TAG(Spalte1)) | Fⁿgt 3áJahre zum 09.06.07 hinzu (09.06.10) |
| 10.12.2008 | 25 | =DATUM(JAHR(Spalte1)+Spalte2,MONAT(Spalte1),TAG(Spalte1)) | Fⁿgt 25áJahre zum 10.12.2008 hinzu (10.12.2033) |
Verwenden Sie die Funktionen DATUM, JAHR, MONAT und TAG, um eine Kombination aus Tagen, Monaten und Jahren zu einem Datum hinzuzufⁿgen.
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 09.06.2007 | =DATUM(JAHR(Spalte1)+3,MONAT(Spalte1)+1,TAG(Spalte1)+5) | Fⁿgt 3áJahre, 1áMonat und 5áTage zum 09.06.2007 hinzu (14.07.2010) |
| 10.12.2008 | =DATUM(JAHR(Spalte1)+1,MONAT(Spalte1)+7,TAG(Spalte1)+5) | Fⁿgt 1áJahr, 7áMonate und 5áTage zum 09.06.2007 hinzu (14.01.2009) |
Berechnen des Unterschieds zwischen zwei Datumsangaben
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 01. Jan. 1995 | 15. Jun. 1999 | =DATEDIF(Spalte1, Spalte2,"t") | Gibt die Anzahl der Tage zwischen zwei Datumsangaben zurⁿck (1626) |
| 01. Jan. 1995 | 15. Jun. 1999 | =DATEDIF(Spalte1, Spalte2,"jm") | Gibt die Anzahl der Monate zwischen zwei Datumsangaben zurⁿck, wobei die Jahresangabe ignoriert wird (5) |
| 01. Jan. 1995 | 15. Jun. 1999 | =DATEDIF(Spalte1, Spalte2,"jt") | Gibt die Anzahl der Tage zwischen zwei Datumsangaben zurⁿck, wobei die Jahresangabe ignoriert wird (165) |
Berechnen des Unterschieds zwischen zwei Zeitangaben
Damit diese Methode funktioniert, dⁿrfen Stunden 24 und Minuten und Sekunden 60, nicht ⁿberschreiten.
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 09.06.07 10:35:00 | 09.06.07 15:30 | =TEXT(Spalte2-Spalte1,"h") | Stunden zwischen zwei Zeitangaben (4) |
| 09.06.07 10:35:00 | 09.06.07 15:30 | =TEXT(Spalte2-Spalte1,"h:mm") | Stunden und Minuten zwischen zwei Zeitangaben (4:55) |
| 09.06.07 10:35:00 | 09.06.07 15:30 | =TEXT(Spalte2-Spalte1,"h:mm:ss") | Stunden, Minuten und Sekunden zwischen zwei Zeitangaben (4:55:00) |
Verwenden Sie die GANZZAHL-Funktion oder die Funktionen STUNDE, MINUTE und SEKUNDE, um das Ergebnis als Summe basierend auf einer Zeiteinheit anzuzeigen.
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 09.06.07 10:35:00 | 10.06.2007 15:30 | =GANZZAHL((Spalte2-Spalte1)*24) | Stunden insgesamt zwischen zwei Zeitangaben (28) |
| 09.06.07 10:35:00 | 10.06.2007 15:30 | =GANZZAHL((Spalte2-Spalte1)*1440) | Minuten insgesamt zwischen zwei Zeitangaben (1735) |
| 09.06.07 10:35:00 | 10.06.2007 15:30 | =GANZZAHL((Spalte2-Spalte1)*86400) | Sekunden insgesamt zwischen zwei Zeitangaben (104100) |
| 09.06.07 10:35:00 | 10.06.2007 15:30 | =STUNDE(Spalte2-Spalte1) | Stunden zwischen zwei Zeitangaben, wenn der Unterschied 24 nicht ⁿberschreitet. (4) |
| 09.06.07 10:35:00 | 10.06.2007 15:30 | =MINUTE(Spalte2-Spalte1) | Minuten zwischen zwei Zeitangaben, wenn der Unterschied 60 nicht ⁿberschreitet. (55) |
| 09.06.07 10:35:00 | 10.06.2007 15:30 | =SEKUNDE(Spalte2-Spalte1) | Sekunden zwischen zwei Zeitangaben, wenn der Unterschied 60 nicht ⁿberschreitet. (0) |
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 10:35:00 | =(Spalte1-GANZZAHL(Spalte1))*24 | Anzahl der Stunden seit 00:00 (10,583333) |
| 12:15 | =(Spalte1-GANZZAHL(Spalte1))*24 | Anzahl der Stunden seit 00:00 (12,25) |
Verwenden Sie den Divisionsoperator und die TEXT-Funktion, um Stunden aus einer Dezimalzahl in das Standardzeitformat (Stunden:Minuten:Sekunden) zu konvertieren.
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 10:5833 | =TEXT(Spalte1/24, "h:mm") | Stunden seit 00:00 (10:35:00) |
| 12:25:00 | =TEXT(Spalte1/24, "h:mm") | Stunden seit 00:00 (12:15:00) |
Einfⁿgen von julianischen Datumsangaben
Das in der Astronomie verwendete julianische Datum besteht aus einem seriellen System, das am 1. Januar v. u. Z. beginnt.
Hinweis Dieses Format basiert nicht auf dem julianischen Kalender.
Verwenden Sie die Funktionen TEXT und DATWERT, um ein Datum in ein julianisches Datum zu konvertieren.
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 23.06.2007 | =TEXT(Spalte1,"jj")&TEXT((Spalte1-DATWERT("1/1/"& TEXT(Spalte1,"jj"))+1),"000") | Datum im "julianischen" Format, mit einem Jahr aus zwei Ziffern (07174) |
| 23.06.2007 | =TEXT(Spalte1,"jjjj")&TEXT((Spalte1-DATWERT("1/1/"&TEXT(Spalte1,"jj"))+1),"000") | Datum im "julianischen" Format, mit einem Jahr aus vier Ziffern (2007174) |
Verwenden Sie die Konstante 2415018.50, um ein Datum in ein julianisches Datum zu konvertieren, das in der Astronomie verwendet wird.
Diese Formel funktioniert nur bei Datumsangaben nach dem 01.03.1901 und bei Verwendung des 1900-Datums-Systems.
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 23.06.2007 | =Spalte1+2415018.50 | Datum im "julianischen" Format der Astronomie (2454274.50) |
Anzeigen von Datumsangaben als Wochentag
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 19. Feb. 2007 | =TEXT(WOCHENTAG(Spalte1), "tttt") | Berechnet den Wochentag fⁿr das Datum und gibt die vollstΣndige Bezeichnung des Tags zurⁿck (Montag) |
| 03. Jan. 2008 | =TEXT(WOCHENTAG(Spalte1), "tt") | Berechnet den Wochentag fⁿr das Datum und gibt die Abkⁿrzung fⁿr den Tag zurⁿck (Do) |
Verwenden Sie den Additionsoperator oder die SUMME-Funktion, um Zahlen in zwei oder mehr Spalten einer Zeile zu addieren.
| Spalte1 | Spalte2 | Spalte3 | Formel | Beschreibung |
|---|---|---|---|---|
| 6 | 5 | 4 | =Spalte1+Spalte2+Spalte3 | Addiert die Werte in den ersten drei Spalten (15) |
| 6 | 5 | 4 | =SUM(Spalte1,Spalte2,Spalte3) | Addiert die Werte in den ersten drei Spalten (15) |
| 6 | 5 | 4 | =SUM(WENN(Spalte1>Spalte2, Spalte1-Spalte2, 10), Spalte3) | Wenn Spalte1 gr÷▀er als Spalte2 ist, wird die Differenz und Spalte3 addiert. Andernfalls wird 10 and Spalte3 addiert. (5) |
| Spalte1 | Spalte2 | Spalte3 | Formel | Beschreibung |
|---|---|---|---|---|
| 15000 | 9000 | -8000 | =Spalte1-Spalte2 | Subtrahiert 9000 von 15000 (6000) |
| 15000 | 9000 | -8000 | =SUM(Spalte1, Spalte2, Spalte3) | Addiert die Zahlen in den ersten drei Spalten, einschlie▀lich negativer Werte (16000) |
Berechnen der Differenz zweier Zahlen in Prozent
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 2342 | 2500 | =(Spalte2-Spalte1)/ABS(Spalte1) | ─nderung in Prozent (6,75% oder 0,06746) |
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 5 | 2 | =Spalte1*Spalte2 | Multipliziert die Zahlen in den ersten beiden Spalten (10) |
| 5 | 2 | =PRODUKT(Spalte1, Spalte2) | Multipliziert die Zahlen in den ersten beiden Spalten (10) |
| 5 | 2 | =PRODUKT(Spalte1,Spalte2,2) | Multipliziert die Zahlen in den ersten beiden Spalten und die Zahl 2 (20) |
Verwenden Sie den Divisionsoperator (-) fⁿr diese Aufgabe.
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 15000 | 12 | =Spalte1/Spalte2 | Dividiert 15000 durch 12 (1250) |
| 15000 | 12 | =(Spalte1+10000)/Spalte2 | Addiert 15000 und 9000 und dividiert das Ergebnis durch 12 (2000) |
Berechnen des Mittelwerts von Zahlen
Der Mittelwert wird auch Durchschnitt genannt. Verwenden Sie die MITTELWERT-Funktion, um den Mittelwert von Zahlen in zwei oder mehr Spalten zu berechnen.
| Spalte1 | Spalte2 | Spalte3 | Formel | Beschreibung |
|---|---|---|---|---|
| 6 | 5 | 4 | =MITTELWERT(Spalte1, Spalte2,Spalte3) | Mittelwert der Zahlen in den ersten drei Spalten (5) |
| 6 | 5 | 4 | =MITTELWERT(WENN(Spalte1>Spalte2, Spalte1-Spalte2, 10), Spalte3) | Wenn Spalte1 gr÷▀er als die Spalte ist, wird der Mittelwert aus der Differenz und Spalte3 berechnet. Andernfalls wird der Mittelwert von Wert 10 und Spalte3 berechnet. (2,5) |
Berechnen des Medians von Zahlen
| A | B | C | D | E | F | Formel | Beschreibung |
|---|---|---|---|---|---|---|---|
| 10 | 7 | 9 | 27 | 0 | 4 | =MEDIAN(A, B, C, D, E, F) | Median der Zahlen in den ersten 6áSpalten (8) |
Berechnen der kleinsten oder gr÷▀ten Zahl in einem Bereich
| Spalte1 | Spalte2 | Spalte3 | Formel | Beschreibung |
|---|---|---|---|---|
| 10 | 7 | 9 | =MIN(Spalte1, Spalte2, Spalte3) | Kleinste Zahl (7) |
| 10 | 7 | 9 | =MAX(Spalte1, Spalte2, Spalte3) | Gr÷▀te Zahl (10) |
| Spalte1 | Spalte2 | Spalte3 | Formel | Beschreibung |
|---|---|---|---|---|
| Apfel | 12.12.2007 | =COUNT(Spalte1, Spalte2, Spalte3) | ZΣhlt die Anzahl der Spalten, die numerische Werte enthalten, einschlie▀lich Datums- und Zeitwerte. Nicht berⁿcksichtigt werden Text und Nullwerte. (1) | |
| $12 | #DIV/0! | 1.01 | =COUNT(Spalte1, Spalte2, Spalte3) | ZΣhlt die Anzahl der Spalten, die numerische Werte enthalten. Nicht berⁿcksichtigt werden Fehler und logische Werte. (2) |
Erh÷hen oder Verringern einer Zahl durch einen Prozentsatz
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 23 | 3% | =Spalte1*(1+5%) | Erh÷ht die Zahl Spalte1 um 5% (24,15) |
| 23 | 3% | =Spalte1*(1+Spalte2) | Erh÷ht die Zahl in Spalte1 um den Prozentwert in Spalte2: 3% (23,69) |
| 23 | 3% | =Spalte1*(1-Spalte2) | Verringert die Zahl in Spalte1 um den Prozentwert in Spalte2: 3% (22,31) |
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 5 | 2 | =Spalte1^Spalte2 | Berechnet 5 hoch 2 (25) |
| 5 | 3 | =POWER(Spalte1, Spalte2) | Berechnet 5 hoch 3 (125) |
Verwenden Sie zum Aufrunden einer Zahl die Funktionen AUFRUNDEN, GERADE und UNGERADE.
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 20,3 | =AUFRUNDEN(Spalte1,0) | Rundet 20,3 auf die nΣchste ganze Zahl auf (21) |
| -5,9 | =AUFRUNDEN(Spalte1,0) | Rundet -5,9 auf (-6) |
| 12.5493 | =AUFRUNDEN(Spalte1,2) | Rundet 12,5493 auf das nΣchste Hundertstel (zwei Dezimalstellen) auf (12,55) |
| 20,3 | =GERADE(Spalte1) | Rundet 20,3 auf die nΣchste gerade Zahl auf (22) |
| 20,3 | =UNGERADE(Spalte1) | Rundet 20,3 auf die nΣchste ungerade Zahl auf (21) |
Verwenden Sie zum Abrunden einer Zahl die ABRUNDEN-Funktion.
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 20,3 | =ABRUNDEN(Spalte1,0) | Rundet 20,3 auf die nΣchste ganze Zahl ab (20) |
| -5,9 | =ABRUNDEN(Spalte1,0) | Rundet -5,9 ab (-5) |
| 125493 | =ABRUNDEN(Spalte1,2) | Rundet 12,5493 auf das nΣchste Hundertstel (zwei Dezimalstellen) ab (12,54) |
Verwenden Sie die RUNDEN-Funktion, um eine Zahl auf die nΣchste Zahl oder Teilzahl zu runden.
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 20,3 | =RUNDEN(Spalte1,0) | Rundet 20,3 ab, da die Teilzahl unter 0,5 liegt (20) |
| 5,9 | =RUNDEN(Spalte1,0) | Rundet 5,9 auf, da die Teilzahl ⁿber 0,5 liegt (6) |
| -5,9 | =RUNDEN(Spalte1,0) | Rundet -5,9 ab, da die Teilzahl unter -0,5 liegt (-6) |
| 1,25 | =RUNDEN(Spalte1, 1) | Rundet die Zahl auf das nΣchste Zehntel (eine Dezimalstelle) auf. Da die zu rundende Teilzahl ⁿber 0,05 liegt, wird die Zahl aufgerundet. (Ergebnis: 1,3) |
| 30452 | =RUNDEN(Spalte1, 2) | Rundet die Zahl auf das nΣchste Hundertstel (zwei Dezimalstellen) auf. Da die zu rundende Teilzahl, 0,002, unter 0,005 liegt, wird die Zahl abgerundet. (Ergebnis: 30,45) |
Verwenden Sie die Funktionen RUNDEN, AUFRUNDEN, ABRUNDEN, GANZZAHL und L─NGE, um eine Zahl auf eine Wertstelle ⁿber 0 zu runden.
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| 5492820 | =RUNDEN(Spalte1,3-L─NGE(GANZZAHL(Spalte1))) | Rundet die Zahl auf 3áWertstellen (5490000) |
| 22230 | =ABRUNDEN(Spalte1,3-L─NGE(GANZZAHL(Spalte1))) | Rundet die untere Zahl auf 3áWertstellen ab (22200) |
| 5492820 | =AUFRUNDEN(Spalte1, 5-L─NGE(GANZZAHL(Spalte1))) | Rundet die obere Zahl auf 5áWertstellen auf (5492900) |
─ndern der Gro▀-/Kleinschreibung
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| nancy Davolio | =GROSS(Spalte1) | ─ndert den Text in Gro▀buchstaben (NANCY DAVOLIO) |
| nancy Davolio | =KLEIN(Spalte1) | ─ndert den Text in Kleinbuchstaben (nancy davolio) |
| nancy Davolio | =GROSS2(Spalte1) | Schreibt den ersten Buchstaben im Wort gro▀ (Nancy Davolio) |
Kombinieren von Vor- und Nachnamen
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| Nancy | Fuller | =Spalte1&Spalte2 | Kombiniert zwei Zeichenfolgen (NancyFuller) |
| Nancy | Fuller | =Spalte1&" "&Spalte2 | Kombiniert zwei Zeichenfolgen durch ein Leerzeichen getrennt (Nancy Fuller) |
| Nancy | Fuller | =Spalte2&","&Spalte1 | Kombiniert zwei Zeichenfolgen durch ein Komma getrennt (Fuller, Nancy) |
| Nancy | Fuller | =VERKETTEN(Spalte2, ",", Spalte1) | Kombiniert zwei Zeichenfolgen durch ein Komma getrennt (Fuller,Nancy) |
Kombinieren von Text und Zahlen aus verschiedenen Spalten
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| Buchanan | 28 | =Spalte1&" hat "&Spalte2&" Artikel verkauft." | Kombiniert den Spalteninhalt in einem Satz (Buchanan hat 28 Artikel verkauft). |
| Dodsworth | 40% | =Spalte1&" erzielte "&TEXT(Spalte2,"0%")&" des Gesamtverkaufs." | Kombiniert den Spalteninhalt in einem Satz (Dodsworth erzielte 40% des Gesamtverkaufs). Hinweis Bei der TEXT-Funktion wird der formatierte Wert von Spalte2 und nicht der zugrunde liegende Wert (0,4) verwendet. |
| Buchanan | 28 | =VERKETTEN(Spalte1," hat ",Spalte2," Artikel verkauft.") | Kombiniert den Spalteninhalt in einem Satz (Buchanan hat 28 Artikel verkauft). |
Kombinieren von Text mit einem Datum oder Zeitraum
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| Rechnungsdatum | 05. Juni 2007 | ="Abrechnungsdatum: "&TEXT(Spalte2, "tt.mm.jjjj") | Kombiniert Text mit einem Datum (Abrechnungsdatum: 05.06.2007) |
| Rechnungsdatum | 05. Juni 2007 | =Spalte1&" "&TEXT(Spalte2, "tt.mm.jjjj") | Kombiniert Text mit einem Datum aus verschiedenen Spalten in einer Spalte (Rechnungsdatum 05.06.2007) |
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| BD122 | BD123 | =IDENTISCH(Spalte1,Spalte2) | Vergleicht den Inhalt der ersten beiden Spalten (FALSCH) |
| BD122 | BD123 | =IDENTISCH(Spalte1, "BD122") | Vergleicht den Inhalt von Spalte1 und die Zeichenfolge "BD122" (WAHR) |
| BD122 | BD123 | =ODER(IDENTISCH("BD121", Spalte1, Spalte2) | Vergleicht die Zeichenfolge "BD121" mit dem Inhalt der ersten beiden Spalten (FALSCH) |
▄berprⁿft, ob der Wert einer Spalte oder ein Teil daraus einem bestimmten Text entspricht
Verwenden Sie die Funktionen WENN, FINDEN, SUCHEN und ISTZAHL, um zu ⁿberprⁿfen, ob eine Spalte einen Wert enthΣlt oder ob ein Teil daraus einem bestimmten Text entspricht.
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| Davolio | =WENN(Spalte1="Davolio", "OK", "Nicht OK") | ▄berprⁿft, ob Spalte1 Davolio lautet (OK) |
| Davolio | =WENN(ISTZAHL(FINDEN("v",Spalte1)), "OK", "Nicht OK") | ▄berprⁿft, ob Spalte1 den Buchstaben v enthΣlt (OK) |
| BD123 | =ISTZAHL(FINDEN("BD";Spalte1)) | ▄berprⁿft, ob Spalte1 BD enthΣlt (WAHR) |
| Spalte1 | Spalte2 | Spalte3 | Formel | Beschreibung |
|---|---|---|---|---|
| Umsatz | 19 | =ANZAHL2"(Spalte1, Spalte2) | ZΣhlt die Anzahl der nicht leeren Spalten (2) | |
| Umsatz | 19 | =ANZAHL2(Spalte1, Spalte2, Spalte3) | ZΣhlt die Anzahl der nicht leeren Spalten (2) |
Entfernen von Zeichen aus Text
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| Vitamin A | =LINKS(Spalte1,L─NGE(Spalte1)-2) | Gibt von links ausgehend 7 (9-2) Zeichen zurⁿck (Vitamin) |
| Vitamin B1 | =RECHTS(Spalte1, L─NGE(Spalte1)-8) | Gibt von rechts ausgehend 2 (10-8) Zeichen zurⁿck (B1) |
Entfernt Leerzeichen am Anfang und Ende einer Spalte
| Spalte1 | Formel | Beschreibung |
|---|---|---|
| Aufgepasst! | =GL─TTEN(Spalte1) | Entfernt die Leerzeichen am Anfang und am Ende (Aufgepasst!) |
Wiederholen eines Zeichens in einer Spalte
| Formel | Beschreibung |
|---|---|
| =WIEDERHOLEN(".",3) | Wiederholt einen Punktá3 Mal (...) |
| =WIEDERHOLEN("-",10) | Wiederholt einen Strich 10áMal (----------) |
Ausblenden von Fehlerwerten in Spalten
| Spalte1 | Spalte2 | Formel | Beschreibung |
|---|---|---|---|
| 10 | 0 | =Spalte1/Spalte2 | Ergibt einen Fehler (#DIV/0) |
| 10 | 0 | =WENN(ISTFEHLER(Spalte1/Spalte2),"NV",Spalte1/Spalte2) | Gibt NV zurⁿck, wenn der Wert ein Fehler ist. |
| 10 | 0 | =WENN(ISTFEHLER(Spalte1/Spalte2),"-",Spalte1/Spalte2) | Gibt einen Strich zurⁿck, wenn der Wert ein Fehler ist. |