Title Property

Sets or returns the title of a file dialog box displayed using the FileDialog object. Read/write String.

expression.Title

expression Required. An expression that returns one of the objects in the Applies To list.

Sets or returns the title of a SharedWorkspaceTask object. Read/write String.

expression.Title

expression Required. An expression that returns a SharedWorkspaceTask object.

Remarks

The Title property is the single required property of a shared workspace task. Use the optional Description property to provide or return additional information about the task.

Example

The following example displays a File Picker dialog box using the FileDialog object and displays each selected file in a message box.

Sub main()

    'Declare a variable as a FileDialog object.
    Dim fd As FileDialog

    'Create a FileDialog object as a File Picker dialog box.
    Set fd = Application.FileDialog(msoFileDialogFilePicker)

    'Declare a variable to contain the path
    'of each selected item. Even though the path is a String,
    'the variable must be a Variant because For Each...Next
    'routines only work with Variants and Objects.
    Dim vrtSelectedItem As Variant

    'Use a With...End With block to reference the FileDialog object.
    With fd

        'Change the title of the dialog
        .Title = "Archive"

        'Use the Show method to display the file picker dialog and return the user's action.
        'If the user presses the action button...
        If .Show = -1 Then

            'Step through each string in the FileDialogSelectedItems collection.
            For Each vrtSelectedItem In .SelectedItems

                'vrtSelectedItem is a String that contains the path of each selected item.
                'You can use any file I/O functions that you want to work with this path.
                'This example simply displays the path in a message box.
                MsgBox "Selected item's path: " & vrtSelectedItem

            Next vrtSelectedItem
        'If the user presses Cancel...
        Else
        End If
    End With

    'Set the object variable to Nothing.
    Set fd = Nothing

End Sub

The following example displays a list of the titles of all tasks in the current shared workspace.

    Dim swsTask As Office.SharedWorkspaceTask
    Dim strTasks As String
    For Each swsTask In ActiveWorkbook.SharedWorkspace.Tasks
        strTasks = strTasks & swsTask.Title & vbCrLf
    Next
    MsgBox strTasks, vbInformation + vbOKOnly, _
        "Tasks in Shared Workspace"
    Set swsTask = Nothing